커뮤니티
재차 문의드립니다.
2010-02-17 16:59:52
617
글번호 28149
관리자님께 먼저 문의를 하였으나 설명이 부족한 관계로 다시 수정하여 질문올리옵니다.
추세에 점수를 부여하여 그 추세가 강한지 약한지를 점수로서 평가하는 것입니다.
매수의 예를 들어서
#5분이동평균선이 쌍바닥일때 + 1 점.
#보조지표 macd(12,26,9) crossup 교차저점 기준으로 쌍바닥시(바닥이 같거나,아니면 저점을 높인) + 1 점.
#보조지표 macd 보다 가격이 하락이면 -1 점 .
#보조지표 macd가 쌍바닥이 아닐때 가격이상승이면 +0.5 ,하락중이면 - 0.5 .
#보조지표 macd(12,26,9) crossdown 교차저점 기준으로 쌍봉확인시 -1점.
#5분 이동평균선의 고점형성이후 고점을 낮추면서 다음 고점이 낮아진다면 -1점
등으로 추세를 판단하는 로직을 따로 구현하였으면 합니다.
##그리고 더불어 3점 이상이면 매수진입식까지 표현해 주셨음합니다.
감사합니다.
답변 1
예스스탁 예스스탁 답변
2010-02-18 09:30:15
안녕하세요
예스스탁입니다.
#보조지표 macd 보다 가격이 하락이면 -1 점 .
--> 하락기준이 명확하지 않습니다.
#5분 이동평균선의 고점형성이후 고점을 낮추면서 다음 고점이 낮아진다면 -1점
--> 고점기준이 명확하지 않습니다.
위 내용은 내용이 명확하지 않아 추가하지 못했습니다.
또한 쌍바닥이나 쌍봉은 식이 구현될수 있도록 정확한 조건 내용을 올려주셔야 합니다.
아래는 일반적인 내용으로 작성한 식입니다.
input : left(3), right(2), Period(200);
var : ma5(0), LowVal1(0), LowVal2(0), Lowidx1(0), Lowidx2(0);
var : MACDV(0),MACDS(0),LL1(0),LL2(0),HH1(0),HH2(0);
#5분이동평균선이 쌍바닥일때 + 1 점.
ma5 = ma(C,5);
LowVal1 = SwingLow(1,ma5,left,right,Period);
LowVal2 = SwingLow(2,ma5,left,right,Period);
Lowidx1 = SwingLowbar(1,ma5,left,right,Period);
Lowidx2 = SwingLowbar(2,ma5,left,right,Period);
if Lowidx2-Lowidx1 > 5 and //두개 저점의 간격이 5봉 이상 떨어져 있고
Lowidx2-Lowidx1 < 30 // 두개 저점의 간격이 30봉 이내이고
and ma5[right]== LowVal1 and // 3개 전봉에서 최근 저점이 형성되었고
accumN(iff(ma5 > ma5[1],1,0), 2) == 2 and // 이평이 3일 연속 상승하였고
(max(LowVal1, LowVal2) - min(LowVal1, LowVal2))/min(LowVal1, LowVal2)*100 < 3 //두저점은 상하3% 범위내이면
then
var1 = 1;
else
var1 = 0;
#보조지표 macd(12,26,9) crossup 교차저점 기준으로 쌍바닥시(바닥이 같거나,아니면 저점을 높인) + 1 점.
macdV = MACD(12,26);
MACDS = ema(MACDv,9);
if CrossDown(MACDv,MACDs) Then{
LL1 = MACDV;
LL2 = LL1[1];
}
if MACDV < LL1 Then
LL1 = MACDV;
if crossup(MACDV,MACDS) and LL1 >= LL2 Then
var2 = 1;
Else
var2 = 0;
#보조지표 macd(12,26,9) crossdown 교차저점 기준으로 쌍봉확인시 -1점.
if CrossUp(MACDv,MACDs) Then{
HH1 = MACDV;
HH2 = HH1[1];
}
if MACDV > HH1 Then
HH1 = MACDV;
if CrossDown(MACDV,MACDS) and HH1 <= HH2 Then
var3 = -1;
Else
var3 = 0;
#보조지표 macd가 쌍바닥이 아닐때 가격이상승이면 +0.5 ,하락중이면 - 0.5 .
if SwingLow(1,MACDV,left,right,left+right+1) == -1 then
if C > C[1] Then
var4 = 0.5;
else
var4 = -0.5;
plot1(var1+var2+var3+var4);
내용이 완전치 않아 시스템식으로는 만들지 못했습니다.
즐거운 하루되세요
> 고릴라 님이 쓴 글입니다.
> 제목 : 재차 문의드립니다.
> 관리자님께 먼저 문의를 하였으나 설명이 부족한 관계로 다시 수정하여 질문올리옵니다.
추세에 점수를 부여하여 그 추세가 강한지 약한지를 점수로서 평가하는 것입니다.
매수의 예를 들어서
#5분이동평균선이 쌍바닥일때 + 1 점.
#보조지표 macd(12,26,9) crossup 교차저점 기준으로 쌍바닥시(바닥이 같거나,아니면 저점을 높인) + 1 점.
#보조지표 macd 보다 가격이 하락이면 -1 점 .
#보조지표 macd가 쌍바닥이 아닐때 가격이상승이면 +0.5 ,하락중이면 - 0.5 .
#보조지표 macd(12,26,9) crossdown 교차저점 기준으로 쌍봉확인시 -1점.
#5분 이동평균선의 고점형성이후 고점을 낮추면서 다음 고점이 낮아진다면 -1점
등으로 추세를 판단하는 로직을 따로 구현하였으면 합니다.
##그리고 더불어 3점 이상이면 매수진입식까지 표현해 주셨음합니다.
감사합니다.
다음글
이전글