커뮤니티
수식의뢰 드립니다.
2025-03-13 11:46:36
352
글번호 189109
현재가부터 지난 4주간의 최고가와 최저가 가격 수평선이 우측으로 계속 연장되게 자동으로 생성되는 수식을 만들고 싶습니다. 고가 와 저가의 변동이 생기면 자동수정 생성되게 만들어 주세요! 우측 라인 윗부분에는 가격이 표시되게 해주세요.
1시간, 30분도 동일한 조건으로 부탁 드립니다.
시간 조정은 외부변수로 부탁드립니다.
답변 1
예스스탁 예스스탁 답변
2025-03-13 15:24:51
안녕하세요
예스스탁입니다.
1
input : n(4);
var : cnt(0),hv(0),lv(0),tx1(0),tx2(0);
Array : hh[50](0),ll[50](0);
if Bdate != Bdate[1] and DayOfWeek(Bdate) < DayOfWeek(Bdate[1]) Then
{
For cnt = 49 DownTo 1
{
hh[cnt] = hh[cnt-1];
ll[cnt] = ll[cnt-1];
}
hh[0] = h;
ll[0] = l;
}
Else
{
if hh[0] > 0 and h > hh[0] Then
{
hh[0] = h;
}
if ll[0] > 0 and l < ll[0] Then
{
ll[0] = l;
}
}
if hh[n-1] > 0 and ll[n-1] > 0 Then
{
hv = 0;
lv = 0;
For cnt = 0 to n-1
{
if hv == 0 or (hv > 0 and hh[cnt] > hv) Then
hv = hh[cnt];
if lv == 0 or (lv > 0 and ll[cnt] < lv) Then
lv = ll[cnt];
}
Plot1(hv);
plot2(lv);
Text_Delete(tx1);
Text_Delete(tx2);
tx1 = Text_New(sDate,sTime,hv,NumToStr(hv,2));
tx2 = Text_New(sDate,sTime,lv,NumToStr(lv,2));
Text_SetStyle(tx1,0,1);
Text_SetStyle(tx2,0,0);
}
2
input : 분(60),n(4);
var : cnt(0),S1(0),D1(0),TM(0),TF(0);
var : hv(0),lv(0),tx1(0),tx2(0);
Array : hh[50](0),ll[50](0);
if Bdate != Bdate[1] Then
{
S1 = TimeToMinutes(stime);
D1 = sdate;
}
if D1 > 0 then
{
if sdate == D1 Then
TM = TimeToMinutes(stime)-S1;
Else
TM = TimeToMinutes(stime)+1440-S1;
TF = TM%분;
if Bdate != Bdate[1] or
(Bdate == Bdate[1] and 분 > 1 and TF < TF[1]) or
(Bdate == Bdate[1] and 분 > 1 and TM >= TM[1]+분) or
(Bdate == Bdate[1] and 분 == 1 and TM > TM[1]) Then
{
For cnt = 49 DownTo 1
{
hh[cnt] = hh[cnt-1];
ll[cnt] = ll[cnt-1];
}
hh[0] = h;
ll[0] = l;
}
Else
{
if hh[0] > 0 and h > hh[0] Then
{
hh[0] = h;
}
if ll[0] > 0 and l < ll[0] Then
{
ll[0] = l;
}
}
}
if hh[n-1] > 0 and ll[n-1] > 0 Then
{
hv = 0;
lv = 0;
For cnt = 0 to n-1
{
if hv == 0 or (hv > 0 and hh[cnt] > hv) Then
hv = hh[cnt];
if lv == 0 or (lv > 0 and ll[cnt] < lv) Then
lv = ll[cnt];
}
Plot1(hv);
plot2(lv);
Text_Delete(tx1);
Text_Delete(tx2);
tx1 = Text_New(sDate,sTime,hv,NumToStr(hv,2));
tx2 = Text_New(sDate,sTime,lv,NumToStr(lv,2));
Text_SetStyle(tx1,0,1);
Text_SetStyle(tx2,0,0);
}
즐거운 하루되세요
> qha71 님이 쓴 글입니다.
> 제목 : 수식의뢰 드립니다.
> 현재가부터 지난 4주간의 최고가와 최저가 가격 수평선이 우측으로 계속 연장되게 자동으로 생성되는 수식을 만들고 싶습니다. 고가 와 저가의 변동이 생기면 자동수정 생성되게 만들어 주세요! 우측 라인 윗부분에는 가격이 표시되게 해주세요.
1시간, 30분도 동일한 조건으로 부탁 드립니다.
시간 조정은 외부변수로 부탁드립니다.