커뮤니티
문의
2024-10-07 15:53:29
676
글번호 184045
input : len (21),offset(2);
var : centr(0),line1(0),line2(0);
centr=ema(close,len);
line1=centr+offset*atr(len);
line2=centr-offset*atr(len);
plot1(centr,"center",blue);
PLOT2(line1,"라인1");
PLOT3(line2,"라인2");
데이타2로 타주기를 사용하면 캔들이 듬성 듬성 생겨서 챠트를 못봅니다.
외부변수로 타주기를 정할수 있게부탁드립니다
답변 1
예스스탁 예스스탁 답변
2024-10-08 11:27:17
안녕하세요
예스스탁입니다.
1번은 타주기 분봉식이고
2번은 타주기 일봉입니다.
1
Input : 분(30),len(21),offset(2);
var : S1(0),D1(0),TM(0),TF(0),ii(0);
Var : Ep(0), centr(0), Pre(0),line1(0),line2(0);;
var : HH(0),LL(0),C1(0),CC(0),cnt(0),sumTR(0),ATRV(0);
Array : TH[100](0),TL[100](0);
Ep = 2/(Len+1);
if Bdate != Bdate[1] Then
{
S1 = TimeToMinutes(stime);
D1 = sdate;
}
if D1 > 0 then
{
if sdate == D1 Then
TM = TimeToMinutes(stime)-S1;
Else
TM = TimeToMinutes(stime)+1440-S1;
TF = TM%분;
if Bdate != Bdate[1] or
(Bdate == Bdate[1] and 분 > 1 and TF < TF[1]) or
(Bdate == Bdate[1] and 분 > 1 and TM >= TM[1]+분) or
(Bdate == Bdate[1] and 분 == 1 and TM > TM[1]) Then
{
ii = ii +1;
Pre = centr[1];
HH = H;
LL = L;
C1 = CC[1];
for cnt = 99 downto 1
{
TH[cnt] = TH[cnt-1];
TL[cnt] = TL[cnt-1];
}
}
if H > HH Then
HH = H;
if L < LL Then
LL = L;
CC = c;
TH[0] = max(C1,HH);
TL[0] = Min(C1,LL);
if ii <= 1 then
centr = C;
else
centr = C * EP + Pre * (1-EP);
if TH[len-1] > 0 and TL[len-1] > 0 then
{
sumTR = 0;
for cnt = 0 to len-1
{
sumTR = sumTR + (TH[cnt]-TL[cnt]);
}
ATRV = sumTR/len;
line1=centr+offset*ATRV;
line2=centr-offset*ATRV;
plot1(centr,"center",blue);
PLOT2(line1,"라인1");
PLOT3(line2,"라인2");
}
}
2
input : len(21),offset(2);
var : sumTR(0),TH(0),TL(0),cnt(0),ATRV(0);
var : DD(0),Ep(0),centr(0),Pre(0),line1(0),line2(0);
Ep = 2/(len+1);
if bdate != bdate[1] then
{
DD = DD + 1;
Pre = centr[1];
}
if DD <= 1 then
centr = C;
else
centr = C * EP + Pre * (1-EP);
sumTR = 0;
for cnt = 0 to Len-1
{
If DayClose(cnt+1) > DayHigh(cnt) then
TH = DayClose(cnt+1);
else
TH = DayHigh(cnt);
If DayClose(cnt+1) < daylow(cnt) then
TL = DayClose(cnt+1);
else
TL = daylow(cnt);
sumTR = sumTR + (TH-TL);
}
ATRV = sumTR/Len;
line1=centr+offset*ATRV;
line2=centr-offset*ATRV;
plot1(centr,"center",blue);
PLOT2(line1,"라인1");
PLOT3(line2,"라인2");
즐거운 하루되세요
> 레전드 님이 쓴 글입니다.
> 제목 : 문의
> input : len (21),offset(2);
var : centr(0),line1(0),line2(0);
centr=ema(close,len);
line1=centr+offset*atr(len);
line2=centr-offset*atr(len);
plot1(centr,"center",blue);
PLOT2(line1,"라인1");
PLOT3(line2,"라인2");
데이타2로 타주기를 사용하면 캔들이 듬성 듬성 생겨서 챠트를 못봅니다.
외부변수로 타주기를 정할수 있게부탁드립니다
다음글