커뮤니티
문의드립니다
2015-11-06 12:49:30
157
글번호 92135
안녕하세요
문의드립니다
1. 현재의 틱봉에서 m분의 RSI 지표를 갭보정 표시할 수 있다면 지표 수식 부탁드립니다.
2. 역시 갭보정이고, RSI 기본수치로 침체구간25에 진입하면 1계약 매수하여 n틱 수익청산을 기본으로 a틱 하락하면 1개 추가 매수하여 x회까지 매수하되 x+1 회에서는 전량손절하는 시스템식 부탁합니다.
(매도는 반대개념이고 과열은 75에 진입할때 입니다)
감사합니다
답변 1
예스스탁 예스스탁 답변
2015-11-06 14:19:12
안녕하세요
예스스탁입니다.
1.
틱봉 차트에서 분봉차트의 지표는
정확히 계산할수 없습니다.
아래 수식이 가장 가깝게 게산해서 값 리턴하는 식입니다.
이용에 참고하시기 바랍니다.
Inputs: nTime(5), Length(14);
input : sig(10);
var : SigSum(0),count2(0),RSIsig(0);
Var : Counter(0), DownAmt(0), UpAmt(0), UpSum(0), DownSum(0), UpAvg(0), DownAvg(0);
var : Dindex(0), PreUpAvg(0), preDownAvg(0),cnt1(0),TF(0);
Array : CC[100](0),RSIV[100](0);
var : sumGap(0), gap(0), GO(0), GH(0), GL(0), GC(0);
if date!=date[1] then {
gap = Open-Close[1];
sumGap = sumGap+gap;
}
GO = O - sumGap;
GH = H - sumGap;
GL = L - sumGap;
GC = C - sumGap;
TF = TimeToMinutes(stime)%nTime;
if date != date[1] or (date == date[1] and TF < TF[1]) Then{
for cnt1 = 1 to 99{
CC[cnt1] = CC[cnt1-1][1];
RSIV[cnt1] = RSIV[cnt1-1][1];
}
PreUpAvg = UpAvg[1];
preDownAvg = DownAvg[1];
Dindex = dindex + 1;
}
CC[0] = GC;
If Dindex == Length Then Begin
UpSum = 0;
DownSum = 0;
For Counter = 0 To Length - 1 Begin
UpAmt = GC[Counter] - GC[Counter+1];
If UpAmt >= 0 Then
DownAmt = 0;
Else Begin
DownAmt = -UpAmt;
UpAmt = 0;
End;
UpSum = UpSum + UpAmt;
DownSum = DownSum + DownAmt;
End;
UpAvg = UpSum / Length;
DownAvg = DownSum / Length;
End
If Dindex > Length Then {
UpAmt = CC[0]-Cc[1];
If UpAmt >= 0 Then
DownAmt = 0;
Else
{
DownAmt = -UpAmt;
UpAmt = 0;
}
if Dindex <=1 Then {
UpAvg = 1;
DownAvg = 1;
}
Else {
UpAvg = (PreUpAvg * (Length - 1) + UpAmt) / Length;
DownAvg = (preDownAvg * (Length - 1) + DownAmt) / Length;
}
}
If UpAvg + DownAvg <> 0 Then
RSIv[0] = 100 * UpAvg / (UpAvg + DownAvg);
Else
RSIv[0] = 0;
SigSum = 0;
for count2 = 0 to sig-1{
SigSum = SigSum+RSIv[count2];
}
RSIsig = SigSum/Sig;
plot1(RSIv[0],"RSI");
PlotBaseLine1(30);
PlotBaseLine2(70);
2,
추가진입을 하는 식이므로 식 적용시에
시스템 트레이딩 설정창의 피라미딩 탭에서
피라미딩을 모든진입신호 허용으로 설정하고 적용하시면 됩니다.
Input : Period(14),수익틱수(10),최대진입횟수(5),추가진입틱수(5);
var : RSIV(0);
RSIV = RSI(Period);
if MarketPosition <= 0 and CrossDown(RSIV,25) Then{
buy("b1",OnClose,def,1);
}
if MarketPosition == 1 Then{
exitlong("BP",atlimit,AvgEntryPrice+PriceScale*수익틱수);
if CurrentEntries < 최대진입횟수 Then
buy("bb",atlimit,LatestEntryPrice(0)-PriceScale*추가진입틱수,1);
if CurrentEntries == 최대진입횟수 Then
ExitLong("BL",atlimit,LatestEntryPrice(0)-PriceScale*추가진입틱수);
}
if MarketPosition >= 0 and Crossup(RSIV,75) Then{
sell("s1",OnClose,def,1);
}
if MarketPosition == -1 Then{
ExitShort("SP",atlimit,AvgEntryPrice-PriceScale*수익틱수);
if CurrentEntries < 최대진입횟수 Then
sell("ss",atlimit,LatestEntryPrice(0)+PriceScale*추가진입틱수,1);
if CurrentEntries == 최대진입횟수 Then
ExitShort("SL",atlimit,LatestEntryPrice(0)+PriceScale*추가진입틱수);
}
즐거운 하루되세요
> 쿠루드 님이 쓴 글입니다.
> 제목 : 문의드립니다
> 안녕하세요
문의드립니다
1. 현재의 틱봉에서 m분의 RSI 지표를 갭보정 표시할 수 있다면 지표 수식 부탁드립니다.
2. 역시 갭보정이고, RSI 기본수치로 침체구간25에 진입하면 1계약 매수하여 n틱 수익청산을 기본으로 a틱 하락하면 1개 추가 매수하여 x회까지 매수하되 x+1 회에서는 전량손절하는 시스템식 부탁합니다.
(매도는 반대개념이고 과열은 75에 진입할때 입니다)
감사합니다
다음글
이전글