커뮤니티
문의드립니다
2015-05-13 22:42:14
135
글번호 86010
안녕하세요
예스글로벌 해외선물에서
1.60분봉에 240분과 일봉의 볼린저밴드 나타내는식:(H+L+C)/3 적용
2.60분봉에 240분의 MA(C,100)와 MA(C,200)표시하는식:
부탁드립니다.
답변 1
예스스탁 예스스탁 답변
2015-05-14 13:46:25
안녕하세요
예스스탁입니다.
1-1
input : P(20),dv(2);
var : T(0),T1(0),T2(0),TF(0),TFF(0);
var : cnt(0),bbup(0),bbdn(0);
var : sum(0),mav(0),SumSqrt(0),Stdv(0);
Array : CC[100](0),HH[100](0),LL[100](0);
if T == 1 and date != date[1] Then{
T = 2;
T2 = TF;
}
if bdate != Bdate[1] Then{
T = 1;
T1 = TimeToMinutes(stime);
}
if T == 1 Then
TF = TimeToMinutes(stime)-T1;
Else
TF = TimeToMinutes(stime)+T2;
TFF = TF%240;
if Bdate != Bdate or (TFF < TFF[1]) Then{
HH[0] = H;
LL[0] = L;
for cnt = 0 to 99{
CC[cnt] = CC[cnt-1][1];
HH[cnt] = HH[cnt-1][1];
LL[cnt] = LL[cnt-1][1];
}
}
CC[0] = C;
if H > HH[0] Then
HH[0] = H;
if L < LL[0] Then
LL[0] = L;
if CC[P-1] > 0 Then{
sum = 0;
for cnt = 0 to P-1{
sum = sum+CC[cnt];
}
mav = sum/P;
SumSqrt = 0;
For cnt = 0 To P - 1 {
SumSqrt = SumSqrt + (CC[cnt] - mav) * (CC[cnt] - mav);
}
Stdv = SquareRoot(SumSqrt / P);
BBup = mav+stdv*dv;
BBdn = mav-stdv*dv;
plot1(bbup);
plot2(mav);
plot3(bbdn);
}
1-2.일봉볼밴
input : Period(20),Dv(2);
var : sum(0),cnt(0),mav(0),SumSqrt(0),Stdv(0);
var : BBup(0),BBdn(0);
sum = 0;
for cnt = 0 to Period-1{
sum = sum + (DayHigh(cnt)+DayLow(cnt)+DayClose(cnt))/3;
}
mav = sum/Period;
#표준편차 계산
SumSqrt = 0;
For cnt = 0 To Period - 1 {
SumSqrt = SumSqrt + ((DayHigh(cnt)+DayLow(cnt)+DayClose(cnt))/3 - mav)^2;
}
Stdv = SquareRoot(SumSqrt / Period);
# 일봉 볼린져밴드 계산
BBup = mav + (Dv * Stdv);
BBdn = mav - (Dv * Stdv);
plot1(BBup ,"상단");
plot2(mav,"중단");
plot3(BBdn,"하단");
2
input : P1(100),P2(200);
var : T(0),T1(0),T2(0),TF(0),TFF(0);
var : cnt(0),sum1(0),mav1(0),sum2(0),mav2(0);
Array : CC[250](0);
if T == 1 and date != date[1] Then{
T = 2;
T2 = TF;
}
if bdate != Bdate[1] Then{
T = 1;
T1 = TimeToMinutes(stime);
}
if T == 1 Then
TF = TimeToMinutes(stime)-T1;
Else
TF = TimeToMinutes(stime)+T2;
TFF = TF%240;
if Bdate != Bdate or (TFF < TFF[1]) Then{
for cnt = 0 to 249{
CC[cnt] = CC[cnt-1][1];
}
}
CC[0] = C;
if CC[P1-1] > 0 Then{
sum1 = 0;
for cnt = 0 to P1-1{
sum1 = sum1+CC[cnt];
}
mav1 = sum1/P1;
plot1(mav1);
}
if CC[P2-1] > 0 Then{
sum2 = 0;
for cnt = 0 to P2-1{
sum2 = sum2+CC[cnt];
}
mav2 = sum2/P2;
plot2(mav2);
}
즐거운 하루되세요
> 뉴스타트 님이 쓴 글입니다.
> 제목 : 문의드립니다
> 안녕하세요
예스글로벌 해외선물에서
1.60분봉에 240분과 일봉의 볼린저밴드 나타내는식:(H+L+C)/3 적용
2.60분봉에 240분의 MA(C,100)와 MA(C,200)표시하는식:
부탁드립니다.