커뮤니티
부탁드립니다
2026-01-25 09:03:47
51
글번호 230052
1. 현재봉이 직전봉보다 거래량이 많았으면 캔들 바로 위에 빨강색 동그라미를, 적었으면 캔들 바로 아래 파란색 동그라미를 구현해 주세요
2. 1분챠트에서 60분마다 전시간대보다 거래량이 많았으면 마지막 캔들 위에 빨강색 동그라미를, 전시간대보다 거래량이 적었으면 마지막 캔들 아래에 파란색 동그라미를 구현해 주세요
3.현재봉이 당일 시가보다 30틱 이상 가격이 높으면 빨강색, 60틱이상 가격이 높으면 흰색, 100틱 이상 가격이 높으면 보라색으로, 당일 시가보다 30틱이상 가격이 낮으면 파란색, 60틱이상 가격이 낮으면 검정색, 100틱이상 가격이 낮으면 노란색으로 구현해 주세요
4. 아시아장, 유럽장, 미국장 각 기준으로 시가봉의 시가선이 각각 나타날 수 있도록 구현해 주세요
감사합니다.
답변 1
예스스탁 예스스탁 답변
2026-01-26 14:21:49
안녕하세요
예스스탁입니다.
1
var : tx(0);
if v > v[1] Then
{
tx = Text_New(sDate,sTime,h,"●");
Text_SetColor(tx,Red);
Text_SetStyle(tx,2,1);
}
if v < v[1] Then
{
tx = Text_New(sDate,sTime,l,"●");
Text_SetColor(tx,Blue);
Text_SetStyle(tx,2,0);
}
2
Input : 분(60);
var : S1(0),D1(0),TM(0),TF(0),vv(0),vv1(0),tx(0);
if Bdate != Bdate[1] Then
{
S1 = TimeToMinutes(stime);
D1 = sdate;
}
if D1 > 0 then
{
if sdate == D1 Then
TM = TimeToMinutes(stime)-S1;
Else
TM = TimeToMinutes(stime)+1440-S1;
TF = TM%분;
if Bdate != Bdate[1] or
(Bdate == Bdate[1] and 분 > 1 and TF < TF[1]) or
(Bdate == Bdate[1] and 분 > 1 and TM >= TM[1]+분) or
(Bdate == Bdate[1] and 분 == 1 and TM > TM[1]) Then
{
vv = v;
vv1 = vv[1];
if vv1 > 0 Then
{
if vv > vv1 Then
{
tx = Text_New(sDate,sTime,h,"●");
Text_SetColor(tx,Red);
Text_SetStyle(tx,2,1);
}
Else
{
tx = Text_New(sDate,sTime,l,"●");
Text_SetColor(tx,Blue);
Text_SetStyle(tx,2,0);
}
}
}
Else
{
vv = vv+v;
if vv1 > 0 Then
{
if vv > vv1 Then
{
Text_SetLocation(tx,sDate,sTime,h);
Text_SetColor(tx,Red);
Text_SetStyle(tx,2,1);
}
Else
{
Text_SetLocation(tx,sDate,sTime,l);
Text_SetColor(tx,Blue);
Text_SetStyle(tx,2,0);
}
}
}
}
3
if c >= DayOpen+PriceScale*30 and c < DayOpen+PriceScale*60 Then
PlotPaintBar(h,l,"강조",Red);
if c >= DayOpen+PriceScale*60 and c < DayOpen+PriceScale*100 Then
PlotPaintBar(h,l,"강조",White);
if c >= DayOpen+PriceScale*100 Then
PlotPaintBar(h,l,"강조",Purple);
if c <= DayOpen-PriceScale*30 and c > DayOpen-PriceScale*60 Then
PlotPaintBar(h,l,"강조",Blue);
if c <= DayOpen-PriceScale*60 and c > DayOpen-PriceScale*100 Then
PlotPaintBar(h,l,"강조",Black);
if c <= DayOpen-PriceScale*100 Then
PlotPaintBar(h,l,"강조",Yellow);
4
input : nTime1(90000),ntime2(170000),ntime3(233000),분(60);
var : S1(0),D1(0),TM(0);
var : TL1(0),TL2(0),TL3(0);
if (sdate != sdate[1] and stime >= nTime1) or
(sdate == sdate[1] and stime >= nTime1 and stime[1] < nTime1) Then
{
var1 = O;
}
if (sdate != sdate[1] and stime >= ntime2) or
(sdate == sdate[1] and stime >= ntime2 and stime[1] < ntime2) Then
{
var2 = O;
}
if (sdate != sdate[1] and stime >= ntime3) or
(sdate == sdate[1] and stime >= ntime3 and stime[1] < ntime3) Then
{
var3 = O;
}
if var1 > 0 Then
Plot1(var1);
if var2 > 0 Then
Plot2(var2);
if var3 > 0 Then
Plot3(var3);
즐거운 하루되세요
이전글