커뮤니티
문의드립니다.
2013-06-13 17:15:52
192
글번호 64304
항상 감사드립니다.
일목균형표를 분봉(3분봉이나 5분봉 등)에서 30분봉을 구현하고 식을 알려주셨으면 합니다.
감사합니다.
답변 1
예스스탁 예스스탁 답변
2013-06-14 11:31:12
안녕하세요
예스스탁입니다.
30분봉의 일목균형표의 각 값을 그리는 지표식은 아래와 같습니다.
일목균형표의 경우 선핸스팬1,2는 값을 25개봉 전진한 값이므로
현재봉의 값은 25개봉전 값입니다.
해당 부분은 수식으로 30분봉상 25개전봉값을 그리게 하면 되는데
후행스팬과 같은 경우는 현재봉 종가를 과거로 25개봉 전으로
후퇴를 시켜하 하는데 해당 부분은 수식으로 가능하지 않습니다.
사용자분이 사용하는 주기에서 30분봉으로 25개봉에 해당하는 봉갯수를
산정해서 속성화면의 이동에 넣어주셔야만 합니다.
Inputs: P1(9), P2(26), P3(52);
Var : 기준선(0), 전환선(0),선행스팬1(0),선행스팬2(0),cnt(0);
var : H9(0),L9(0),H26(0),L26(0),H52(0),L52(0);
Array : HH[100](0),LL[100](0),pre1[100](0),Pre2[100](0);
var1 = TimeToMinutes(stime)%30;
if dayindex == 0 or (var1 < var1[1] and stime > stime[1]) Then{
HH[0] = H;
LL[0] = L;
for cnt = 1 to 99{
HH[cnt] = HH[cnt-1][1];
LL[cnt] = LL[cnt-1][1];
pre1[cnt] = pre1[cnt-1][1];
pre2[cnt] = pre2[cnt-1][1];
}
}
if H > HH[0] Then
HH[0] = H;
if L < LL[0] Then
LL[0] = L;
H9 = HH[0];
L9 = LL[0];
H26 = HH[0];
L26 = LL[0];
H52 = HH[0];
L52 = LL[0];
for cnt = 0 to P3{
if cnt < P1 Then{
if HH[cnt] > H9 Then
H9 = HH[cnt];
if LL[cnt] < L9 Then
L9 = LL[cnt];
}
if cnt < P2 Then{
if HH[cnt] > H26 Then
H26 = HH[cnt];
if LL[cnt] < L26 Then
L26 = LL[cnt];
}
if cnt < P3 Then{
if HH[cnt] > H52 Then
H52 = HH[cnt];
if LL[cnt] < L52 Then
L52 = LL[cnt];
}
}
전환선 = (H9 + L9) / 2;
기준선 = (H26 + L26) / 2;
Pre1[0] = (전환선 + 기준선) / 2;
pre2[0] = (H52 + L52) / 2;
선행스팬1 = Pre1[25];
선행스팬2 = Pre2[25];
Plot1(전환선, "전환선");
Plot2(기준선, "기준선");
Plot3(선행스팬1,"선행스팬1");
Plot4(선행스팬2, "선행스팬2");
Plot5(c, "후행스팬");
즐거운 하루되세요
> 애널박 님이 쓴 글입니다.
> 제목 : 문의드립니다.
> 항상 감사드립니다.
일목균형표를 분봉(3분봉이나 5분봉 등)에서 30분봉을 구현하고 식을 알려주셨으면 합니다.
감사합니다.
다음글