커뮤니티
분봉에 타주기
2015-05-06 22:00:18
190
글번호 85782
검색으로 하면서 고민하가가 올려봅니다
같은 질문처럼 보이는데 답변은 왜 다른지 알수가 없어서 저 역시 올려봅니다
1분봉차트에 이평선 300 나오게
타주기 2분봉차트의 300 이평선이 1분봉차트에 나오게
타주기 2분봉차트의 100 이평선이 1분봉차트에 나오게
타주기 5분봉차트의 300 이평선이 1분봉차트에 나오게
타주기 10분봉차트의 300 이평선이 1분봉차트에 나오게
타주기 30분봉차트의 300 이평선이 1분봉차트에 나오게
부탁합니다
답변 1
예스스탁 예스스탁 답변
2015-05-07 14:33:35
안녕하세요
예스스탁입니다.
차트에서 다른 주기를 지표값을 계산하는 부분은
다른주기의 이평과 차트의 주기를 고려해서 작성되므로 수식이 조금씩 다를수 있습니다.
즉 타주기의 지표를 그리는 내용이 기본틀은 비슷하다고 해도 조금씩 틀리게 되며
계산을 할수 없는 경우도 있습니다.
또한 차트 자체에서 계산하면
차트의 봉수의 제한이 있으므로 (전략실행차트는 최대조회건수가 1만개입니다. 해외선물쪽은 5000개 입니다.)
차트보다 너무 큰 주기의 이평은 봉수 문제로 계산이 되지 않습니다.
올리신 내용에서 보면 10분봉의 300이평이나, 30분봉의 300이평은 계산이 되지 않습니다.
식에는 올리신 각 주기별로 계산하게 올려드립니다.
차트에서 타주기이평을 계산할 만큰 데이터가 충족되지 않으면
해당 이평은 그려지지 않습니다.
input : Atime1(2),Atime2(5),Atime3(10),Atime4(30);
input : P1(100),P2(300);
var : cnt(0),TF1(0),TF2(0),TF3(0),TF4(0);
var : sum11(0),mav11(0);
var : sum12(0),mav12(0);
var : sum2(0),mav2(0);
var : sum3(0),mav3(0);
var : sum4(0),mav4(0);
Array : C1[300](0),C2[300](0),C3[300](0),C4[300](0);
TF1 = TimeToMinutes(stime)%Atime1;
TF2 = TimeToMinutes(stime)%Atime2;
TF3 = TimeToMinutes(stime)%Atime3;
TF4 = TimeToMinutes(stime)%Atime4;
#2분 주기단위로 종가 저장
if dayindex() == 0 or (TF1 < TF1[1] and stime > stime[1]) Then{
for cnt = 1 to 299{
C1[cnt] = C1[cnt-1][1];
}
}
C1[0] = C;
#5분 주기단위로 종가 저장
if dayindex() == 0 or (TF2 < TF2[1] and stime > stime[1]) Then{
for cnt = 1 to 299{
C2[cnt] = C2[cnt-1][1];
}
}
C2[0] = C;
#10분 주기단위로 종가 저장
if dayindex() == 0 or (TF3 < TF3[1] and stime > stime[1]) or stime == 151500 Then{
for cnt = 1 to 299{
C3[cnt] = C3[cnt-1][1];
}
}
C3[0] = C;
#30분 주기단위로 종가 저장
if dayindex() == 0 or (TF4 < TF4[1] and stime > stime[1]) Then{
for cnt = 1 to 299{
C4[cnt] = C4[cnt-1][1];
}
}
C4[0] = C;
if C1[P1-1] > 0 Then{
sum11 = 0;
for cnt = 0 to P1-1{
sum11 = sum11+C1[cnt];
}
mav11 = sum11/P1;
plot1(mav11,"2분100이평");
}
if C1[P2-1] > 0 Then{
sum12 = 0;
for cnt = 0 to P2-1{
sum12 = sum12+C1[cnt];
}
mav12 = sum12/P2;
plot2(mav12,"2분300이평");
}
if C2[P2-1] > 0 Then{
sum2 = 0;
for cnt = 0 to P2-1{
sum2 = sum2+C2[cnt];
}
mav2 = sum2/P2;
plot3(mav2,"5분300이평");
}
if C3[P2-1] > 0 Then{
sum3 = 0;
for cnt = 0 to P2-1{
sum3 = sum3+C3[cnt];
}
mav3 = sum3/P2;
plot4(mav3,"10분300이평");
}
if C4[P2-1] > 0 Then{
sum4 = 0;
for cnt = 0 to P2-1{
sum4 = sum4+C4[cnt];
}
mav4 = sum4/P2;
plot5(mav4,"30분300이평");
}
즐거운 하루되세요
> 효효효효효 님이 쓴 글입니다.
> 제목 : 분봉에 타주기
> 검색으로 하면서 고민하가가 올려봅니다
같은 질문처럼 보이는데 답변은 왜 다른지 알수가 없어서 저 역시 올려봅니다
1분봉차트에 이평선 300 나오게
타주기 2분봉차트의 300 이평선이 1분봉차트에 나오게
타주기 2분봉차트의 100 이평선이 1분봉차트에 나오게
타주기 5분봉차트의 300 이평선이 1분봉차트에 나오게
타주기 10분봉차트의 300 이평선이 1분봉차트에 나오게
타주기 30분봉차트의 300 이평선이 1분봉차트에 나오게
부탁합니다