커뮤니티
안녕하세요~ 수식 부탁드립니다~
2016-06-10 14:12:36
125
글번호 98942
안녕하세요~ 시스템신호 수식 부탁 좀 드립니다~
1. 분봉과 틱챠트에서 일봉 이평선(5일선 - 나중에 수치 조정 할수 있도록 부탁드립니다)을 캔들이 양봉(상승)으로 올라가 뚫고 이전 고점을 갱신 후 다시 음봉으로 내려와서 일봉이평에 닫고 양봉캔들이 보이면 바로 매수, 반대는 매도
2, 분봉과 틱챠트에서 음봉으로 하락하여 일봉이평선에 닫고(오차범위 +-5틱) 양봉 캔들이 보이면 매수, 반대는 매도
3. 분봉과 틱챠트에서 일봉이평선(수치 조정)에서 100틱 멀어졌을때 매수, 매도, 200틱 멀어졌을때 추가로 매수, 매도 (수치는 변경 가능하도록 부탁드립니다)
답변 1
예스스탁 예스스탁 답변
2016-06-13 09:23:34
안녕하세요
예스스탁입니다.
1.
input : P(5);
var : sum(0),cnt(0),mav(0),Bcond(0),Scond(0);
sum = 0;
for cnt = 0 to P-1{
sum = sum + DayClose(cnt);
}
mav = sum/P;
if date != date[1] Then{
Bcond = 0;
Scond = 0;
}
if crossup(C,mav) Then
Bcond = 1;
if Bcond == 1 and C > O Then
Bcond = 2;
if Bcond == 2 and C > dayhigh[1] Then
Bcond = 3;
if Bcond == 3 and L <= mav and C < O Then
Bcond = 4;
if Bcond == 4 and C > O Then{
Bcond = 5;
Buy();
}
if CrossDown(C,mav) Then
Scond = 1;
if Scond == 1 and C < O Then
Scond = 2;
if Scond == 2 and C < daylow[1] Then
Scond = 3;
if Scond == 3 and H >= mav and C > O Then
Scond = 4;
if Scond == 4 and C < O Then{
Scond = 5;
sell();
}
2
input : P(5),T(5);
var : sum(0),cnt(0),mav(0),Bcond(0),Scond(0);
sum = 0;
for cnt = 0 to P-1{
sum = sum + DayClose(cnt);
}
mav = sum/P;
if date != date[1] Then{
Bcond = 0;
Scond = 0;
}
if CrossDown(L,mav+PriceScale*T) Then
Bcond = 1;
if Bcond == 1 and C > O Then{
Bcond = 2;
buy();
}
if crossup(H,mav-PriceScale*T) Then
Scond = 1;
if Scond == 1 and C < O Then{
Scond = 2;
Sell();
}
3
추가진입하는 식이므로
시스템 적용시 시스템 트레이딩 설정창의
피라미딩 탭에서 피라미딩을 다른진입신호만 허용으로 설정하고 적용하시기 바랍니다.
input : P(5),T1(100),T2(200);
var : sum(0),cnt(0),mav(0),Bcond(0),Scond(0);
sum = 0;
for cnt = 0 to P-1{
sum = sum + DayClose(cnt);
}
mav = sum/P;
if MarketPosition <= 0 Then
buy("b",AtStop,mav+PriceScale*T1);
if MarketPosition == 1 and MaxEntries == 1 then
buy("bb",AtStop,mav+PriceScale*T2);
if MarketPosition >= 0 Then
sell("s",AtStop,mav-PriceScale*T1);
if MarketPosition == -1 and MaxEntries == 1 then
sell("ss",AtStop,mav-PriceScale*T2);
즐거운 하루되세요
> phn 님이 쓴 글입니다.
> 제목 : 안녕하세요~ 수식 부탁드립니다~
> 안녕하세요~ 시스템신호 수식 부탁 좀 드립니다~
1. 분봉과 틱챠트에서 일봉 이평선(5일선 - 나중에 수치 조정 할수 있도록 부탁드립니다)을 캔들이 양봉(상승)으로 올라가 뚫고 이전 고점을 갱신 후 다시 음봉으로 내려와서 일봉이평에 닫고 양봉캔들이 보이면 바로 매수, 반대는 매도
2, 분봉과 틱챠트에서 음봉으로 하락하여 일봉이평선에 닫고(오차범위 +-5틱) 양봉 캔들이 보이면 매수, 반대는 매도
3. 분봉과 틱챠트에서 일봉이평선(수치 조정)에서 100틱 멀어졌을때 매수, 매도, 200틱 멀어졌을때 추가로 매수, 매도 (수치는 변경 가능하도록 부탁드립니다)