커뮤니티
지표식 부탁드립니다.
2013-03-11 15:16:41
220
글번호 60541
분봉에서 일봉의 이격도, 볼린져밴드와 주봉의 이격도, 볼린져밴드를 보는
수식 부탁드립니다.
실시간으로 참조가능하게 부탁드리겠습니다.
감사합니다.
답변 1
예스스탁 예스스탁 답변
2013-03-11 16:23:58
안녕하세요
예스스탁입니다.
1. 일봉 이격도
input : P1(20);
var : sumV(0), maV(0), count(0),dis(0);
sumV = 0;
for count = 0 to P1-1 {
sumV = sumV+DayClose(count);
}
maV = sumV / P1;
dis = C/mav*100;
plot1(dis);
2. 일봉 볼린져밴드
# 분봉에서 일봉 볼린져밴드 계산 시작
input : dayPeriod(30),dayDv(2);
var : daysum(0),daycnt(0),dayma(0),daySumSqrt(0),dayStdv(0);
var : dayBBup(0),dayBBdn(0),dayCounter(0);
daysum = 0;
for daycnt = 0 to dayPeriod-1{
daysum = daysum + DayClose(daycnt);
}
dayma = daysum/dayPeriod;
If DayClose(dayPeriod) != 0 Then {
daySumSqrt = 0;
For dayCounter = 0 To dayPeriod - 1 {
daySumSqrt = daySumSqrt + (DayClose(dayCounter) - dayma) * (DayClose(dayCounter) - dayma);
}
dayStdv = SquareRoot(daySumSqrt / dayPeriod);
}
Else
dayStdv = 0;
dayBBup = dayma + (dayDv * dayStdv);
dayBBdn = dayma - (dayDv * dayStdv);
# 분봉에서 일봉 볼린져밴드 계산 끝
plot1(dayBBup);
plot2(dayma );
plot3(dayBBdn);
3, 주봉 이격도
input : weekP(20);
var : cnt(0),count(0),sum1(0),mav1(0);
array : WeekC[50](0);
if DayOfWeek(date) < DayOfWeek(date)[1] then{
for cnt = 1 to 49{
WeekC[cnt] = WeekC[cnt-1][1];
}
}
WeekC[0] = C;
sum1 = 0;
if weekC[weekP] > 0 Then{
for count = 0 to weekP{
sum1 = sum1+WeekC[count];
}
mav1 = sum1/weekP;
}
plot1(C/mav1*100);
4 주봉 볼린져밴드
# 분봉에서 주봉 볼린져밴드 계산 시작
input : weekPeriod(20),weekDv(2);
var : weekcnt(0),weekcount(0),weeksum(0),weekmav(0),weekBBup(0),weekBBdn(0),weekAvgv(0),weekSumSqrt(0),weekCounter(0),weekStdv(0);
Array : weekC[120](0);
if dayofweek(date) < dayofweek(date[1]) Then{
weekC[1] = C[1];
for weekcnt = 2 to weekPeriod+1{
weekC[weekcnt] = weekC[weekcnt-1][1];
}
weeksum = 0;
for weekcount = 1 to weekPeriod-1{
weeksum = weeksum+weekC[weekcount];
}
}
weekC[0] = C;
weekmav = (C+weeksum)/weekPeriod;
If weekC[weekPeriod] != 0 Then Begin
weekAvgv = weekmav;
weekSumSqrt = 0;
For weekCounter = 0 To weekPeriod - 1 Begin
weekSumSqrt = weekSumSqrt + (weekC[weekCounter] - weekAvgv) * (weekC[weekCounter] - weekAvgv);
End;
weekStdv = SquareRoot(weekSumSqrt / weekPeriod);
End
Else
weekStdv = 0;
weekBBup = weekmav + (weekDv * weekStdv);
weekBBdn = weekmav - (weekDv * weekStdv);
# 분봉에서 주봉 볼린져밴드 계산 끝
plot1(weekBBup);
plot2(weekmav );
plot3(weekBBdn);
일봉데이터의 경우에는
차트의 첫봉의 날짜 + 99일치 정도의 일봉데이터가 내장되어 사용할수 있지만
주봉데이터의 경우에는 제공되지 않으므로
차트자체 봉으로만 계산을 합니다. 차트에 필요한
주수만큼의 데이터가 없으면 지표가 제대로 그려지지 않습니다.
즐거운 하루되세요
> 엠제이 님이 쓴 글입니다.
> 제목 : 지표식 부탁드립니다.
> 분봉에서 일봉의 이격도, 볼린져밴드와 주봉의 이격도, 볼린져밴드를 보는
수식 부탁드립니다.
실시간으로 참조가능하게 부탁드리겠습니다.
감사합니다.