커뮤니티
파라볼릭 지표에 관한 질문입니다.
2016-05-18 10:15:11
171
글번호 98206
안녕하세요.
항상 수고가 많으십니다.
질문드립니다 -----------------------------------------
파라볼릭 계산식을 알고 싶습니다.
즉, 변수 x에 대한 파라볼릭식을 계산해 보고 싶습니다.
그리고 af = 0.02와 maxAF = 0.2는 무엇을 의미하는지도 알고 싶습니다.
또한 파라볼릭(종가)와는 무슨 차이가 있는지도 알고 싶습니다.
감사합니다.
답변 1
예스스탁 예스스탁 답변
2016-05-19 13:12:43
안녕하세요
예스스탁입니다.
1
af는 가속도, maxaf는 최대가속도값입니다.
상승이나 하락할때 지정한 값 만큰 가속도가 증가하고
최대 증가치는 maxaf까지만 허용합니다.
2
기본 파라볼릭식은 상승하락의 판단을 고가와 저가를 이용하는데
파라볼릭(종가)는 종가로만 판단하는 식입니다.
자세한 내용은 기술적지표관련 서적참고하시기 바랍니다.
3
사용자함수로 올려드립니다.
사용자함수로 아래 내용 함수로 작성하신 후에
지표식등에서 사용하실때
para(X,0.02,02)
와 같이 함수 호출해 사용하시면 됩니다.
사용자함수명 : Para
반환값형 : 숫자형
Input : value(Numeric),AF(NumericSimple), AFMAX(NumericSimple);
Var : Direction(0), SAR_Value(value), AF_Value(.02), HighValue(value), LowValue(value), EP(0),sarv(0);
if EP != 0 Then
{
if Direction == 1 then
{
EP = HighValue;
SAR_Value = SAR_Value + AF_Value * (EP - SAR_Value);
if value > HighValue then
{
HighValue = value;
AF_Value = AF_Value + AF;
if AF_Value >= AFMAX then AF_Value = AFMAX;
}
if value < SAR_Value then
{
Direction = -1;
SAR_Value = EP;
AF_Value = 0;
EP = 0;
LowValue = value;
}
}
else
{
EP = LowValue;
SAR_Value = SAR_Value + AF_Value * (EP - SAR_Value);
if value < LowValue then
{
LowValue = value;
AF_Value = AF_Value + Af;
if AF_Value >= AFMAX then AF_Value = AFMAX;
}
if value > SAR_Value then
{
Direction = 1;
SAR_Value = EP;
AF_Value = 0;
EP = 0;
HighValue = value;
}
}
Sarv = SAR_Value;
}
else
{
if SAR_Value != 0 && EP == 0 then
{
if Direction == 1 then
{
EP = HighValue;
AF_Value = AF;
SAR_Value = SAR_Value + AF_Value * (EP - SAR_Value);
if value > HighValue then
{
HighValue = value;
AF_Value = AF_Value + AF;
if AF_Value >= AFMAX then AF_Value = AFMAX;
}
}
else
{
EP = LowValue;
AF_Value = Af;
SAR_Value = SAR_Value + AF_Value * (EP - SAR_Value);
if value < LowValue then
{
LowValue = value;
AF_Value = AF_Value + AF;
if AF_Value >= AFMAX then AF_Value = AFMAX;
}
}
Sarv = SAR_Value;
}
else
{
if Direction == 0 then
{
if value > value[1] then Direction = 1;
else
if value < value[1] then Direction = -1;
}
else
{
if Direction == 1 then
{
if value < value[1] then
{
Direction = -1;
SAR_Value = HighValue;
Sarv = SAR_Value;
}
}
if Direction == -1 then
{
if value > value[1] then
{
Direction = 1;
SAR_Value = LowValue;
Sarv = SAR_Value;
}
}
}
LowValue = min(value, LowValue);
HighValue = max(value, HighValue);
}
}
para = sarv;
즐거운 하루되세요
> 샐리짱 님이 쓴 글입니다.
> 제목 : 파라볼릭 지표에 관한 질문입니다.
> 안녕하세요.
항상 수고가 많으십니다.
질문드립니다 -----------------------------------------
파라볼릭 계산식을 알고 싶습니다.
즉, 변수 x에 대한 파라볼릭식을 계산해 보고 싶습니다.
그리고 af = 0.02와 maxAF = 0.2는 무엇을 의미하는지도 알고 싶습니다.
또한 파라볼릭(종가)와는 무슨 차이가 있는지도 알고 싶습니다.
감사합니다.
다음글
이전글