커뮤니티
문의
2013-05-22 16:29:06
236
글번호 63490
조건 1. 10000원(INPUT)이하 9000원(INPUT)이상 진입후 5개봉(INPUT)이 유지되었을때
1차 매수신호 발생
조건 2. 1차 매수가격 대비 5%(INPUT)하락시 2차 매수신호 발생/추가매수
(단, 매수시 지정금액(50만원)(INPUT)만큼..)
조건 3. 1/2차 매수신호 발생 이후 10%(INPUT)하락시 손절
조건 4. 매수가 대비 3%(INPUT)이상 5%(INPUT)이하 상승후 익절없이 하락
매수가 도달시 전량매도
조건 5. 매수가 대비 5%(INPUT)상승시 절반 익절
조건 6. 절반 익절후 나머지 최고수익대비 50%하락시 전량매도
(예시-5%상승시 절반 매도후 추가상승없이 2.5%하락시 전량매도)
(예시-5%상승시 절반 매도후 10%추가 상승후(총15%) 7.5%하락시 전량매도)
조건 7. 특정가격(INPUT)(9500원) 이하 하락시 전량매도(강제손절)
단, 미지정(0으로 지정)시 신호발생없을것.
#시스템매매 조건설정후 실행시 10000원/9000원으로 설정된 가격영역을
차트에 반영할수 있는지요??(가로수평선 및 영역색상부여 가능한지요??)
시스템에 포함되면 매매실행때마다 지정한 가격만큼 영역대가 생성될듯한데..
답변 1
예스스탁 예스스탁 답변
2013-05-23 10:17:26
안녕하새요
예스스탁입니다.
input : 최초투입금액(500000),추가투입금액(500000),지정가격손절(9500);
input : UpPrice(10000),DnPrice(9000),Nbars(5),addPer(5),loss(10),P1(3),P2(5),Profit(5);
var : Vol1(0),vol2(0),Xvol(0);
if CodeCategory == 1 Then #코스피
{
if BasePrice < 50000 Then
{
vol1 = int(int((최초투입금액)/C)/10)*10;
vol2 = int(int((추가투입금액*0.5)/C)/10)*10;
}
Else
{
Vol1 = int((최초투입금액)/C);
Vol2 = int((추가투입금액*0.5)/C);
}
}
if CodeCategory == 2 Then#코스닥
{
Vol1 = int((최초투입금액)/C);
Vol2 = int((추가투입금액*0.5)/C);
}
if MarketPosition == 0 and countif(UpPrice > C and C > DnPrice,Nbars) == Nbars Then
buy("매수",OnClose,def,vol1);
if MarketPosition == 1 Then{
if CodeCategory == 1 Then
{
if BasePrice < 50000 Then
xvol = int(int(MaxContracts*0.5)/10)*10;
Else
XVol = int(MaxContracts*0.5);
}
if CodeCategory == 2 Then
XVol = int(MaxContracts*0.5);
if CurrentContracts == MaxContracts and MaxEntries == 1 Then{
buy("추가매수",atlimit,EntryPrice*(1-addPer/100),vol2);
}
exitlong("손절",AtStop,EntryPrice*(1-Loss/100));
if highest(H,BarsSinceEntry) >= EntryPrice*(1+P1/100) and
highest(H,BarsSinceEntry) < EntryPrice*(1+P2/100) Then
ExitLong("본절",AtStop,EntryPrice);
if CurrentContracts == MaxContracts Then
exitlong("익절1",Atlimit,EntryPrice*(1+Profit/100),"",Xvol,1);
if CurrentContracts < MaxContracts and highest(h,BarsSinceEntry) >= EntryPrice*(1+Profit/100) Then
exitlong("TR청산",AtStop,highest(H,BarsSinceEntry)-(highest(H,BarsSinceEntry)-EntryPrice)*0.5);
if 지정가격손절 > 0 Then
exitlong("지정가격청산",AtStop,지정가격손절);
}
추가매수 1회 해야하므로 피라미딩을 다른진입신호만 허용으로
설정하고 적용하시면 됩니다.
시스템식 에서는 차트에 그림을 그릴수 없습니다.
아래식 지표식으로 별로 작성해서 차트에 적용하셔야 합합니다.
input : UpPrice(10000),DnPrice(9000);
plot1(upPrice);
plot2(DnPrice);
즐거운 하루되세요
> 메디사 님이 쓴 글입니다.
> 제목 : 문의
> 조건 1. 10000원(INPUT)이하 9000원(INPUT)이상 진입후 5개봉(INPUT)이 유지되었을때
1차 매수신호 발생
조건 2. 1차 매수가격 대비 5%(INPUT)하락시 2차 매수신호 발생/추가매수
(단, 매수시 지정금액(50만원)(INPUT)만큼..)
조건 3. 1/2차 매수신호 발생 이후 10%(INPUT)하락시 손절
조건 4. 매수가 대비 3%(INPUT)이상 5%(INPUT)이하 상승후 익절없이 하락
매수가 도달시 전량매도
조건 5. 매수가 대비 5%(INPUT)상승시 절반 익절
조건 6. 절반 익절후 나머지 최고수익대비 50%하락시 전량매도
(예시-5%상승시 절반 매도후 추가상승없이 2.5%하락시 전량매도)
(예시-5%상승시 절반 매도후 10%추가 상승후(총15%) 7.5%하락시 전량매도)
조건 7. 특정가격(INPUT)(9500원) 이하 하락시 전량매도(강제손절)
단, 미지정(0으로 지정)시 신호발생없을것.
#시스템매매 조건설정후 실행시 10000원/9000원으로 설정된 가격영역을
차트에 반영할수 있는지요??(가로수평선 및 영역색상부여 가능한지요??)
시스템에 포함되면 매매실행때마다 지정한 가격만큼 영역대가 생성될듯한데..