커뮤니티
수식 부탁드려요.
2015-06-24 09:49:58
114
글번호 87586
예를들어 MACD 가 MACD Signal 선을 골든크로스 했을때.
1번 수식
2계약 진입.
1계약은 진입 후 20틱 수익일때 청산
나머지 1계약은
30틱 수익후 10틱으로 내려오면 청산
40틱 수익후 15틱으로 내려오면 청산
50틱 수익후 20틱으로 내려오면 청산
2번 수식
프라이스 채널 지표를 이용했을때
프라이스채널 상단을 터치하고 다음봉 음봉으로 전환되면 매도 진입.
반대로 하단을 터치하고 양봉으로 전환되면 매수진입.
* 그리고 매수 매도 진입시 진입명을 정할 수 있는데.
진입한 진입가도 표시되게 할 수 있는 방법좀 부탁드립니다.
항상 감사합니다.
답변 1
예스스탁 예스스탁 답변
2015-06-24 14:32:19
안녕하세요
예스스탁입니다.
1.
Input : short(12), long(26), sig(9);
Var : MACDv(0), MACDs(0);
MACDv = MACD(short, long);
MACDs = ema(MACDv,sig);
if crossup(MACDv,MACDs) Then{
buy("b",OnClose,def,2);
if MarketPosition <=0 Then
Text_New(sdate,stime,H+PriceScale*2,NumToStr(c,2));
}
if CrossDown(MACDv,MACDs) Then{
sell("s",OnClose,def,2);
if MarketPosition >=0 Then
Text_New(sdate,stime,L-PriceScale*2,NumToStr(c,2));
}
if MarketPosition == 1 Then{
var1 = highest(H,BarsSinceEntry);
exitlong("bx1",AtStop,EntryPrice+PriceScale*20,"",1,1);
if var1 >= EntryPrice+PriceScale*30 and var1 < EntryPrice+PriceScale*40 Then
ExitLong("bx21",AtStop,EntryPrice+PriceScale*10);
if var1 >= EntryPrice+PriceScale*40 and var1 < EntryPrice+PriceScale*50 Then
ExitLong("bx22",AtStop,EntryPrice+PriceScale*15);
if var1 >= EntryPrice+PriceScale*50 Then
ExitLong("bx23",AtStop,EntryPrice+PriceScale*20);
}
if MarketPosition == -1 Then{
var2 = Lowest(L,BarsSinceEntry);
ExitShort("sx1",AtStop,EntryPrice-PriceScale*20,"",1,1);
if var2 <= EntryPrice-PriceScale*30 and var2 > EntryPrice-PriceScale*40 Then
ExitShort("sx21",AtStop,EntryPrice-PriceScale*10);
if var2 <= EntryPrice-PriceScale*40 and var2 > EntryPrice-PriceScale*50 Then
ExitShort("sx22",AtStop,EntryPrice-PriceScale*15);
if var2 <= EntryPrice-PriceScale*50 Then
ExitShort("sx23",AtStop,EntryPrice-PriceScale*20);
}
2.
INPUT : LENGTH(10),N(2);
VAR : TCHAN(0), BCHAN(0);
TCHAN = HIGHEST(HIGH, LENGTH)[1];
BCHAN = LOWEST(LOW, LENGTH)[1];
if C[1] < O[1] and C >= TCHAN Then{
sell("매도");
if MarketPosition <=0 Then
Text_New(sdate,stime,H+PriceScale*2,NumToStr(c,2));
}
if C[1] > O[1] and C <= BCHAN Then{
buy("매수");
if MarketPosition >=0 Then
Text_New(sdate,stime,L-PriceScale*2,NumToStr(c,2));
}
3
진입가는 따로 설정에서 출력되게 지정이 되지 않습니다.
수식안에서 텍스트 출력함수를 이용해 출력해야 합니다.
위 수식에 진입가가 표시되게 텍스트함수로 지정되었습니다.
즐거운 하루되세요
> 찬찬히 님이 쓴 글입니다.
> 제목 : 수식 부탁드려요.
> 예를들어 MACD 가 MACD Signal 선을 골든크로스 했을때.
1번 수식
2계약 진입.
1계약은 진입 후 20틱 수익일때 청산
나머지 1계약은
30틱 수익후 10틱으로 내려오면 청산
40틱 수익후 15틱으로 내려오면 청산
50틱 수익후 20틱으로 내려오면 청산
2번 수식
프라이스 채널 지표를 이용했을때
프라이스채널 상단을 터치하고 다음봉 음봉으로 전환되면 매도 진입.
반대로 하단을 터치하고 양봉으로 전환되면 매수진입.
* 그리고 매수 매도 진입시 진입명을 정할 수 있는데.
진입한 진입가도 표시되게 할 수 있는 방법좀 부탁드립니다.
항상 감사합니다.
다음글
이전글