커뮤니티
부탁 드립니다.
2015-07-06 21:30:00
140
글번호 88057
운영자님~~!
수식작성 노고에 깊이 감사드립니다.
a)10분봉 차트에서 (유로화 기준)
1)10분봉의 Bollinger Bands
2)60분봉으로계산되는 Bollinger Bands
3)120분봉으로계산되는 Bollinger Bands
4)일봉으로 계산되는 Bollinger Bands 를
10분봉 차트에서 동시에 구현 하고 싶을때의 지표식과 변수값 부탁 드립니다
미리 감사드리오며 경배 올립니다.
답변 1
예스스탁 예스스탁 답변
2015-07-07 09:19:20
안녕하세요
예스스탁입니다.
input : Atime1(60),Atime2(120);
input : Period(20),dv(2);
var : cnt(0),TM(0);
var : mav1(0),BBup1(0),BBdn1(0);
var : TF2(0),sum2(0),mav2(0),SumSqrt2(0),Stdv2(0),BBup2(0),BBdn2(0);
var : TF3(0),sum3(0),mav3(0),SumSqrt3(0),Stdv3(0),BBup3(0),BBdn3(0);
var : TF4(0),sum4(0),mav4(0),SumSqrt4(0),Stdv4(0),BBup4(0),BBdn4(0);
var : sum5(0),mav5(0);
Array : C2[130](0),C3[130](0),C4[130](0);
if bdate != Bdate[1] Then
var1 = stime;
if date != date[1] Then
var2 = TM[1];
if stime >= var1 Then
TM = TimeToMinutes(stime)-TimeToMinutes(var1);
Else
TM = TimeToMinutes(stime)+var2;
TF2 = TM%Atime1;
TF3 = TM%Atime2;
if Bdate != Bdate[1] or (Bdate == Bdate[1] and TF2 < TF2[1]) Then{
for cnt = 1 to 129{
C2[cnt] = C2[cnt-1][1];
}
}
C2[0] = C;
if Bdate != Bdate[1] or (Bdate == Bdate[1] and TF3 < TF3[1]) Then{
for cnt = 1 to 129{
C3[cnt] = C3[cnt-1][1];
}
}
C3[0] = C;
BBup1 = BollBandUp(Period,dv);
BBdn1 = BollBandDown(Period,dv);
plot1(BBup1,"기본차트 볼밴상단");
plot2(BBdn1,"기본차트 볼밴하단");
if C2[Period-1] > 0 then{
sum2 = 0;
for cnt = 0 to Period-1{
sum2 = sum2+C2[cnt];
}
mav2 = sum2/Period;
SumSqrt2 = 0;
For cnt = 0 To Period - 1 {
SumSqrt2 = SumSqrt2 + (C2[cnt] - mav2) * (C2[cnt] - mav2);
}
Stdv2 = SquareRoot(SumSqrt2/ Period);
BBup2 = mav2+stdv2*dv;
BBdn2 = mav2-stdv2*dv;
plot3(BBup2,"Atime1 볼밴상단");
plot4(BBdn2,"Atime1 볼밴하단");
}
if C3[Period-1] > 0 then{
sum3 = 0;
for cnt = 0 to Period-1{
sum3 = sum3+C3[cnt];
}
mav3 = sum3/Period;
SumSqrt3 = 0;
For cnt = 0 To Period - 1 {
SumSqrt3 = SumSqrt3 + (C3[cnt] - mav3) * (C3[cnt] - mav3);
}
Stdv3 = SquareRoot(SumSqrt3/ Period);
BBup3 = mav3+stdv3*dv;
BBdn3 = mav3-stdv3*dv;
plot5(BBup3,"Atime2 볼밴상단");
plot6(BBdn3,"Atime2 볼밴하단");
}
if DayClose(Period-1) > 0 then{
sum4 = 0;
for cnt = 0 to Period-1{
sum4 = sum4+DayClose(cnt);
}
mav4 = sum4/Period;
SumSqrt4 = 0;
For cnt = 0 To Period - 1 {
SumSqrt4 = SumSqrt4 + (DayClose(cnt) - mav4) * (DayClose(cnt) - mav4);
}
Stdv4 = SquareRoot(SumSqrt4/ Period);
BBup4 = mav4+stdv4*dv;
BBdn4 = mav4-stdv4*dv;
plot7(BBup4,"일봉 볼밴상단");
plot8(BBdn4,"일봉 볼밴하단");
}
즐거운 하루되세요
> yes 님이 쓴 글입니다.
> 제목 : 부탁 드립니다.
> 운영자님~~!
수식작성 노고에 깊이 감사드립니다.
a)10분봉 차트에서 (유로화 기준)
1)10분봉의 Bollinger Bands
2)60분봉으로계산되는 Bollinger Bands
3)120분봉으로계산되는 Bollinger Bands
4)일봉으로 계산되는 Bollinger Bands 를
10분봉 차트에서 동시에 구현 하고 싶을때의 지표식과 변수값 부탁 드립니다
미리 감사드리오며 경배 올립니다.
이전글