커뮤니티
120분봉에서 240분봉 지표 표시
2013-04-18 09:43:15
164
글번호 62195
안녕하세요.
아래와 같은 240분봉 지표를 120분봉 차트에 표시하고 싶습니다.
1. 240분봉 데이타의 StochasticsK(10,5)
2. 240분봉 데이타의 MACD_OSC(12,26,9)
추가로 궁금한 점은 제 질문에 대한 수식을 작성하실때, 120분봉 2개를 1개의 240분봉 데이타로 합쳐서 구현하게 되는것인가요?
부탁 드립니다.
수고하세요.
답변 1
예스스탁 예스스탁 답변
2013-04-18 14:23:18
안녕하세요
예스스탁입니다.
1.
input : Atime(240),StoPeriod(10), StoPeriod1(5), StoPeriod2(5);
var : count(0), highVal(0), lowVal(0), StoFastK(0), StoK(0), StoD(0);
var : Ep(0), EP1(0), JISU(0), DINDEX(0), PreStoK(0), PreStoD(0),cnt(0);
Array : HH[50](0),LL[50](0);
if date != date[1] Then
value1 = TimeToMinutes(stime);
var1 = (TimeToMinutes(stime)-value1)%Atime;
if dayindex == 0 or (var1 < var1[1] and stime > stime[1]) Then{
HH[0] = H;
LL[0] = L;
for cnt = 1 to 49{
HH[cnt] = HH[cnt-1][1];
LL[cnt] = LL[cnt-1][1];
}
}
if H > HH[0] Then
HH[0] = H;
if L < LL[0] Then
LL[0] = L;
highVal = HH[0];
lowVal = LL[0];
for count = 0 to StoPeriod-1 {
if HH[count] > highVal then
highVal = HH[count];
if LL[count] < lowVal then
lowVal = LL[count];
}
StoFastK = (C-lowVal)/(highVal-lowVal)*100;
#### Slow StochasticsK ####
Ep = 2/(StoPeriod1+1);
if DINDEX >= StoPeriod and (date != date[1] or var1 < var1[1]) then {
DINDEX = DINDEX + 1;
PreStoK = StoK[1];
}
if DINDEX <= 1 then
StoK = StoFastK ;
else
StoK = StoFastK * EP + PreStoK * (1-EP);
#### Slow StochasticsD ####
Ep1 = 2/(StoPeriod2+1);
if date != date[1] or var1 < var1[1] then {
DINDEX = DINDEX + 1;
PreStoD = StoD[1];
}
if DINDEX <= 1 then
StoD = StoK ;
else
StoD = StoK * EP1 + PreStoD * (1-EP1);
plot1(StoK);
plot2(StoD);
PlotBaseLine1(20);
PlotBaseLine2(80);
2.
Input : Atime(240),Period1(12),Period2(26),Period3(9);
Var : Ep1(0), JISU1(0), DINDEX1(0), PreJISU1(0);
Var : Ep2(0), JISU2(0), PreJISU2(0);
Var : Ep3(0), JISU3(0), PreMACDSIG(0);
var : MACDVal(0),MACDSig(0),MACDOsc(0),PreMACDOsc(0);
if date != date[1] Then
value1 = TimeToMinutes(stime);
Ep1 = 2/(Period1+1);
Ep2 = 2/(Period2+1);
Ep3 = 2/(Period3+1);
var1 = (TimeToMinutes(stime)-value1)%Atime;
if dayindex() == 0 or (var1 <= var1[1] and stime > stime[1]) Then{
DINDEX1 = DINDEX1 + 1;
PreJISU1 = JISU1[1];
PreJISU2 = JISU2[1];
PreMACDOsc = MACDOsc[1];
if Dindex1 >= 2 Then
PreMACDSIG = MACDSIG[1];
}
if DINDEX1 <= 1 then {
JISU1 = C;
JISU2 = C;
}
else{
JISU1 = C * EP1 + PreJISU1 * (1-EP1);
JISU2 = C * EP2 + PreJISU2 * (1-EP2);
}
MACDVal = JiSu1-Jisu2;
if DINDEX1 <= 2 then {
MACDSIG = Jisu1-jisu2;
}
else{
MACDSIG = MACDVal * EP3 + PreMACDSIG * (1-EP3);
}
MACDOsc = MACDVal-MACDsig;
plot1(MACDVal);
plot2(MACDsig);
plot3(MACDOsc);
3.
봉갯수가 아닌 시간으로 구간을 나눠 계산합니다.
즐거운 하루되세요
> hugnkiss 님이 쓴 글입니다.
> 제목 : 120분봉에서 240분봉 지표 표시
> 안녕하세요.
아래와 같은 240분봉 지표를 120분봉 차트에 표시하고 싶습니다.
1. 240분봉 데이타의 StochasticsK(10,5)
2. 240분봉 데이타의 MACD_OSC(12,26,9)
추가로 궁금한 점은 제 질문에 대한 수식을 작성하실때, 120분봉 2개를 1개의 240분봉 데이타로 합쳐서 구현하게 되는것인가요?
부탁 드립니다.
수고하세요.
다음글
이전글