커뮤니티
시간동안의 고가와 저가 표시..
2016-05-31 12:28:16
164
글번호 98640
해외선물 투자자 입니다.
1. 특정시간동안의 고가와 저가를 해당 거래일까지 나타내는 지표.
예) 15:00 ~ 19:00 동안의 고가와 저가를 다음날 아침 06:00까지 나타내는 수식
2.[1의 변경]
특정시간동안의 고가가 직전 스윙하이봉의 고가보다 낮을때는 직전 스윙하이봉부터
특정시간동안의 저가가 직전 스윙로우봉의 저가보다 높을때는 직전 스윙로우봉부터
다음날 아침 06:00 까지 나타내는 수식
예) 추세선의 스윙하이봉 사용: SHvalH
input : Left(3),Right(3);
var : SHvalH(0);
if Swinghigh(1,H,Left,Right,Left+Right+1) != -1
SHvalH = H[Right];
15:00 직전의 shvalh값이 15:00부터 19:00까지의 고가보다 높을경우 shvalh값을 고점으로
06:00시까지 지표로 나타내고 직전 스윙로우의값이 저가보다 낮을경우에는 직전의 스윙로우
저가로 나타냅니다.
3.[1과 2의 변경]
15:00시부터 19:00까지의 고가와 저가보다 19:00시 이후 첫 스윙하이와 스윙로우값이 높거나 낮을경우 스윙하이값이나 스윙로우값을 고점과 저점으로 06:00시까지 나타내는 수식 부탁드립니다.
질문 2.3의 경우 스윙하이와 스윙로우값이 직전&직후의 값이 시간대의 고가와 저가보다
낮거나 높을경우에는 시간대의 고가와 저가를 표시합니다.
4. 15:00~19:00 동안의 평균 거래량
이해가 되시게 질문드렸는지 모르겠네요..
부탁드립니다.
답변 1
예스스탁 예스스탁 답변
2016-05-31 16:39:50
안녕하세요
예스스탁입니다.
1.
var : BD(0),HH(0),LL(0),Tcond(false);
#최고가최저가 계산 시작시간
if stime == 150000 or (stime > 150000 and stime[1] < 150000) Then{
Tcond = true;
BD = bdate;
HH = H;
LL = L;
}
#최고가 최저가 계산 종료시간
if stime == 190000 or (stime > 190000 and stime[1] < 190000) Then
Tcond = false;
if Tcond == true then{
if H > HH Then
HH = H;
if L < LL Then
LL = L;
}
if Bdate == BD Then{
plot1(HH);
plot2(LL);
}
2
input : Left(3),Right(3);
var : SH(0),SL(0);
var : BD(0),HH(0),LL(0),Tcond(false);
if Swinghigh(1,H,Left,Right,Left+Right+1) != -1 Then
SH = H[Right];
if SwingLow(1,L,Left,Right,Left+Right+1) != -1 then
SL = L[Right];
#최고가최저가 계산 시작시간
if stime == 150000 or (stime > 150000 and stime[1] < 150000) Then{
Tcond = true;
BD = bdate;
HH = SH;
LL = SL;
}
#최고가 최저가 계산 종료시간
if stime == 190000 or (stime > 190000 and stime[1] < 190000) Then{
Tcond = false;
}
if Tcond == true then{
if H > HH Then
HH = H;
if L < LL Then
LL = L;
}
if Bdate == BD Then{
plot1(HH);
plot2(LL);
}
3
input : Left(3),Right(3);
var : SH(0),SL(0);
var : BD(0),HH(0),LL(0),Tcond(false);
#최고가최저가 계산 시작시간
if stime == 150000 or (stime > 150000 and stime[1] < 150000) Then{
Tcond = true;
BD = bdate;
HH = H;
LL = L;
}
#최고가 최저가 계산 종료시간
if stime == 190000 or (stime > 190000 and stime[1] < 190000) Then{
Tcond = false;
Condition1 = true;
Condition2 = true;
}
if Tcond == true then{
if H > HH Then
HH = H;
if L < LL Then
LL = L;
}
if Bdate == BD Then{
if Condition1 == true and Swinghigh(1,H,Left,Right,Left+Right+1) != -1 Then{
Condition1 = false;
SH = H[Right];
if SH > HH Then
HH = SH;
}
if Condition2 == true and SwingLow(1,L,Left,Right,Left+Right+1) != -1 then{
Condition2 = false;
SL = L[Right];
if SL < LL Then
LL = SL;
}
plot1(HH);
plot2(LL);
}
4
var : Tcond(false);
#시작시간
if stime == 150000 or (stime > 150000 and stime[1] < 150000) Then{
Tcond = true;
var1 = 0;
var2 = 0;
var3 = 0;
}
if stime == 190000 or (stime > 190000 and stime[1] < 190000) Then{
Tcond = false;
}
if Tcond == true Then{
var1 = var1+V;
var2 = var2+1;
var3 = var1/var2;
}
plot1(var3);
즐거운 하루되세요
> 다올 님이 쓴 글입니다.
> 제목 : 시간동안의 고가와 저가 표시..
> 해외선물 투자자 입니다.
1. 특정시간동안의 고가와 저가를 해당 거래일까지 나타내는 지표.
예) 15:00 ~ 19:00 동안의 고가와 저가를 다음날 아침 06:00까지 나타내는 수식
2.[1의 변경]
특정시간동안의 고가가 직전 스윙하이봉의 고가보다 낮을때는 직전 스윙하이봉부터
특정시간동안의 저가가 직전 스윙로우봉의 저가보다 높을때는 직전 스윙로우봉부터
다음날 아침 06:00 까지 나타내는 수식
예) 추세선의 스윙하이봉 사용: SHvalH
input : Left(3),Right(3);
var : SHvalH(0);
if Swinghigh(1,H,Left,Right,Left+Right+1) != -1
SHvalH = H[Right];
15:00 직전의 shvalh값이 15:00부터 19:00까지의 고가보다 높을경우 shvalh값을 고점으로
06:00시까지 지표로 나타내고 직전 스윙로우의값이 저가보다 낮을경우에는 직전의 스윙로우
저가로 나타냅니다.
3.[1과 2의 변경]
15:00시부터 19:00까지의 고가와 저가보다 19:00시 이후 첫 스윙하이와 스윙로우값이 높거나 낮을경우 스윙하이값이나 스윙로우값을 고점과 저점으로 06:00시까지 나타내는 수식 부탁드립니다.
질문 2.3의 경우 스윙하이와 스윙로우값이 직전&직후의 값이 시간대의 고가와 저가보다
낮거나 높을경우에는 시간대의 고가와 저가를 표시합니다.
4. 15:00~19:00 동안의 평균 거래량
이해가 되시게 질문드렸는지 모르겠네요..
부탁드립니다.