커뮤니티
안녕하세요***60선위 macd양오실
2017-08-10 14:28:39
200
글번호 54335
안녕하세요
세가지 질문을 할까 합니다
macd osillater
1)macd osillater 양오실 이며
3배수에서도 양오실동시만족 매수/반대매도
2)주가가60일 이동평균선 위에서 양오실 매수/반대매도
3)주가가60일 이동평균선 위. macd osillater 양오실
3배수에서도 이동평균60선위 macd osillater 양오실
동시만족 매수/반대매도
감사합니다
답변 1
예스스탁 예스스탁 답변
2012-09-04 09:49:00
안녕하세요
예스스탁입니다.
1.
Input : Atime(3),Period1(12),Period2(26),Period3(9);
Var : Ep1(0), JISU1(0), DINDEX1(0), PreJISU1(0);
Var : Ep2(0), JISU2(0), PreJISU2(0);
Var : Ep3(0), JISU3(0), PreMACDSIG(0);
var : MACDVal(0),MACDSig(0),MACDOsc(0),PreMACDOsc(0);
var : MACDO(0);
Ep1 = 2/(Period1+1);
Ep2 = 2/(Period2+1);
Ep3 = 2/(Period3+1);
var1 = TimeToMinutes(stime)%(BarInterval*3);
if dayindex() == 0 or (var1 <= var1[1] and stime > stime[1]) Then{
DINDEX1 = DINDEX1 + 1;
PreJISU1 = JISU1[1];
PreJISU2 = JISU2[1];
PreMACDOsc = MACDOsc[1];
if Dindex1 >= 2 Then
PreMACDSIG = MACDSIG[1];
}
if DINDEX1 <= 1 then {
JISU1 = C;
JISU2 = C;
}
else{
JISU1 = C * EP1 + PreJISU1 * (1-EP1);
JISU2 = C * EP2 + PreJISU2 * (1-EP2);
}
MACDVal = JiSu1-Jisu2;
if DINDEX1 <= 2 then {
MACDSIG = Jisu1-jisu2;
}
else{
MACDSIG = MACDVal * EP3 + PreMACDSIG * (1-EP3);
}
MACDOsc = MACDVal-MACDsig;
MACDO = MACD_OSC(Period1,Period2,Period3);
if MACDOsc > 0 and MACDO > 0 Then
buy();
if MACDOsc < 0 and MACDO < 0 Then
sell();
2.
Input : Period1(12),Period2(26),Period3(9);
var : MACDO(0);
MACDO = MACD_OSC(Period1,Period2,Period3);
var1 = ma(c,60);
if MACDO > 0 and C > var1 Then
buy();
if MACDO < 0 and C < var1 Then
sell();
3.
Input : Atime(3),Period1(12),Period2(26),Period3(9),P1(60);
Var : Ep1(0), JISU1(0), DINDEX1(0), PreJISU1(0);
Var : Ep2(0), JISU2(0), PreJISU2(0);
Var : Ep3(0), JISU3(0), PreMACDSIG(0);
var : MACDVal(0),MACDSig(0),MACDOsc(0),PreMACDOsc(0),MACDO(0);
var : cnt(0),count(0),sum1(0),mav1(0),mav2(0);
Array : CC[100](0);
Ep1 = 2/(Period1+1);
Ep2 = 2/(Period2+1);
Ep3 = 2/(Period3+1);
var1 = TimeToMinutes(stime)%(BarInterval*3);
if dayindex() == 0 or (var1 <= var1[1] and stime > stime[1]) Then{
for cnt = 1 to 99{
CC[cnt] = CC[cnt-1][1];
}
DINDEX1 = DINDEX1 + 1;
PreJISU1 = JISU1[1];
PreJISU2 = JISU2[1];
PreMACDOsc = MACDOsc[1];
if Dindex1 >= 2 Then
PreMACDSIG = MACDSIG[1];
}
CC[0] = C;
if DINDEX1 <= 1 then {
JISU1 = C;
JISU2 = C;
}
else{
JISU1 = C * EP1 + PreJISU1 * (1-EP1);
JISU2 = C * EP2 + PreJISU2 * (1-EP2);
}
MACDVal = JiSu1-Jisu2;
if DINDEX1 <= 2 then {
MACDSIG = Jisu1-jisu2;
}
else{
MACDSIG = MACDVal * EP3 + PreMACDSIG * (1-EP3);
}
MACDOsc = MACDVal-MACDsig;
MACDO = MACD_OSC(Period1,Period2,Period3);
sum1 = 0;
for count = 0 to P1-1{
sum1 = sum1+CC[count];
}
mav1 = sum1/P1;
mav2 = ma(C,p1);
if MACDOsc > 0 and MACDO > 0 and C > mav1 and C > mav2 and CC[P1-1] > 0 Then
buy();
if MACDOsc < 0 and MACDO < 0 and C < mav1 and C < mav2 and CC[P1-1] > 0 Then
sell();
즐거운 하루되세요
> jbouu123 님이 쓴 글입니다.
> 제목 : 안녕하세요
> 안녕하세요
세가지 질문을 할까 합니다
macd osillater
1)macd osillater 양오실 이며
3배수에서도 양오실동시만족 매수/반대매도
2)주가가60일 이동평균선 위에서 양오실 매수/반대매도
3)주가가60일 이동평균선 위. macd osillater 양오실
3배수에서도 이동평균60선위 macd osillater 양오실
동시만족 매수/반대매도
감사합니다