커뮤니티
문의
2025-02-14 09:28:10
432
글번호 188135
안녕하세요..
답변 주신 글들을 읽다가 궁금한 점이 생겨서요.
91379번 글..
https://www.yesstock.com/Board/View.asp?db=board100036&Ext=0&startpage=1&pageno=1&num=188964&ref=188950&Sort=&KeyField=&KeyWord=&SystemName=
이 글에서 마지막에 파란색 수평 라인으로 표시되는 값(y축, 금액)을 찾고 싶은데.. 그 값은 어디에 저장되어 있는지 궁금합니다.
그리고, 고점과 저점을 사용하셔서 추세선(빨강색)을 그었는데요.
위 아래 꼬리를 없애고 몸통의 위 아래를 사용해서 그려보고 싶은데.. 어떤 것을 바꾸면 될까요?
늘 감사합니다.
좋은 하루보내세요.
답변 1
예스스탁 예스스탁 답변
2025-02-14 14:45:15
안녕하세요
예스스탁입니다.
1
valArr 배열변수에 저장됩니다.
가장 최근 변곡점은 valArr[1], 그전은 valArr[2]와 같이 순서대로 저장됩니다.
2
Input:barCnt(5);
Var:j(0),turnPntBit(""),TL1(0),TL33(0),TL44(0),HD(0),HT(0),LD(0),LT(0),HH(0),LL(0);
var : TL121(0),TL122(0),tx121(0),tx122(0),tl2(0),TL3(0),TL4(0),TL5(0),sTL1(0),sTL2(0);
Array:valArr[10](0),barArr[10](0),turnPntArr[10]("");
var : Hv(0),Lv(0);
For j = 0 To 9
{
barArr[j] = barArr[j] + 1;
}
hv = max(c,o);
lv = min(c,o);
Condition1 = Highest(Hv,barCnt)[barCnt+1] <= Hv[barCnt] and Hv[barCnt] > Highest(Hv,barCnt);
Condition2 = Lowest(Lv,barCnt)[barCnt+1] >= Lv[barCnt] and Lv[barCnt] < Lowest(Lv,barCnt);
turnPntBit = "";
If Condition1 and Condition2 Then
{
If Max(valArr[1],valArr[2]) < Hv[barCnt] and Min(valArr[1],valArr[2]) > Lv[barCnt] Then
turnPntBit = "HiLo";
Else If Max(valArr[1],valArr[2]) < Hv[barCnt] Then turnPntBit = "Hi";
Else If Min(valArr[1],valArr[2]) > Lv[barCnt] Then turnPntBit = "Lo";
Else If turnPntArr[1] == "Hi" Then turnPntBit = "Lo";
Else If turnPntArr[1] == "Lo" Then turnPntBit = "Hi";
}
Else If Condition1 Then turnPntBit = "Hi";
Else If Condition2 Then turnPntBit = "Lo";
If turnPntBit <> "" Then
{
If turnPntBit == "HiLo" Then
{
valArr[1] = IFF(turnPntArr[1] == "Hi",Hv[barCnt],Lv[barCnt]);
barArr[1] = barCnt;
TL_SetEnd(TL1,sDate[barArr[1]],sTime[barArr[1]],valArr[1]);
TL_SetEnd(TL2,sDate[barArr[1]],sTime[barArr[1]],(valArr[2]+valArr[1])/2);
If turnPntArr[1] == "Hi" Then
turnPntBit = "Lo";
Else
turnPntBit = "Hi";
}
If turnPntBit <> turnPntArr[1] Then
{
for j = 8 downto 1
{
valArr[j+1] = valArr[j];
barArr[j+1] = barArr[j];
turnPntArr[j+1] = turnPntArr[j];
}
}
If turnPntBit <> turnPntArr[1] or
(turnPntBit == turnPntArr[1] and
((turnPntBit == "Hi" and valArr[1] < Hv[barCnt]) or
(turnPntBit == "Lo" and valArr[1] > Lv[barCnt]))) Then
{
valArr[1] = IFF(turnPntBit == "Hi",Hv[barCnt],Lv[barCnt]);
barArr[1] = barCnt;
turnPntArr[1] = turnPntBit;
If turnPntArr[1][1] <> turnPntArr[1][0] Then
{
TL1 = TL_New(sDate[barArr[2]],sTime[barArr[2]],valArr[2],sDate[barArr[1]],sTime[barArr[1]],valArr[1]);
TL2 = TL_New(sDate[barArr[2]],sTime[barArr[2]],(valArr[2]+valArr[1])/2,sDate[barArr[1]],sTime[barArr[1]],(valArr[2]+valArr[1])/2);
TL_SetExtRight(TL2,true);
tL3 = tl2[1];
tL4 = tl3[1];
tL5 = tl4[1];
TL_Delete(TL5);
TL_SetExtRight(TL3,False);
}
Else
{
TL_SetEnd(TL1,sDate[barArr[1]],sTime[barArr[1]],valArr[1]);
TL_SetBegin(TL2,TL_GetBeginDate(TL2),TL_GetBeginTime(TL2),(valArr[2]+valArr[1])/2);
TL_SetEnd(TL2,sDate[barArr[1]],sTime[barArr[1]],(valArr[2]+valArr[1])/2);
}
}
}
TL_SetSize(TL1,2);
TL_SetColor(TL1,RED);
TL_SetSize(TL2,2);
TL_SetColor(TL2,RED);
TL_Delete(sTL1);
TL_Delete(sTL2);
stl1 = TL_New(sDate[barArr[1]],sTime[barArr[1]],valArr[1],sDate,sTime,valArr[1]);
stl2 = TL_New(sDate[barArr[2]],sTime[barArr[2]],valArr[2],sDate,sTime,valArr[2]);
TL_SetColor(stl1,Blue);
TL_SetColor(stl2,Blue);
TL_SetSize(stl1,2);
TL_SetSize(stl2,2);
즐거운 하루되세요
> 이루나라 님이 쓴 글입니다.
> 제목 : 문의
> 안녕하세요..
답변 주신 글들을 읽다가 궁금한 점이 생겨서요.
91379번 글..
https://www.yesstock.com/Board/View.asp?db=board100036&Ext=0&startpage=1&pageno=1&num=188964&ref=188950&Sort=&KeyField=&KeyWord=&SystemName=
이 글에서 마지막에 파란색 수평 라인으로 표시되는 값(y축, 금액)을 찾고 싶은데.. 그 값은 어디에 저장되어 있는지 궁금합니다.
그리고, 고점과 저점을 사용하셔서 추세선(빨강색)을 그었는데요.
위 아래 꼬리를 없애고 몸통의 위 아래를 사용해서 그려보고 싶은데.. 어떤 것을 바꾸면 될까요?
늘 감사합니다.
좋은 하루보내세요.
다음글
이전글