커뮤니티
수식문의드립니다.
2025-04-01 11:43:56
367
글번호 189754
해외선물 다음조건으로 매매하는 수식을 만들고 싶습니다.
15시 이후부터 21시 사이에 1회만 매매. 목표가 미도달시 05:50 청산
<매수 조건> (아래 모든 진입조건에서 터치가 어려우면 돌파도 가능)
현재가가 당일중심선 위에 있는 경우 당일중심선이 당일의 최고인 시점에서 가격이 위에서 아래로 내려오면서 당일중심선을 터치하면 매수
현재가가 당일중심선 아래에 있는 경우 당일중심선 위로 20틱 이상 올라간 다음에 다시 내려와서 당일중심선을 터치하면 매수
<매도 조건은 반대로 동일>
목표가 도달하면 청산. 목표가는 별도로 정함.
답변 1
예스스탁 예스스탁 답변
2025-04-01 13:54:28
안녕하세요
예스스탁입니다.
input : 진입시작(150000),진입끝(210000),당일청산(055000),익절틱수(50);
var : Tcond(false),MH(0),ML(0),T(0),entry(0);
IF 당일청산 > 진입시작 Then
SetStopEndofday(당일청산);
Else
{
if sDate != sDate[1] Then
SetStopEndofday(당일청산);
}
if Bdate != Bdate[1] Then
{
Tcond = False;
MH = (DayHigh+DayLow)/2;
ML = (DayHigh+DayLow)/2;
entry = 0;
if C > (DayHigh+DayLow)/2 Then
T = 1;
if C < (DayHigh+DayLow)/2 Then
T = -1;
}
if (MarketPosition != 0 and MarketPosition != MarketPosition[1]) or
(MarketPosition == MarketPosition[1] and TotalTrades > TotalTrades[1]) Then
entry = entry+1;
if (DayHigh+DayLow)/2 > MH Then
MH = (DayHigh+DayLow)/2;
if (DayHigh+DayLow)/2 < ML Then
ML = (DayHigh+DayLow)/2;
if (sdate != sdate[1] and stime >= 진입시작) or
(sdate == sdate[1] and stime >= 진입시작 and stime[1] < 진입시작) Then
{
Tcond = true;
IF 당일청산 <= 진입시작 Then
{
SetStopEndofday(0);
}
}
if (sdate != sdate[1] and stime >= 진입끝) or
(sdate == sdate[1] and stime >= 진입끝 and stime[1] < 진입끝) Then
{
Tcond = False;
}
if CrossUp(C,(DayHigh+DayLow)/2) Then
T = 1;
if CrossDown(C,(DayHigh+DayLow)/2) Then
T = -1;
if T == 1 and H >= (DayHigh+DayLow)/2 + PriceScale*20 Then
T = 2;
if T == -1 and L <= (DayHigh+DayLow)/2 - PriceScale*20 Then
T = -2;
if Tcond == true and entry < 1 Then
{
if (DayHigh+DayLow)/2 == MH and L > (DayHigh+DayLow)/2 Then
Buy("b1",AtLimit,(DayHigh+DayLow)/2);
if (DayHigh+DayLow)/2 != MH and T == 2 and L > (DayHigh+DayLow)/2 Then
Buy("b2",AtLimit,(DayHigh+DayLow)/2);
if (DayHigh+DayLow)/2 == ML and H < (DayHigh+DayLow)/2 Then
Sell("s1",AtLimit,(DayHigh+DayLow)/2);
if (DayHigh+DayLow)/2 != ML and T == -2 and H < (DayHigh+DayLow)/2 Then
Sell("s2",AtLimit,(DayHigh+DayLow)/2);
}
SetStopProfittarget(익절틱수*PriceScale,PointStop);
즐거운 하루되세요
> 강장군 님이 쓴 글입니다.
> 제목 : 수식문의드립니다.
> 해외선물 다음조건으로 매매하는 수식을 만들고 싶습니다.
15시 이후부터 21시 사이에 1회만 매매. 목표가 미도달시 05:50 청산
<매수 조건> (아래 모든 진입조건에서 터치가 어려우면 돌파도 가능)
현재가가 당일중심선 위에 있는 경우 당일중심선이 당일의 최고인 시점에서 가격이 위에서 아래로 내려오면서 당일중심선을 터치하면 매수
현재가가 당일중심선 아래에 있는 경우 당일중심선 위로 20틱 이상 올라간 다음에 다시 내려와서 당일중심선을 터치하면 매수
<매도 조건은 반대로 동일>
목표가 도달하면 청산. 목표가는 별도로 정함.