커뮤니티
지표문의드립니다
2025-04-10 17:01:21
272
글번호 190010
안녕하세요 관리자님!!
혹시 윌리엄스vixfix지표와 윌리엄스리버스지표를 구현할수 있을까요??
실거래중인데 변곡점을 잡는데 유용할것 같아 문의드립니다!!
항상 감사합니다^^
답변 1
예스스탁 예스스탁 답변
2025-04-11 12:52:35
안녕하세요
예스스탁입니다.
모두 속성에서 막대그래프로 지정하고 적요하시면 됩니다.
1. Vix Fix
input : pd(22), bbl(20), mult(2.0), lb(50), ph(0.85);
var : wvf(0), sDev(0),midLine(0), upperBand(0);
var : rangeHigh(0),color(0), OverSold(0), TL1(0), TX1(0);
var : 년(0), 월(0), 일(0), 시(0), 분(0);
# williams vix fix 및 과매도권 밴드 계산
wvf = ((highest(close, pd)-low)/(highest(close, pd)))*100;
sDev = mult * std(wvf, bbl);
midLine = ma(wvf, bbl);
upperBand = midLine + sDev;
rangeHigh = (highest(wvf, lb)) * ph;
# 과매도권 정의
if wvf >= upperBand or wvf >= rangeHigh Then
OverSold = 1;
Else
OverSold = 0;
# 색상 처리
color = iff(OverSold == 1, GREEN, GRAY);
# 과매도 이탈시 색상 및 수직선
if CountIF(OverSold[1] > 0 ,4) == 4 and OverSold == 0 Then {
color = RED;
년 = int(sdate/10000);
월 = int((sdate-int(sdate/10000)*10000)/100);
일 = sdate - int(sdate/100)*100;
시 = int(sTime/10000);
분 = int((sTime-int(sTime/10000)*10000)/100);
TL1 = TL_New(sDate, sTime, 0, sDate, sTime, 999999999);
TX1 = Text_New(sDate, sTime, Lowest(L,pd), numtostr(년,0)+"/"+numtostr(월,0)+"/"+numtostr(일,0)+" "+numtostr(시,0)+":"+numtostr(분,0));
TL_SetColor(TL1, GRAY);
TEXT_SetColor(TX1, GRAY);
Text_SetStyle(TX1, 0, 0);
}
Plot1(wvf,"wvf",color);
2. Vix Inverse
input : pd(22), bbl(20), mult(2.0), lb(50), ph(0.85);
var : wvf_inv(0), sDev2(0),midLine2(0), upperBand2(0), rangeHigh2(0),color2(0),Overbought(0);
wvf_inv = ((high-lowest(close, pd))/lowest(close, pd))*100;
sDev2 = mult * std(wvf_inv, bbl);
midLine2 = ma(wvf_inv, bbl);
upperBand2 = midLine2 + sDev2;
rangeHigh2 = (highest(wvf_inv, lb)) * ph;
color2 = iff(wvf_inv >= upperBand2 or wvf_inv >= rangeHigh2, RGB(255,102,0), GRAY);
if wvf_inv >= upperBand2 or wvf_inv >= rangeHigh2 Then
Overbought = 1;
Else
Overbought = 0;
color2 = iff(Overbought == 1, RGB(255,102,0), GRAY);
if CountIF(Overbought[1] > 0 ,4) == 4 and Overbought == 0 Then
color2 = BLUE;
plot1(wvf_inv,"wvf",color2);
즐거운 하루되세요
> 카카 님이 쓴 글입니다.
> 제목 : 지표문의드립니다
> 안녕하세요 관리자님!!
혹시 윌리엄스vixfix지표와 윌리엄스리버스지표를 구현할수 있을까요??
실거래중인데 변곡점을 잡는데 유용할것 같아 문의드립니다!!
항상 감사합니다^^
다음글
이전글