커뮤니티
문의드립니다.
2025-03-18 20:53:04
307
글번호 189308
선물차트 기준으로 문의드립니다.
틱차트에 분봉의 fibonacci retrace 지표를 나타내고자 합니다.
분봉의 기간값과
fibonacci retrace 지표의 xavglen Hilolen Retrace 변수값들은 수정가능하게
부탁드립니다.
항상 감사드립니다. 수고하세요!!!
답변 1
예스스탁 예스스탁 답변
2025-03-19 12:34:46
안녕하세요
예스스탁입니다.
input : 분(60);
Inputs: XAvgLen(15), HiLoLen(50), Retrace(0.382);
var : cnt(0),S1(0),D1(0),TM(0),TF(0),ii(0);
var : EP(0),Xavg(0),PreXavg(0);
var : HiHi(0),LoLo(0),Retracement(0),HRetrace(0),LRetrace(0);
Array : HH[100](0),LL[100](0),CC[100](0);
EP = 2/(XAvgLen+1);
if Bdate != Bdate[1] Then
{
S1 = TimeToMinutes(stime);
D1 = sdate;
}
if D1 > 0 then
{
if sdate == D1 Then
TM = TimeToMinutes(stime)-S1;
Else
TM = TimeToMinutes(stime)+1440-S1;
TF = TM%분;
if Bdate != Bdate[1] or
(Bdate == Bdate[1] and 분 > 1 and TF < TF[1]) or
(Bdate == Bdate[1] and 분 > 1 and TM >= TM[1]+분) or
(Bdate == Bdate[1] and 분 == 1 and TM > TM[1]) Then
{
ii = ii +1;
for cnt = 99 downto 1
{
HH[cnt] = HH[cnt-1];
LL[cnt] = LL[cnt-1];
CC[cnt] = CC[cnt-1];
}
HH[0] = H;
LL[0] = L;
PreXavg = Xavg[1];
}
if H > HH[0] Then
HH[0] = H;
if L < LL[0] Then
LL[0] = L;
CC[0] = C;
if ii <= 1 then
XAvg = C;
else
XAvg = C * EP + PreXAvg * (1-EP);
plot1(XAvg);
if HH[HiLoLen] >0 and LL[HiLoLen] > 0 Then
{
HiHi = 0;
LoLo = 0;
For cnt = 0 to HiLoLen-1
{
if HiHi == 0 or (HiHi > 0 and HH[cnt] > HiHi) Then
HiHi = HH[cnt];
if LoLo == 0 or (LoLo > 0 and LL[cnt] < LoLo) Then
LoLo = LL[cnt];
}
Retracement = (HiHi - LoLo) * Retrace;
HRetrace = HiHi - Retracement;
Lretrace = LoLo + Retracement;
Plot2(HRetrace, "HRetrace");
Plot3(Lretrace, "LRetrace");
}
}
즐거운 하루되세요
> 해암 님이 쓴 글입니다.
> 제목 : 문의드립니다.
> 선물차트 기준으로 문의드립니다.
틱차트에 분봉의 fibonacci retrace 지표를 나타내고자 합니다.
분봉의 기간값과
fibonacci retrace 지표의 xavglen Hilolen Retrace 변수값들은 수정가능하게
부탁드립니다.
항상 감사드립니다. 수고하세요!!!
다음글
이전글