커뮤니티
종목 검색식 부탁드립니다.
2026-04-28 21:02:52
94
글번호 231813
1. 일목균형표 선행스팬 2 가 횡보(직선"ㅡ") 하다가 상승으로 돌아설때,
" 첫상승 " 종목 검색식 부탁드려요.( 꼭 "첫상승"만 / 2일연속 x , 3일연속x . . .)
2. 일목균형표 선행스팬 1 이 횡보(직선"ㅡ") 하다가 상승으로 돌아설때,
" 첫상승 " 종목 검색식 부탁드려요.( 꼭 "첫상승"만 / 2일연속 x , 3일연속x . . .)
3. 단순10이평이 20이평을 돌파(골든크로스)후 "첫 발생"하는 20일 신고가 종목 부탁드려요
(종가기준/꼬리는 x)
4. 단순10이평이 20이평을 돌파(골든크로스)후 "첫 발생"하는 "20일 신고가 종목"
0봉전~5봉전까지의 검색식 부탁드려요.
(종가기준/꼬리는 x)
5. 단순 20 이평이 60 이평을 돌파할때 종목 검색식 부탁드려요.
6. 단순 20 이평이 60 이평을 돌파할때 0봉전~5봉전까지의 모든종목 검색식 부탁드려요.
답변 1
예스스탁 예스스탁 답변
2026-04-29 10:42:51
안녕하세요
예스스탁입니다.
1
var : 선행스팬2(0),T(0);
선행스팬2 = (Highest(High, 52)[25] + Lowest(Low, 52)[25]) / 2;
if 선행스팬2 > 선행스팬2[1] Then
T = 1;
else if 선행스팬2 < 선행스팬2[1] Then
T = -1;
Else
T = 0;
if T == 1 and T[1] == 0 Then
Find(1);
2
var : 전환선(0),기준선(0),선행스팬1(0),T(0);
전환선 = (Highest(High, 9) + Lowest(Low, 9)) / 2;
기준선 = (Highest(High, 26) + Lowest(Low, 26)) / 2;
선행스팬1 = (전환선[25] + 기준선[25]) / 2 ;
if 선행스팬1 > 선행스팬1[1] Then
T = 1;
else if 선행스팬1 < 선행스팬1[1] Then
T = -1;
Else
T = 0;
if T == 1 and T[1] == 0 Then
Find(1);
3
var : T(0);
var1 = ma(C,10);
var2 = ma(C,20);
if CrossUp(var1,var2) Then
T = 1;
if CrossDown(var1,var2) Then
T = -1;
if T == 1 and c > highest(C,20)[1] Then
{
T = 2;
Find(1);
}
4
input : N(5);
var : T(0);
var1 = ma(C,10);
var2 = ma(C,20);
if CrossUp(var1,var2) Then
T = 1;
if CrossDown(var1,var2) Then
T = -1;
if T == 1 and c > highest(C,20)[1] Then
{
T = 2;
}
if CountIf(T == 2 and T != T[1],N) >= 1 Then
Find(1);
5
var : T(0);
var1 = ma(C,20);
var2 = ma(C,60);
if crossup(var1,var2) Then
Find(1);
6
input : N(5);
var : T(0);
var1 = ma(C,20);
var2 = ma(C,60);
if CountIf(crossup(var1,var2),N) >= 1 Then
Find(1);
즐거운 하루되세요
다음글
이전글