예스스탁
예스스탁 답변
2024-08-26 09:32:34
안녕하세요
예스스탁입니다.
1
input : sto1(10),sto2(5),short(12),long(26),sig(9),R기간(10),N(13);
var : S(0),md(0),ms(0),R(0);
var : Bs_Sto(-1),cnt_sto(-1),Bs_macd(-1),Bs_Rsi(-1),조건(False);
S = StochasticsK(sto1,sto2);
Md = Macd(short,long);
Ms = Ema(Md,sig);
R = RSI(R기간);
if CrossUp(S,20) Then
{
Bs_Sto = 0;
cnt_Sto = 0;
}
Else
{
if Bs_Sto >= 0 Then
Bs_Sto = Bs_Sto+1;
if cnt_Sto >= 0 and S < 80 Then
cnt_Sto = cnt_Sto+1;
}
if CrossUp(Md,Ms) Then
Bs_Macd = 0;
Else
{
if Bs_Macd >= 0 Then
Bs_Macd = Bs_Macd+1;
}
if CrossUp(R,50) Then
Bs_Rsi = 0;
Else
{
if Bs_Rsi >= 0 Then
Bs_Rsi = Bs_Rsi+1;
}
조건 = Bs_Sto >= 0 and Bs_Macd >= 0 and Bs_Rsi >= 0 and Bs_Sto <= N and
Bs_Sto > Bs_Macd and Bs_Sto > Bs_Rsi;
if 조건 && 조건[1] == False && (Bs_Sto+1)==cnt_Sto Then
Find(1);
2
input : per1(23.6),per2(38.2),per3(50.0),per4(61.8),per5(76.4);
var : HH(0),LL(0),OO(0),CC(0);
HH = DayHigh;
LL = DayLow;
if HH > 0 and LL > 0 and C > HH-(HH-LL)*(Per3/100) then
{
Find(1);
}
3
저점은 swinglow로 대체해 드립니다.
input :left(3),right(3);
if SwingLow(1,L,left,right,left+right+1) != -1 Then
{
var1 = L[right];
var2 = var1[1];
if var1 > Var2 and Var2 > 0 Then
Find(1);
}
4
if sDate != sDate[1] Then
var1 = h;
if var1 > 0 and c > var1 Then
Find(1);
즐거운 하루되세요
> 소나기 님이 쓴 글입니다.
> 제목 : 안녕하세요 수식 부탁드립니다~
> 안녕하세요
아래의 조건으로 종목검색식을 만들고 싶습니다.
1. 현재봉기준 N(13)봉 이내에,
스토캐스틱슬로우(12,5) %K가 20선을 상향 돌파한 후에,
MACD(12,26,9)가 signal선을 상향 돌파하고,
RSI(14)가 50선을 상향 돌파하는 세 가지를
모두 만족하는 종목을 검색하고 싶습니다.
세 가지를 만족하기 전에
스토캐스틱 %K가 80선을 돌파하면 제외하는 조건입니다.
(스토캐스틱 신호 후, MACD와 RSI는 순서 상관없음)
키움 신호수식은 다음과 같습니다.
이것을 예스 종목검색식으로 바꾸고 싶습니다.
S = Stochasticsslow(sto1,sto2);
M = Macd(short,long);
Ms = eavg(M,sig);
R = RSI(R기간);
Bs_Sto = BarsSince(CrossUp(S,20));
cnt_Sto = CountSince(CrossUp(S,20), S<80);
Bs_Macd = BarsSince(CrossUp(M,Ms));
Bs_Rsi = BarsSince(CrossUp(R,50));
조건 = Bs_Sto > Bs_Macd && Bs_Sto > Bs_Rsi;
//Max(Bs_Sto, Bs_Macd, Bs_Rsi) == Bs_Sto
조건 && !조건(1) && (Bs_Sto+1)==cnt_Sto
2. 피보나치조정대 0.5 위에 있는 종목만 검색하고 싶습니다.
아래 수식을 아무리 변형해봐도 잘 안되어서 부득이 부탁드립니다.
당일 분봉에서 현재봉이 per3(50.0) 위에 있는 종목만 검색하고 싶습니다.
input : per1(23.6),per2(38.2),per3(50.0),per4(61.8),per5(76.4);
var : HH(0),LL(0),OO(0),CC(0);
HH = DayHigh;
LL = DayLow;
if HH > 0 and LL > 0 then{
plot5(HH-(HH-LL)*(Per1/100),"per1%");
plot6(HH-(HH-LL)*(Per2/100),"per2%");
plot7(HH-(HH-LL)*(Per3/100),"per3%");
plot8(HH-(HH-LL)*(Per4/100),"per4%");
plot9(HH-(HH-LL)*(Per5/100),"per5%");
}
3. N자형으로 저점이 높아지고 고점도 높아지는 패턴의 종목을
검색하는 종목검색식 부탁드립니다.
장중에 분봉에서 사용용도입니다.
게시판을 몇 번 검색해도 찾지를 못하겠습니다.
저점과 고점이 정의가 안되어 수식작성이 안되면
일반적으로 사용되는 검색식이라도 부탁드리겠습니다.
4. 오늘 당일 N분봉 첫봉의 고가 위에 있는 종목만 검색하고 싶습니다.
수고에 감사드리며
늘 고맙습니다!!