커뮤니티
수식 부탁드립니다.
2024-12-04 23:13:55
516
글번호 185950
1. 일봉,10분봉,1분봉에서 bollinger band 상단선 이상이거나 1%범위안에
있으면서
2. 일봉,10분봉,1분봉에서 이동평균선(5일선,10일선)이 1%범위안에 있으면서
정배열로 매집 확산될때 매수하고
3. 역배열일때 매도하는 수식 가능할까요?
4. 1종목당 매수비용 10만원으로 부탁드립니다.
답변 1
예스스탁 예스스탁 답변
2024-12-05 11:28:54
안녕하세요
예스스탁입니다.
input : Period(20),Dv(2),타주기분(10),p1(5),p2(10),mm(100000);
var : cnt(0);
var : dsum(0),dbbmd(0),dSumSqrt(0),dStdv(0),dbbup(0);
var : dsumV1(0),dsumV2(0),dmav1(0),dmav2(0);
var : S1(0),D1(0),TM(0),TF(0);
var : tSumSqrt(0),tStdv(0),tsum(0),tBBmd(0),tBbup(0);
var : tsum1(0),tsum2(0),tmav1(0),tmav2(0);
var : bbup(0), mav1(0),mav2(0);
Array : CC[100](0);
If DayClose(Period) > 0 Then
{
dsum = 0;
for cnt = 0 to Period-1
{
dsum = dsum + DayClose(cnt);
}
dbbmd = dsum/Period;
dSumSqrt = 0;
For cnt = 0 To Period - 1
{
dSumSqrt = dSumSqrt + (DayClose(cnt) - dbbmd)^2;
}
dStdv = SquareRoot(dSumSqrt / Period);
dBBup = dbbmd + (Dv * dStdv);
}
dsumV1 = 0;
dsumV2 = 0;
for cnt = 0 to P2
{
if cnt < P1 Then
dsumV1 = dsumV1+DayClose(cnt);
if cnt < P2 Then
dsumV2 = dsumV2+DayClose(cnt);
}
dmaV1 = dsumV1 / P1;
dmaV2 = dsumV2 / P2;
if Bdate != Bdate[1] Then
{
S1 = TimeToMinutes(stime);
D1 = sdate;
}
if D1 > 0 then
{
if sdate == D1 Then
TM = TimeToMinutes(stime)-S1;
Else
TM = TimeToMinutes(stime)+1440-S1;
TF = TM%타주기분;
if Bdate != Bdate[1] or
(Bdate == Bdate[1] and 타주기분 > 1 and TF < TF[1]) or
(Bdate == Bdate[1] and 타주기분 > 1 and TM >= TM[1]+타주기분) or
(Bdate == Bdate[1] and 타주기분 == 1 and TM > TM[1]) Then
{
for cnt = 1 to 99
{
CC[cnt] = CC[cnt-1][1];
}
}
CC[0] = C;
if CC[Period] > 0 then
{
tsum = 0;
for cnt = 0 to Period-1
{
tsum = tsum + CC[cnt];
}
tBBmd = tsum/Period;
tSumSqrt = 0;
For cnt = 0 To Period - 1
{
tSumSqrt = tSumSqrt + (CC[cnt] - tBBmd)^2;
}
tStdv = SquareRoot(tSumSqrt / Period);
tBBup = tBBmd + (Dv * tStdv);
}
if CC[P1-1] > 0 then
{
tsum1 = 0;
for cnt = 0 to P1-1
{
tsum1 = tsum1+CC[cnt];
}
tmav1 = tsum1/P1;
}
if CC[P2-1] > 0 then
{
tsum2 = 0;
for cnt = 0 to P2-1
{
tsum2 = tsum2+CC[cnt];
}
tmav2 = tsum2/P2;
}
}
bbup = BollBandUp(Period,dv);
mav1 = ma(C,P1);
mav2 = ma(C,P2);
if dbbup > 0 and tbbup > 0 and bbup > 0 and
dmav1 > 0 and dmav2 > 0 and tmav1 > 0 and tmav2 > 0 and mav1 > 0 and mav2 > 0 and
C >= dbbup*0.99 and C >= tbbup*0.99 and c >= bbup*0.99 and
dmav1 > dmav2 and dmav1 <= dmav2*1.01 and
tmav1 > tmav2 and tmav1 <= tmav2*1.01 and
mav1 > mav2 and mav1 <= mav2*1.01 Then
Buy("b",OnClose,Def,Floor(mm/c));
if MarketPosition == 1 and
dmav1 < dmav1 and
tmav1 < tmav2 and
mav1 < mav2 Then
ExitLong();
즐거운 하루되세요
> 만경 님이 쓴 글입니다.
> 제목 : 수식 부탁드립니다.
> 1. 일봉,10분봉,1분봉에서 bollinger band 상단선 이상이거나 1%범위안에
있으면서
2. 일봉,10분봉,1분봉에서 이동평균선(5일선,10일선)이 1%범위안에 있으면서
정배열로 매집 확산될때 매수하고
3. 역배열일때 매도하는 수식 가능할까요?
4. 1종목당 매수비용 10만원으로 부탁드립니다.
이전글