커뮤니티
부탁드립니다
2026-03-16 02:47:30
82
글번호 231080
var : af(0.02), maxAF(0.2), Diperiod(14), RocPeriod(10);
if C > CSar(af,maxAF) then
var1 = 1;
else
var1 = -1;
if Diplus(diperiod) > Diminus(diperiod) then
var2 = var1 + 1;
else
var2 = var1 - 1;
if PROC(rocperiod) > 0 then
var3 = var2 + 1;
else
var3 = var2 - 1;
if var3 ==3 and var3[1] < 3 then
Buy("매수", onclose, DEF, DEF);
if var3 == -3 and var3[1] > -3 then
sell("매도", onclose, DEF, DEF);
위의 수식에
신호기준 최고점과 최저점 파동선을 그리고 싶습니다
파동선 최고점 라인과 수치
파동선 최저점 라인과 수치도 부탁드립니다
sell("매도", onclose, DEF, DEF); 이게 무슨 뜻인지요?
답변 1
예스스탁 예스스탁 답변
2026-03-16 13:57:47
안녕하세요
예스스탁입니다.
1
sell("매도", onclose, DEF, DEF);
def는 디폴트입니다.
진입함수의 3번째 매개변수는 신호가격, 4번째 매개변수는 수량입니다.
신호가격은 atstop이나 atlimit 신호타입을 사용할 경우에만 지정해야 하는 매개변수이고
onclose 신호타입은 신호가격을 지정하는 타입이 아니므로 def로 처리합니다.
수량은 적지 않거나 def로 지정하면 설정창에서 지정한 수량이 반영됩니다.
2
var : af(0.02), maxAF(0.2), Diperiod(14), RocPeriod(10);
var : bd(0),bt(0),bh(0),sd(0),st(0),sl(0),tl(0),tx(0);
if C > CSar(af,maxAF) then
var1 = 1;
else
var1 = -1;
if Diplus(diperiod) > Diminus(diperiod) then
var2 = var1 + 1;
else
var2 = var1 - 1;
if PROC(rocperiod) > 0 then
var3 = var2 + 1;
else
var3 = var2 - 1;
if MarketPosition <= 0 and var3 ==3 and var3[1] < 3 then
{
Buy("매수", onclose, DEF, DEF);
bd = sDate;
bt = sTime;
bh = h;
if bh > 0 Then
{
tl = TL_New(sd,st,sl,bd,bt,bh);
TL_SetColor(tl,Red);
tx = Text_New(bd,bt,bh,NumToStr(bh,2));
Text_SetStyle(tx,2,1);
}
}
if MarketPosition >= 0 and var3 == -3 and var3[1] > -3 then
{
sell("매도", onclose, DEF, DEF);
sd = sDate;
st = sTime;
sl = l;
if bh > 0 Then
{
tl = TL_New(bd,bt,bh,sd,st,sl);
TL_SetColor(tl,Blue);
tx = Text_New(sd,st,sl,NumToStr(sl,2));
Text_SetStyle(tx,2,0);
}
}
if MarketPosition == 1 Then
{
if h > bh Then
{
bd = sDate;
bt = sTime;
bh = h;
TL_SetEnd(tl,bd,bt,bh);
Text_SetString(tx,NumToStr(bh,2));
Text_SetLocation(tx,bd,bt,bh);
}
}
if MarketPosition == -1 Then
{
if l < sl Then
{
sd = sDate;
st = sTime;
sl = l;
TL_SetEnd(tl,sd,st,sl);
Text_SetString(tx,NumToStr(sl,2));
Text_SetLocation(tx,sd,st,sl);
}
}
즐거운 하루되세요
다음글
이전글