커뮤니티
하나 더 부탁여...
2010-03-08 18:07:38
872
글번호 28555
전에 MACD에 갭보정 값을 넣는걸 물어보았는데, 답변 감사합니다.
StochasticsK와 DIPlus, DIMinus에도 갭보정 값을 넣을 수는 없을까요?
답변 1
예스스탁 예스스탁 답변
2010-03-08 18:24:36
안녕하세요
예스스탁입니다.
1. 갭보정 스토케스틱
input : Period(12), Period1(5), Period2(5);
var : sumGap(0), gap(0), GO(0), GH(0), GL(0), GC(0);
var : stoLval(0), stoHval(0), fstK(0), stoK(0), stoD(0);
if date!=date[1] then { // 날짜가 변경되는 봉에서(분봉에서 첫번째 봉)
gap = Open-Close[1]; // 일간갭
sumGap = sumGap+gap; // 일간갭 누적
}
GO = O - sumGap;// 갭보정 시가
GH = H - sumGap;// 갭보정 고가
GL = L - sumGap;// 갭보정 저가
GC = C - sumGap; // 갭보정 종가
stoLval = lowest(GL,Period);
stoHval = highest(GH,Period);
fstK = (GC-stoLval)/(stoHval-stoLval)*100;
stoK = ema(fstK, Period1);
stoD = ema(StoK, Period2);
plot1(stoK,"갭보정 %K");
plot2(stoD,"갭보정 %D");
plotBaseline1(20, "기준선1");
plotBaseline2(80, "기준선2");
2. 갭보정 diplus diminus adx입니다.
Inputs: Length(10);
var : sumGap(0), gap(0), GO(0), GH(0), GL(0), GC(0),TH(0),TL(0),TR(0);
Var : Counter(0), TRange(0), MyRange(Length), PlusDM14(0), PlusDM(0), MinusDM(0),DPlus(0);
Var : MinusDM14(0), Dminus(0),DMIv(0), ADXCounter(0), ADXCummDMI(0), ADXReturn(0),Return(0),GADX(0);
if date!=date[1] then { // 날짜가 변경되는 봉에서(분봉에서 첫번째 봉)
gap = Open-Close[1]; // 일간갭
sumGap = sumGap+gap; // 일간갭 누적
}
GO = O - sumGap;// 갭보정 시가
GH = H - sumGap;// 갭보정 고가
GL = L - sumGap;// 갭보정 저가
GC = C - sumGap; // 갭보정 종가
If GC[1] > GH then
TH = GC[1];
else
TH = GH;
If GC[1] < GL then
TL = GC[1];
else
TL = GL;
TR = TH - TL;
If CurrentBar == 1 Then {
MyRange = Length;
DPlus = 0;
PlusDM14 = 0;
MinusDM14 = 0;
TRange = 0;
For Counter = 0 To MyRange - 1 {
If GH[Counter] - GH[Counter+1] < 0 Then
PlusDM = 0;
Else
PlusDM = GH[Counter] - GH[Counter+1];
If GL[Counter+1] - GL[Counter] < 0 Then
MinusDM = 0;
Else
MinusDM = GL[Counter+1] - GL[Counter];
If MinusDM >= PlusDM Then
PlusDM = 0;
If PlusDM >= MinusDM Then
MinusDM = 0;
TRange = TRange + TR[Counter];
PlusDM14 = PlusDM14 + PlusDM;
MinusDM14 = MinusDM14 + MinusDM;
}
If TRange <> 0 Then
DPlus = 100 * PlusDM14 / TRange;
Else
DPlus = 0 ;
If TRange <> 0 Then
DMinus = 100 * MinusDM14 / TRange;
Else
DMinus = 0;
}
##dp
Else
If CurrentBar > 1 Then {
If GH[0] - GH[1] < 0 Then
PlusDM = 0;
Else
PlusDM = GH[0] - GH[1];
If GL[1] - GL[0] < 0 Then
MinusDM = 0;
Else
MinusDM = GL[1] - GL[0];
If MinusDM >= PlusDM Then
PlusDM = 0;
If PlusDM >= MinusDM Then
MinusDM = 0 ;
If MyRange > 0 Then Begin
TRange = TRange[1] - (TRange[1] / MyRange) + TR;
PlusDM14 = PlusDM14[1] - (PlusDM14[1] / MyRange) + PlusDM;
MinusDM14 = MinusDM14[1] - (MinusDM14[1] / MyRange) + MinusDM;
End;
If TRange <> 0 Then
DPlus = 100 * PlusDM14 / TRange;
Else
DPlus = 0 ;
If TRange <> 0 Then
DMinus = 100 * MinusDM14 / TRange;
Else
DMinus = 0;
}
If DPlus + DMinus == 0 Then
DMIv = 0;
Else
DMIv = 100 * AbsValue(DPlus - DMinus) / (DPlus + DMinus);
Return = 0;
If CurrentBar >= 1 AND Length > 0 Then Begin
If CurrentBar < Length Then begin
ADXCummDMI = 0;
for Counter = 0 To CurrentBar - 1 Begin
ADXCummDMI = ADxCummDMI + DMIV[Counter];
End;
Return = ADXCummDMI / CurrentBar;
End
Else
Return = (GADX[1] * (Length - 1) + DMIv) / Length;
End;
GADX = Return;
plot1(GADX);
plot2(Dplus);
plot3(Dminus);
즐거운 하루되세요
> 빨간우산 님이 쓴 글입니다.
> 제목 : 하나 더 부탁여...
> 전에 MACD에 갭보정 값을 넣는걸 물어보았는데, 답변 감사합니다.
StochasticsK와 DIPlus, DIMinus에도 갭보정 값을 넣을 수는 없을까요?
다음글
이전글