커뮤니티
수식 부탁드립니다.
2025-07-18 11:35:21
173
글번호 192571
90틱 챠트에 30분봉의 캔들을 배경에 보여주고 싶습니다.
답변 1
예스스탁 예스스탁 답변
2025-07-18 14:56:59
안녕하세요
예스스탁입니다.
input : 분(30);
var : S1(0),D1(0),TM(0),TF(0);
var : oo(0),hh(0),ll(0),ii(0);
var : tl1(0),tl2(0),box1(0),box2(0);
if Bdate != Bdate[1] Then
{
S1 = TimeToMinutes(stime);
D1 = sdate;
}
if D1 > 0 then
{
if sdate == D1 Then
TM = TimeToMinutes(stime)-S1;
Else
TM = TimeToMinutes(stime)+1440-S1;
TF = TM%분;
if Bdate != Bdate[1] or
(Bdate == Bdate[1] and 분 > 1 and TF < TF[1]) or
(Bdate == Bdate[1] and 분 > 1 and TM >= TM[1]+분) or
(Bdate == Bdate[1] and 분 == 1 and TM > TM[1]) Then
{
oo = o;
hh = h;
ll = l;
ii = 0;
box1 = Box_New(sDate,sTime,oo,NextBarSdate,NextBarStime,c);
box2 = Box_New(sDate,sTime,oo,NextBarSdate,NextBarStime,c);
tl1 = TL_New(sDate[ii],sTime[ii],hh,sDate[ii],sTime[ii],max(oo,c));
tl2 = TL_New(sDate[ii],sTime[ii],ll,sDate[ii],sTime[ii],max(oo,c));
}
Else
{
ii = ii +1;
if h > hh Then
hh = h;
if l < ll Then
ll = l;
Box_SetEnd(box1,sDate,sTime,c);
Box_SetEnd(box2,sDate,sTime,c);
TL_SetBegin(tl1,sDate[Floor(ii/2)],sTime[Floor(ii/2)],hh);
TL_SetEnd(tl1,sDate[Floor(ii/2)],sTime[Floor(ii/2)],max(oo,c));
TL_SetBegin(tl2,sDate[Floor(ii/2)],sTime[Floor(ii/2)],ll);
TL_SetEnd(tl2,sDate[Floor(ii/2)],sTime[Floor(ii/2)],min(oo,c));
}
Box_SetColor(box1,IFf(c>oo,Red,IFf(c<oo,Blue,Green)));
Box_SetFill(box1,true);
Box_SetColor(box2,IFf(c>oo,Red,IFf(c<oo,Blue,Green)));
Box_SetSize(box2,1);
TL_SetColor(tl1,IFf(c>oo,Red,IFf(c<oo,Blue,Green)));
TL_SetDrawMode(tl1,0);
TL_SetSize(TL1,1);
TL_SetColor(tl2,IFf(c>oo,Red,IFf(c<oo,Blue,Green)));
TL_SetDrawMode(tl2,0);
TL_SetSize(TL2,1);
}
즐거운 하루되세요
> 오늘도수익 님이 쓴 글입니다.
> 제목 : 수식 부탁드립니다.
> 90틱 챠트에 30분봉의 캔들을 배경에 보여주고 싶습니다.
다음글
이전글