커뮤니티
종목 검색식 부탁드립니다.
2026-05-06 10:35:11
73
글번호 231884
1. 60 봉 신고가 종목 검색식 부탁드려요.
(단, 종가기준 / 꼬리는 포함하지 않음)
2. Bostian's Intraday intensity index 가 "상승전환" OR "연속상승"시
종목 검색식 부탁드려요
3. BWI (50,2) "상승 전환" 일때 종목 검색식 부탁드려요.
4. 일목 선행스팬2 가 "상승전환" OR "연속상승" 종목 검색식 부탁드려요
5. BWI (60,2) 가 "상승 전환" OR "연속상승" 하면서,
BWI (120,2) 을 상향 돌파(골든크로스)할때
종목 검색식 부탁드려요.
답변 1
예스스탁 예스스탁 답변
2026-05-06 13:48:42
안녕하세요
예스스탁입니다.
1
if c > highest(c,60)[1] Then
Find(1);
2
var : BIII(0),T(0);
BIII = accum(V*(Pow(C-L,2)-Pow(H-C, 2)) / (H-L));
if BIII > BIII[1] Then
T = 1;
if BIII < BIII[1] Then
T = -1;
if (T == 1 and T != T[1]) or
CountIf(BIII>BIII[1],2) == 2 Then
Find(1);
3
Input: Period(40), D(2);
var : BM(0),BU(0),BD(0),BWI(0),T(0);
BM = ma((C+H+L)/3,Period);
BU = BM+D*std((C+H+L)/3,Period);
BD = BM-D*std((C+H+L)/3,Period);
BWI = (BU-BD)/BM*100;
if BWI > BWI[1] Then
T = 1;
if BWI < BWI[1] Then
T = -1;
if T == 1 and T != T[1] Then
Find(1);
4
var : 선행스팬2(0),T(0);
선행스팬2 = (Highest(High, 52)[25] + Lowest(Low, 52)[25]) / 2;
if 선행스팬2 > 선행스팬2[1] Then
T = 1;
if 선행스팬2 < 선행스팬2[1] Then
T = -1;
if (T == 1 and T != T[1]) or
CountIf(선행스팬2>선행스팬2[1],2) == 2 Then
Find(1);
5
Input: Period1(60), D1(2);
Input: Period2(120), D2(2);
var : BM1(0),BU1(0),BD1(0),BWI1(0),T(0);
var : BM2(0),BU2(0),BD2(0),BWI2(0);
BM1 = ma((C+H+L)/3,Period1);
BU1 = BM1+D1*std((C+H+L)/3,Period1);
BD1 = BM1-D1*std((C+H+L)/3,Period1);
BWI1 = (BU1-BD1)/BM1*100;
BM2 = ma((C+H+L)/3,Period2);
BU2 = BM2+D2*std((C+H+L)/3,Period2);
BD2 = BM2-D2*std((C+H+L)/3,Period2);
BWI2 = (BU2-BD2)/BM2*100;
if BWI1 > BWI1[1] Then
T = 1;
if BWI1 < BWI1[1] Then
T = -1;
if ((T == 1 and T != T[1]) or
CountIf(BWI1>BWI1[1],2) == 2) and
CrossUp(BWI1,BWI2) Then
Find(1);
즐거운 하루되세요