커뮤니티
문의드립니다
2024-10-09 13:23:54
805
글번호 184115
첨부 이미지
그림1
안녕하세요
국내선물에서 쌍바닥이 발생한 후에 매수 진입하는 방법이 궁금합니다.
쌍바닥의 저점은 당일 저가일 필요는 없고, 아래와 같은 조건만 만족하면 됩니다.
1. 저점(A)와 저점(B) 사이에는 최소 10개의 캔들이 발생함
2. 저점(A)와 저점(B)의 상하폭은 최대 0.5 포인트 이하
3. 저점(A)와 고점(C)의 상하폭은 최소 0.5 포인트 이상
위의 조건이 만족한 경우, 이후에 발생하는 MACD 골든크로스에서 매수 진입하는 방법을 알려주시면 감사하겠습니다.
- 1. 파워포인트_쌍바닥.jpg (0.08 MB)
답변 1
예스스탁 예스스탁 답변
2024-10-10 11:51:15
안녕하세요
예스스탁입니다.
고점과 저점인데 관련 정의가 없으셔서
지그재그 식으로 대체해 작성해 드립니다.
수식 내용 참고하시기 바랍니다.
input : 최소변화폭(0.5);
input : short(12),long(26),sig(9);
var : macdv(0),macds(0);
Array : HD[10](0),HT[10](0),HV[10](0),HI[10](0);
Array : LD[10](0),LT[10](0),LV[10](0),LI[10](0);
var : cnt(0),Hprice(0),Lprice(0);
var : UpTrend(false),DownTrend(False),Trend(0);
var : ZigZagTL(0),HTL(0),LTL(0),Text(0);
macdv = macd(short,long);
macds = ema(macdv,sig);
HPrice = H;
LPrice = L;
if Index == 0 Then
{
HD[0] = sDate;
HT[0] = sTime;
HV[0] = HPrice;
LD[0] = sDate;
LT[0] = sTime;
LV[0] = LPrice;
}
Else
{
UpTrend = HPrice >= LV[0]+최소변화폭;
DownTrend = LPrice <= HV[0]-최소변화폭;
if trend <= 0 and UpTrend == true Then
{
trend = 1;
For cnt = 9 DownTo 1
{
HD[cnt] = HD[cnt-1];
HT[cnt] = HT[cnt-1];
HV[cnt] = HV[cnt-1];
HI[cnt] = HI[cnt-1];
}
HD[0] = sDate;
HT[0] = sTime;
HV[0] = HPrice;
HI[0] = Index;
ZigZagTL = TL_New(LD[0],LT[0],LV[0],HD[0],HT[0],HV[0]);
TL_SetColor(ZigZagTL,Red);
TL_SetSize(ZigZagTL,1);
Text = Text_New(HD[0],HT[0],HV[0],NumToStr(HV[0],2));
Text_SetColor(Text,Red);
Text_SetStyle(Text,2,1);
}
Else if trend >= 0 and DownTrend Then//하락추세 전환
{
trend = -1;
For cnt = 9 DownTo 1
{
LD[cnt] = LD[cnt-1];
LT[cnt] = LT[cnt-1];
LV[cnt] = LV[cnt-1];
LI[cnt] = LI[cnt-1];
}
LD[0] = sDate;
LT[0] = sTime;
LV[0] = LPrice;
LI[0] = Index;
ZigZagTL = TL_New(HD[0],HT[0],HV[0],LD[0],LT[0],LV[0]);
TL_SetColor(ZigZagTL,Blue);
TL_SetSize(ZigZagTL,1);
Text = Text_New(LD[0],LT[0],LV[0],NumToStr(LV[0],2));
Text_SetColor(Text,Blue);
Text_SetStyle(Text,2,0);
}
Else
{
if trend == 1 Then
{
if HPrice > HV[0] Then
{
HD[0] = sDate;
HT[0] = sTime;
HV[0] = HPrice;
HI[0] = Index;
TL_SetEnd(ZigZagTL,HD[0],HT[0],HV[0]);
Text_SetLocation(Text,HD[0],HT[0],HV[0]);
Text_SetString(Text,NumToStr(HV[0],2));
}
if LI[0] >= LI[1]+10 and
LV[0] > LV[1] and LV[0] < LV[1]+0.5 and
HV[0] >= LV[1]+0.5 and
CrossUp(MACDV,MACDS) Then
Buy();
}
if trend == -1 Then
{
if LPrice < LV[0] Then
{
LD[0] = sDate;
LT[0] = sTime;
LV[0] = LPrice;
LI[0] = Index;
TL_SetEnd(ZigZagTL,LD[0],LT[0],LV[0]);
Text_SetLocation(Text,LD[0],LT[0],LV[0]);
Text_SetString(Text,NumToStr(LV[0],2));
}
}
}
}
즐거운 하루되세요
> 맘속의행복 님이 쓴 글입니다.
> 제목 : 문의드립니다
> 안녕하세요
국내선물에서 쌍바닥이 발생한 후에 매수 진입하는 방법이 궁금합니다.
쌍바닥의 저점은 당일 저가일 필요는 없고, 아래와 같은 조건만 만족하면 됩니다.
1. 저점(A)와 저점(B) 사이에는 최소 10개의 캔들이 발생함
2. 저점(A)와 저점(B)의 상하폭은 최대 0.5 포인트 이하
3. 저점(A)와 고점(C)의 상하폭은 최소 0.5 포인트 이상
위의 조건이 만족한 경우, 이후에 발생하는 MACD 골든크로스에서 매수 진입하는 방법을 알려주시면 감사하겠습니다.
이전글