키움 슈퍼트렌드 매수, 매도라인입니다
예스트레이더로 수식변경 부탁합니다.
행복한 하루되세요
A=supertrend(period, multiplier);
ValueWhen(1, CrossUp(C, A), A(1));
A=supertrend(period, multiplier);
ValueWhen(1, CrossDown(C, A), A(1));
답변 1
예스스탁
예스스탁 답변
2025-01-07 10:49:40
안녕하세요
예스스탁입니다.
input : period(60),multiplier(3);
var : src(0), AtrV(0),upperBand(0),lowerBand(0), prevLowerBand(0), prevUpperBand(0);
var : prevSuperTrend(0), direction(0),alpha(0),source(0),S(C),라인(0),K(0);
if CurrentBar > 1 Then
{
src = (H+L)/2;
alpha = 1 / period ;
source = max(high - low, abs(high - close[1]), abs(low - close[1]));
ATrV = alpha * source + (1 - alpha) * ATrV[1];
upperBand = src + multiplier * AtrV;
lowerBand = src - multiplier * AtrV;
prevLowerBand = lowerBand[1];
prevUpperBand = upperBand[1];
if lowerBand > prevLowerBand or close[1] < prevLowerBand Then
lowerBand = lowerBand;
Else
lowerBand = prevLowerBand;
if upperBand < prevUpperBand or close[1] > prevUpperBand Then
upperBand = upperBand;
Else
upperBand = prevUpperBand;
if C > UpperBand Then
direction = 1;
if C < LowerBand Then
direction = -1;
if direction == 1 Then
S = lowerband;
Else
S = upperband;
if CrossUp(C,S) Then
var1 = S[1];
if CrossDown(C,S) Then
var2 = S[1];
Plot1(var1);
Plot2(var2);
}
즐거운 하루되세요
> 볼라레 님이 쓴 글입니다.
> 제목 : 수식 변경 부탁합니다
> 키움 슈퍼트렌드 매수, 매도라인입니다
예스트레이더로 수식변경 부탁합니다.
행복한 하루되세요
A=supertrend(period, multiplier);
ValueWhen(1, CrossUp(C, A), A(1));
A=supertrend(period, multiplier);
ValueWhen(1, CrossDown(C, A), A(1));