커뮤니티
지그재그를 이용한 마디가 구하기
2016-01-27 02:03:01
446
글번호 94835
첨부 이미지
그림1
항상 회원들의 질문에 성심성의껏 답변 해주셔서 감사합니다.
다름아니라, 첨부파일처럼 지그재그 수식을 이용해서 마디가를 구하고 싶습니다
동그라미 친 부분들이 지그재그 꺽이는 부분인데, 그 꺽이는 부분의 종가들의 평균을 선으로 그어주는걸 만들고 싶습니다.
물론 변수로 봉갯수를 입력할 수 있게 만들어 주시면 감사하겠습니다.
즉, 예를 들면, 변수로 120을 입력하면, 그 기간동안 지그재그로 인해 꺽이는 부분이 4번 있다면, 그 4개 캔들 종가의 평균을 직선으로 표현하고 싶습니다.
- 1. 2016-01-27_오전_1-54-50.jpg (0.28 MB)
답변 1
예스스탁 예스스탁 답변
2016-01-27 15:23:30
안녕하세요
예스스탁입니다.
Input:chngRate(5);
Var:j(0),lastHiVal(0),lastLoVal(0),turnPntBit(""),TL1(0);
Array:valArr[50](0),barArr[50](0),turnPntArr[50]("");
For j = 0 To 49
{
barArr[j] = barArr[j] + 1;
}
Condition1 = Min(valArr[1],valArr[2]) * (1 + (chngRate/100)) < H and lastHiVal < H;
Condition2 = Max(valArr[1],valArr[2]) * (1 - (chngRate/100)) > L and
(lastLoVal > L || lastLoVal == 0);
If Condition1 Then { lastHiVal = H; lastLoVal = 0; }
If Condition2 Then { lastLoVal = L; lastHiVal = 0; }
turnPntBit = "";
If Condition1 and Condition2 Then
{
If Max(valArr[1],valArr[2]) < H and Min(valArr[1],valArr[2]) > L Then
turnPntBit = "HiLo";
Else If Max(valArr[1],valArr[2]) < H Then turnPntBit = "Hi";
Else If Min(valArr[1],valArr[2]) > L Then turnPntBit = "Lo";
}
Else If Condition1 Then turnPntBit = "Hi";
Else If Condition2 Then turnPntBit = "Lo";
If turnPntBit <> "" Then
{
If turnPntBit == "HiLo" Then
{
valArr[1] = IFF(turnPntArr[1] == "Hi",H,L);
barArr[1] = 0;
TL_SetEnd(TL1,sDate[barArr[1]],sTime[barArr[1]],valArr[1]);
If turnPntArr[1] == "Hi" Then
turnPntBit = "Lo";
Else
turnPntBit = "Hi";
}
If turnPntBit <> turnPntArr[1] Then
{
for j = 48 downto 1
{
valArr[j+1] = valArr[j];
barArr[j+1] = barArr[j];
turnPntArr[j+1] = turnPntArr[j];
}
}
If turnPntBit <> turnPntArr[1] or
(turnPntBit == turnPntArr[1] and
((turnPntBit == "Hi" and valArr[1] < H) or
(turnPntBit == "Lo" and valArr[1] > L))) Then
{
valArr[1] = IFF(turnPntBit == "Hi",H,L);
barArr[1] = 0;
turnPntArr[1] = turnPntBit;
If turnPntArr[1][1] <> turnPntArr[1][0] Then
TL1 = TL_New(sDate[barArr[2]],sTime[barArr[2]],valArr[2],
sDate[barArr[1]],sTime[barArr[1]],valArr[1]);
Else
TL_SetEnd(TL1,sDate[barArr[1]],sTime[barArr[1]],valArr[1]);
}
}
TL_SetSize(TL1,4);
TL_SetColor(TL1,GREEN);
input : N(120);
var : sum(0),ii(0),cnt(0),mav(0);
sum = 0;
ii = 0;
for cnt = 1 to 49{
if bararr[cnt] < N Then{
sum = sum + ValArr[cnt];
ii = ii+1;
}
}
mav = sum/ii;
plot1(mav);
즐거운 하루되세요
> 퍼플앙 님이 쓴 글입니다.
> 제목 : 지그재그를 이용한 마디가 구하기
> 항상 회원들의 질문에 성심성의껏 답변 해주셔서 감사합니다.
다름아니라, 첨부파일처럼 지그재그 수식을 이용해서 마디가를 구하고 싶습니다
동그라미 친 부분들이 지그재그 꺽이는 부분인데, 그 꺽이는 부분의 종가들의 평균을 선으로 그어주는걸 만들고 싶습니다.
물론 변수로 봉갯수를 입력할 수 있게 만들어 주시면 감사하겠습니다.
즉, 예를 들면, 변수로 120을 입력하면, 그 기간동안 지그재그로 인해 꺽이는 부분이 4번 있다면, 그 4개 캔들 종가의 평균을 직선으로 표현하고 싶습니다.