커뮤니티
시스템식 부탁드리겠습니다.
2012-05-28 20:07:09
306
글번호 51380
일봉에서 주봉의 ADX를 활용한 시스템식 부탁드리겠습니다.
data2를 활용하지 않고 실시간으로 참조 할 수 있게 부탁드려요
매수
주봉의
DIPLUS(5) > DIMINUS(5)
and ADX(5) > ADX(5)[1]
and ADX(5) >= 20 then
Buy();
매수청산
DIPLUS(5) < DIMINUS(5) then
ExitLong();
감사합니다.
답변 1
예스스탁 예스스탁 답변
2012-05-29 13:47:25
안녕하세요
예스스탁입니다.
input : Length(5);
var : TL(0),TH(0),cnt(0),Dcnt(0),preTRange(0),prePlusDM14(0),DMinus(0),MinusDM14(0),TRange1(0),preMinusDM14(0);
Variables: Counter(0), TRange(0), MyRange(Length), PlusDM14(0), PlusDM(0), MinusDM(0),Dplus(0),preADX(0),ADXv(0);
Variables: CummDMI(0), Return(0);
Array : HH[61](0),LL[61](0),CC[61](0),TR[61](0),DMIv[61](0);
var1 = DayOfWeek(sdate);
if var1 < var1[1] and sdate > sdate[1] Then{
Dcnt = Dcnt+1;
HH[0] = H;
LL[0] = L;
CC[0] = C;
preTRange = TRange[1];
prePlusDM14 = PlusDM14[1];
preMinusDM14 = MinusDM14[1];
preADX = ADXv[1];
for cnt = 1 to 60{
HH[cnt] = HH[cnt-1][1];
LL[cnt] = LL[cnt-1][1];
CC[cnt] = CC[cnt-1][1];
TR[cnt] = TR[cnt-1][1];
DMIv[cnt] = DMIv[cnt-1][1];
}
}
if H > HH[0] Then
HH[0] = H;
if L < LL[0] Then
LL[0] = L;
CC[0] = C;
if CC[1] > 0 Then{
If CC[1] > HH[0] then
TH = CC[1];
else
TH = HH[0];
If CC[1] < LL[0] then
TL = CC[1];
else
TL = LL[0];
TR[0] = TH-TL;
}
If Dcnt == Length+1 Then {
MyRange = Length;
DPlus = 0;
PlusDM14 = 0;
TRange = 0;
DMinus = 0;
MinusDM14 = 0;
TRange1 = 0;
For Counter = 0 To MyRange - 1 {
If HH[Counter] - HH[Counter+1] < 0 Then
PlusDM = 0 ;
Else
PlusDM = HH[Counter] - HH[Counter+1];
If LL[Counter+1] - LL[Counter] < 0 Then
MinusDM = 0;
Else
MinusDM = LL[Counter+1] - LL[Counter];
If MinusDM >= PlusDM Then
PlusDM = 0;
If PlusDM >= MinusDM Then
MinusDM = 0;
TRange = TRange + TR[Counter];
PlusDM14 = PlusDM14 + PlusDM;
MinusDM14 = MinusDM14 + MinusDM;
}
If TRange <> 0 Then
DPlus = 100 * PlusDM14 / TRange;
Else
DPlus = 0 ;
If TRange <> 0 Then
DMinus = 100 * MinusDM14 / TRange;
Else
DMinus = 0;
}
Else If Dcnt > Length+1 Then {
If HH[0] - HH[1] < 0 Then
PlusDM = 0;
Else
PlusDM = HH[0] - HH[1];
If LL[1] - LL[0] < 0 Then
MinusDM = 0;
Else
MinusDM = LL[1] - LL[0];
If MinusDM >= PlusDM Then
PlusDM = 0;
If PlusDM >= MinusDM Then
MinusDM = 0 ;
If MyRange > 0 Then {
TRange = preTRange - (preTRange / MyRange) + TR[0];
PlusDM14 = prePlusDM14 - (prePlusDM14 / MyRange) + PlusDM;
MinusDM14 = preMinusDM14 - (preMinusDM14 / MyRange) + MinusDM;
}
If TRange <> 0 Then
DPlus = 100 * PlusDM14 / TRange;
Else
DPlus = 0 ;
If TRange <> 0 Then
DMinus = 100 * MinusDM14 / TRange;
Else
DMinus = 0;
}
If DPlus + DMinus == 0 Then
DMIv[0] = 0;
Else
DMIv[0] = 100 * Abs(DPlus - DMinus) / (DPlus + DMinus);
Return = 0;
If dcnt < Length Then {
CummDMI = 0;
for Counter = 0 To dcnt - 1 {
CummDMI = CummDMI + DMIV[Counter];
}
ADXv = CummDMI / CurrentBar;
}
Else {
ADXv = (PreADX * (Length - 1) + DMIV[0]) / Length;
}
if Dplus > DMinus and Adxv > preADX and ADXv >= 20 Then
buy();
if Dplus < DMinus Then
ExitLong();
즐거운 하루되세요
> 엠제이 님이 쓴 글입니다.
> 제목 : 시스템식 부탁드리겠습니다.
>
일봉에서 주봉의 ADX를 활용한 시스템식 부탁드리겠습니다.
data2를 활용하지 않고 실시간으로 참조 할 수 있게 부탁드려요
매수
주봉의
DIPLUS(5) > DIMINUS(5)
and ADX(5) > ADX(5)[1]
and ADX(5) >= 20 then
Buy();
매수청산
DIPLUS(5) < DIMINUS(5) then
ExitLong();
감사합니다.