커뮤니티
지표식 작성 문의드립니다.
2013-06-10 18:28:33
208
글번호 64181
틱차트에서 장 종료시 동시호가를 포함한 봉(마지막 봉)을 제외한 data의
지표식을 구하려면 어떻게 해야할까요?
예를 들어 2013년 6월 10일의 장초반에 EMA, stochastics 등의 지표식을 구할 때
6월 7일의 경우 15:04:40에 시작하는 봉(300tick기준)을 제외한
지표값을 구하려면 어떻게 하면 되는지 부탁드립니다.
감사합니다.
답변 1
예스스탁 예스스탁 답변
2013-06-11 10:52:05
안녕하세요
예스스탁입니다.
틱차트에서 동시호가 데이터는 정규장 마지막봉에 포함이 되며
stime은 항상 다르므로 봉의 종가시간(time)을 사용해 처리하시면 됩니다.
마지막봉의 끝시간은 151500입니다.
함수식을 모두 풀어서 작성하셔야 합니다.
1. 지수이동평균
input : Period(20);
var : EP(0),idx(0),JISU(0);
Ep = 2/(Period+1);
if time != 151500 Then{
idx = idx+1;
if idx <= 1 then
JISU = C;
else
JISU = C * EP + JISU * (1-EP);
}
plot1(JISU);
2. 스토케스틱
input : Period1(10),Period2(5),Period3(5);
var : EP1(0),EP2(0),idx(0),JISU(0),cnt(0),Hval(0),Lval(0),FK(0),SK(0),SD(0);
Array : HH[100](0),LL[100](0);
EP1 = 2/(Period2+1);
EP2 = 2/(Period3+1);
if time != 151500 Then{
idx = idx+1;
HH[0] = H;
LL[0] = L;
for cnt = 1 to 49{
HH[cnt] = HH[cnt-1][1];
LL[cnt] = LL[cnt-1][1];
}
hval = HH[0];
lval = LL[0];
for cnt = 0 to Period1-1 {
if HH[cnt] > hval then
hval = HH[cnt];
if LL[cnt] < lval then
lval = LL[cnt];
}
FK = (C-lval)/(hval-lval)*100;
if Idx <= Period1 Then
SK = FK;
Else
SK = FK*EP1 + SK*(1-EP1);
if Idx <= Period1+1 Then
SD = SK;
Else
SD = SK*EP2 + SD*(1-EP2);
}
plot1(SK);
plot2(SD);
PlotBaseLine1(20);
PlotBaseLine2(80);
즐거운 하루되세요
> showtime 님이 쓴 글입니다.
> 제목 : 지표식 작성 문의드립니다.
> 틱차트에서 장 종료시 동시호가를 포함한 봉(마지막 봉)을 제외한 data의
지표식을 구하려면 어떻게 해야할까요?
예를 들어 2013년 6월 10일의 장초반에 EMA, stochastics 등의 지표식을 구할 때
6월 7일의 경우 15:04:40에 시작하는 봉(300tick기준)을 제외한
지표값을 구하려면 어떻게 하면 되는지 부탁드립니다.
감사합니다.