커뮤니티
수식문의 드립니다....
2015-12-10 09:59:28
126
글번호 93257
120틱봉에서
1분봉의 macd가 골드가 날때 매수
데드가 날때 매도를 표시할수 있을까요?
또 20일선위에서첫봉이
고점을 치고 2번째봉도 3번째봉도 전고점을 넘지못하고3번째봉부터
5틱내려오면 매수..
또 20일선아래에서첫봉이
저점을 찍고 2번3번째봉도 저점을 깨고 내려가지못하면 3번째봉부터
5틱올라오면 매도.주석도 부탁드립니다....
답변 1
예스스탁 예스스탁 답변
2015-12-10 13:54:55
안녕하세요
예스스탁입니다.
1.
틱봉에서 분봉의 지표는 정확히 계산이 되지 않습니다.
수식에서는 시고저종가만 사용가능한데
틱봉은 봉중간에 분봉의 시간경계가 있을 경우가 많습니다.
아래식이 가장 근접하게 작성된 식입니다.
Input : N(10),Period1(12),Period2(26),Period3(9);
Var : Ep1(0), JISU1(0), DINDEX1(0), PreJISU1(0);
Var : Ep2(0), JISU2(0), PreJISU2(0);
Var : Ep3(0), JISU3(0), PreMACDSIG(0),TF(0);
var : MACDVal(0),MACDSig(0);
Ep1 = 2/(Period1+1);
Ep2 = 2/(Period2+1);
Ep3 = 2/(Period3+1);
TF = TimeToMinutes(stime);
if date != date[1] or (date == date[1] and TF > TF[1]) Then{
DINDEX1 = DINDEX1 + 1;
PreJISU1 = JISU1[1];
PreJISU2 = JISU2[1];
PreMACDSIG = MACDSIG[1];
}
if DINDEX1 <= 1 then {
JISU1 = C;
JISU2 = C;
}
else{
JISU1 = C * EP1 + PreJISU1 * (1-EP1);
JISU2 = C * EP2 + PreJISU2 * (1-EP2);
}
MACDVal = JiSu1-Jisu2;
if DINDEX1 <= 2 then {
MACDSIG = Jisu1-jisu2;
}
else{
MACDSIG = MACDVal * EP3 + PreMACDSIG * (1-EP3);
}
if crossup(MACDVal,MACDsig) Then
buy("매수");
if CrossDown(MACDVal,MACDsig) Then
sell("매도");
2.
var : upi(0),upv(0),dni(0),dnv(0),T(0),HH(0),LL(0);
var1 = ma(c,20);
#골든크로스 발생하면
#T는 1
#고가저장
#골드구간 봉수는 초기화 0
if T <= 0 and crossup(C,var1) Then{
T = 1;
HH = H;
upi = 0;
}
#데드크로스 발생하면
#T는 -1
#저가저장
#데드구간 봉수는 초기화 0
if T >= 0 and CrossDown(C,var1) Then{
T = -1;
LL = L;
dni = 0;
}
#골드구간
if T == 1 Then{
#봉수 1씩 증가
upi = upi+1;
#3번째 봉이고 현재봉 고가와 전봉고가가 골드봉 고가보다 작으면
#T는 2
#upv에 종가저장
if upi == 3 and H < HH and H[1] < HH Then{
T = 2;
upv = C;
}
}
#데드구간
if T == -1 Then{
#봉수 1씩 증가
dni = dni+1;
#3번째 봉이고 현재봉 저가와 전봉저가가 데드봉 저가보다 작으면
#T는 -2
#dnv에 종가저장
if dni == 3 and L > LL and L[1] > LL Then{
T = -2;
dnv = C;
}
}
#T는 2이고 upv보다 3틱이상 하락하면 매수
if T == 2 and CrossDown(C,upv-PriceScale*3) Then
buy("매수");
#T는 -2이고 dnv보다 3틱이상 상승하면 매도
if T == -2 and CrossUp(C,dnv+PriceScale*3) Then
sell("매도");
즐거운 하루되세요
> 고구미 님이 쓴 글입니다.
> 제목 : 수식문의 드립니다....
> 120틱봉에서
1분봉의 macd가 골드가 날때 매수
데드가 날때 매도를 표시할수 있을까요?
또 20일선위에서첫봉이
고점을 치고 2번째봉도 3번째봉도 전고점을 넘지못하고3번째봉부터
5틱내려오면 매수..
또 20일선아래에서첫봉이
저점을 찍고 2번3번째봉도 저점을 깨고 내려가지못하면 3번째봉부터
5틱올라오면 매도.주석도 부탁드립니다....
다음글
이전글