커뮤니티
수식 부탁합니다
2026-05-07 17:49:35
56
글번호 231938
스토캐스틱 (25,6,6) 골든크로스 발생
단 슈퍼트렌드 발생 현재 기준 30일 이내에 있어야 하고
슈퍼트렌드 발생한 후 첫번째 스토캐스틱(25,6,6) 골든크로스 발생한 종목 검색식 부탁합니다ㅣ
답변 1
예스스탁 예스스탁 답변
2026-05-08 09:13:40
안녕하세요
예스스탁입니다.
input : period(10),multiplier(3);
input : sto1(10),sto2(5),sto3(5);
var : src(0), alpha(0),ATRV(0),upperBand(0),lowerBand(0),direction(0),SuperTrend(C);
var : sk(0),sd(0),T(0),S(0);
sk = stochasticsK(sto1,sto2);
sd = stochasticsD(sto1,sto2,sto3);
if CurrentBar > 1 Then
{
src = (H+L)/2;
alpha = 1 / period ;
ATRV = IFf(IsNan(ATRV[1]) == true, ma(TrueRange,period) , alpha * TrueRange + (1 - alpha) * IFf(isnan(ATRV[1])==true,0,ATRV[1]));
upperBand = src + multiplier * AtrV;
lowerBand = src - multiplier * AtrV;
if lowerBand > lowerBand[1] or close[1] < lowerBand[1] Then
lowerBand = lowerBand;
Else
lowerBand = lowerBand[1];
if upperBand < upperBand[1] or close[1] > upperBand[1] Then
upperBand = upperBand;
Else
upperBand = upperBand[1];
if C > UpperBand Then
direction = 1;
if C < LowerBand Then
direction = -1;
if direction == 1 Then
SuperTrend = lowerband;
Else
SuperTrend = upperband;
}
if CrossUp(C,SuperTrend) Then
{
T = 1;
S = Index;
}
if CrossDown(C,SuperTrend) Then
T = -1;
if T == 1 and Index < S+30 and CrossUp(sk,sd) Then
{
T = 2;
Find(1);
}
즐거운 하루되세요
다음글
이전글