커뮤니티
부탁 드립니다.
2015-06-30 15:14:59
134
글번호 87820
운영자님~~!
안녕하세요?
무더운 여름 장마철에
노고에 감사드립니다.
신기한 수식들은 마치 요술 방망이를 보는 듯한
느낌 입니다.
42688번 문의한 사항과 같이 동일 유형으로
3가지 추가 부탁 드리고자 합니다.
1)Stochastics
2)MFI(Money Flow Index)
3)이평선(60,120선)
상기 3가지 지표를 (예를 든다면) 1분봉 차트에서 10분봉의 지표를 나타내고 싶습니다.
노고에 감사 드리오며
경배 올립니다.
답변 1
예스스탁 예스스탁 답변
2015-06-30 18:21:21
안녕하세요
예스스탁입니다.
1.
input : Atime1(10),StoPeriod(5), StoPeriod1(3), StoPeriod2(3);
var : TF1(0),TF2(0),Ep1(0), EP2(0),cnt(0);
var : hVal1(0), lVal1(0), StoFastK(0), StoK(0), StoD(0);
var : JISU(0), DINDEX(0), PreStoK(0), PreStoD(0);
Array : H1[50](0),L1[50](0);
TF1 = TimeToMinutes(stime)%Atime1;
Ep1 = 2/(StoPeriod1+1);
Ep2 = 2/(StoPeriod2+1);
if dayindex == 0 or (TF1 < TF1[1] and stime > stime[1]) or stime >= 151500 Then{
H1[0] = H;
L1[0] = L;
for cnt = 1 to 49{
H1[cnt] = H1[cnt-1][1];
L1[cnt] = L1[cnt-1][1];
}
DINDEX = DINDEX + 1;
PreStoK = StoK[1];
PreStoD = StoD[1];
}
if H > H1[0] Then
H1[0] = H;
if L < L1[0] Then
L1[0] = L;
hVal1 = H1[0];
lVal1 = L1[0];
for cnt = 0 to StoPeriod-1 {
if H1[cnt] > hVal1 then
hVal1 = H1[cnt];
if L1[cnt] < lval1 then
LVal1 = L1[cnt];
}
StoFastK = (C-lVal1)/(hVal1-lVal1)*100;
if DINDEX <= 1 then{
StoK = StoFastK ;
StoD = StoK ;
}
else{
StoK = StoFastK * EP1 + PreStoK * (1-EP1);
StoD = StoK * EP2 + PreStoD * (1-EP2);
}
plot1(StoK);
plot2(StoD);
PlotBaseLine1(20);
PlotBaseLine2(80);
2.
Input :Atime(10),Period(14);
var : TF(0),MFIv(0),cnt(0),sum1(0),sum2(0);
Array : HH[100](0),LL[100](0),CC[100](0),Vv[100](0);
Array : val1[100](0),val2[100](0),val3[100](0),val4[100](0);
TF = TimeToMinutes(stime)%Atime;
if dayindex() == 0 or (TF < TF[1] and stime > stime[1]) or stime >= 151500 Then{
HH[0] = H;
LL[0] = L;
VV[0] = 0;
for cnt = 1 to 99{
HH[cnt] = HH[cnt-1][1];
LL[cnt] = LL[cnt-1][1];
CC[cnt] = CC[cnt-1][1];
val1[cnt] = val1[cnt-1][1];
val2[cnt] = val2[cnt-1][1];
val3[cnt] = val3[cnt-1][1];
val4[cnt] = val4[cnt-1][1];
}
}
CC[0] = C;
if H > HH[0] Then
HH[0] = H;
if L < LL[0] Then
LL[0] = L;
VV[0] = VV[0]+V;
val1[0] = HH[0] + LL[0] + CC[0];
val4[0] = VV[0] * Val1[0]/ 3;
if val1[0] > val1[1] then
val2[0] = val4[0];
else
val2[0] = 0;
if val1[0] < val1[1] then
val3[0] = val4[0];
else
val3[0] = 0;
if CC[Period-1] > 0 Then{
sum1 = 0;
sum2 = 0;
for cnt = 0 to Period-1{
sum1 = sum1+val2[cnt];
sum2 = sum2+val3[cnt];
}
MFIv = 100 - 100 / (1 + (sum1/sum2));
plot1(MFIv);
PlotBaseLine1(20, "하단기준선");
PlotBaseLine2(80, "상단기준선");
}
3.
input : Atime(30),P1(60),P2(120);
var : TF(0),cnt(0),sum1(0),mav1(0),sum2(0),mav2(0);
Array : CC[130](0);
TF = TimeToMinutes(stime)%Atime;
if dayindex() == 0 or (TF < TF[1] and stime > stime[1]) or stime >= 151500 Then{
for cnt = 1 to 99{
CC[cnt] = CC[cnt-1][1];
}
}
CC[0] = C;
if CC[P1-1] > 0 then{
sum1 = 0;
for cnt = 0 to P1-1{
sum1 = sum1+CC[cnt];
}
mav1 = sum1/P1;
plot1(mav1);
}
if CC[P2-1] > 0 then{
sum2 = 0;
for cnt = 0 to P2-1{
sum2 = sum2+CC[cnt];
}
mav2 = sum2/P2;
plot2(mav2);
}
즐거운 하루되세요
> yes 님이 쓴 글입니다.
> 제목 : 부탁 드립니다.
> 운영자님~~!
안녕하세요?
무더운 여름 장마철에
노고에 감사드립니다.
신기한 수식들은 마치 요술 방망이를 보는 듯한
느낌 입니다.
42688번 문의한 사항과 같이 동일 유형으로
3가지 추가 부탁 드리고자 합니다.
1)Stochastics
2)MFI(Money Flow Index)
3)이평선(60,120선)
상기 3가지 지표를 (예를 든다면) 1분봉 차트에서 10분봉의 지표를 나타내고 싶습니다.
노고에 감사 드리오며
경배 올립니다.
다음글
이전글