커뮤니티
파라볼릭 수식
2013-04-24 16:48:02
475
글번호 62454
앞전에 전화 통화를 통하여 만들어 주셨던 파라볼릭은 검증을 해보니
파라볼릭 찍을때 수치가 안맞아서 쓰지 못하고 있습니다...
죄송합니다 다시한번 부탁을 드리겠습니다.
파라볼릭 지표식 말고요
파라볼릭을 제작하는 수식을 올려주시면
제가 수정해서 사용하겠습니다..
1. 저는 파라볼릭이 캔들이 찍을때 그위치에 생성되게 해야합니다..
이전봉 가져오는거 말고요.. (이전봉을 가져오면 수치가 파라볼릭 찍을때 수치가 다릅니다)비슷하기라도 해야 하는데요.
정말 중요합니다..
파라볼릭 생성수식을 부탁드립니다..
(예를 들어 캔들이 위에 있는 파라볼릭을 찍으면 파라볼릭과 캔들이 접촉하는곳에 파라볼릭이 생성되고 다음봉에서 믿으로 내려가도록 만들고 싶습니다..)
답변 1
예스스탁 예스스탁 답변
2013-04-24 17:29:11
안녕하세요
예스스탁입니다.
예스랭귀지의 파라볼릭을 포함한 지표함수는
모두 사용자함수로 작성이 되어 있습니다.
사용자함수 클릭하시면 해당 내용 보실수 있습니다.
예스랭귀지 편집기의 파일관리자의 사용자함수탭에서 sar클릭하시면 됩니다.
기본으로 제공되는 사용자함수 자체는 따로 변경이 가능하지 않으므로
해당 내용참고하셔서 다른이름의 함수로 만드셔야 합니다.
sar내용은 아래와 같습니다.
/* Description : Parabolic (S)top (A)nd (R)eversal
*
* Provided By : YesStock Inc. (c) Copyright 2006
* E-Mail : webmaster@yesstock.com
*/
Input : AF(NumericSimple), AFMAX(NumericSimple);
Var : Direction(0), SAR_Value(Close), AF_Value(.02), HighValue(High), LowValue(Low), EP(0);
if EP != 0 Then
{
if Direction == 1 then
{
EP = HighValue;
SAR_Value = SAR_Value + AF_Value * (EP - SAR_Value);
if High > HighValue then
{
HighValue = High;
AF_Value = AF_Value + AF;
if AF_Value >= AFMAX then AF_Value = AFMAX;
}
if Low < SAR_Value then
{
Direction = -1;
SAR_Value = EP;
AF_Value = 0;
EP = 0;
LowValue = low;
}
}
else
{
EP = LowValue;
SAR_Value = SAR_Value + AF_Value * (EP - SAR_Value);
if Low < LowValue then
{
LowValue = Low;
AF_Value = AF_Value + Af;
if AF_Value >= AFMAX then AF_Value = AFMAX;
}
if High > SAR_Value then
{
Direction = 1;
SAR_Value = EP;
AF_Value = 0;
EP = 0;
HighValue = High;
}
}
Sar = SAR_Value;
}
else
{
if SAR_Value != 0 && EP == 0 then
{
if Direction == 1 then
{
EP = HighValue;
AF_Value = AF;
SAR_Value = SAR_Value + AF_Value * (EP - SAR_Value);
if High > HighValue then
{
HighValue = High;
AF_Value = AF_Value + AF;
if AF_Value >= AFMAX then AF_Value = AFMAX;
}
}
else
{
EP = LowValue;
AF_Value = Af;
SAR_Value = SAR_Value + AF_Value * (EP - SAR_Value);
if Low < LowValue then
{
LowValue = Low;
AF_Value = AF_Value + AF;
if AF_Value >= AFMAX then AF_Value = AFMAX;
}
}
Sar = SAR_Value;
}
else
{
if Direction == 0 then
{
if Close > Close[1] then Direction = 1;
else
if Close < Close[1] then Direction = -1;
}
else
{
if Direction == 1 then
{
if Close < Close[1] then
{
Direction = -1;
SAR_Value = HighValue;
Sar = SAR_Value;
}
}
if Direction == -1 then
{
if Close > Close[1] then
{
Direction = 1;
SAR_Value = LowValue;
Sar = SAR_Value;
}
}
}
LowValue = min(Low, LowValue);
HighValue = max(High, HighValue);
}
}
즐거운 하루되세요
> HI_cbk4610 님이 쓴 글입니다.
> 제목 : 파라볼릭 수식
> 앞전에 전화 통화를 통하여 만들어 주셨던 파라볼릭은 검증을 해보니
파라볼릭 찍을때 수치가 안맞아서 쓰지 못하고 있습니다...
죄송합니다 다시한번 부탁을 드리겠습니다.
파라볼릭 지표식 말고요
파라볼릭을 제작하는 수식을 올려주시면
제가 수정해서 사용하겠습니다..
1. 저는 파라볼릭이 캔들이 찍을때 그위치에 생성되게 해야합니다..
이전봉 가져오는거 말고요.. (이전봉을 가져오면 수치가 파라볼릭 찍을때 수치가 다릅니다)비슷하기라도 해야 하는데요.
정말 중요합니다..
파라볼릭 생성수식을 부탁드립니다..
(예를 들어 캔들이 위에 있는 파라볼릭을 찍으면 파라볼릭과 캔들이 접촉하는곳에 파라볼릭이 생성되고 다음봉에서 믿으로 내려가도록 만들고 싶습니다..)
다음글
이전글