커뮤니티
87076번 실제 돌려보니 문의내용과 다른 결과입니다.
2024-05-10 10:20:53
451
글번호 179331
제가 잘 못 봤을 수도 있습니다만 다시 한번 확인 부탁드립니다.
그리고 주석도 조금 부탁드립니다~
매수신호후 진입가에서 10틱 밀리면 즉시 청산한 후 반등이 나와 매수신호가 나온 진입가를 돌파하여 10틱 이상 올라가면 즉시 재매수 신호가 나오게 하고 싶습니다.
이때 매도신호로 바뀌기 전까지 처음 매수신호가 나온 봉의 종가인 진입가를 기준으로 조건만족시 매수신호가 반복해서 나오길 원합니다.
(파라볼릭 매수신호가 유지되는 중간에 1) 50틱 상승후 고점대비 30틱 하락시, 2) 첫 매수신호 나온 후 50개봉이 경과하는 2가지 상황이 되면 위의 진입가 기준 재진입이 중단되게도 부탁드립니다)
==> 첫 진입가를 다시 10틱 돌파해도 청산식으로 청산되고나면 재신호가 정확하게 나오지 않는거 같습니다.
답변 1
예스스탁 예스스탁 답변
2024-05-10 10:56:57
안녕하세요
예스스탁입니다.
1
수식을 다시 살펴보았지만 재진입에 문제가 없습니다.
아래 지표는 파라볼릭 크로스 시점의 종가기준 +-10틱선을 그리는 지표입니다.
적용해 보시면 손절후에 해당 라인에 도달하면 재진입 되고 있습니다.
Input : af(0.02), maxAF(0.2);
Var : Sarv(0);
var : cc(0);
Sarv = sar(af,maxAF);
If crossup(c,Sarv) Then
{
cc = c;
}
If CrossDown(c,Sarv) Then
{
cc = c;
}
Plot1(cc+PriceScale*10);
Plot2(cc-PriceScale*10);
2.
수식에 주석을 첨부해 드립니다.
Input : af(0.02), maxAF(0.2);
Var : Sarv(0),T(0),BB(0),SS(0),i(0);
var : cc(0),hh(0),ll(0);
Sarv = sar(af,maxAF);
#종가가 파라볼릭 상향돌파
If crossup(c,Sarv) Then
{
#무포지션이거나 매도포지션이면
if MarketPosition <= 0 Then
{
#매수
Buy("b1");
#종가 저장
BB = C;
#재매수 제어 변수 초기값 true
Condition1 = true;
}
#T는 1
T = 1;
#i에 볼번호 저장
i = Index;
#파라볼릭 매수구간 첫봉의 종가
cc = c;
#파라볼릭 매수구간의 최고값 저장변수 초기값 고가
hh = h;
}
#종가가 파라볼릭 하향이탈
If CrossDown(c,Sarv) Then
{
#무포지션이거나 매수포지션이면
if MarketPosition >= 0 Then
{
#매수진입
Sell("s1");
#종가자장
SS = C;
#재매도 제어 변수 초기값 true
Condition2 = true;
}
#T는 -1
T = -1;
#i에 볼번호 저장
i = Index;
#파라볼릭 매수구간 첫봉의 종가
cc = c;
#파라볼릭 매도구간의 최저값 저장변수 초기값 저가
ll = l;
}
#파라볼릭 매수구간이면
if T == 1 Then
{
#매수구간 최고가
if h > hh Then
hh =h ;
#매수구간돌입 후 50개봉 이상 경과하거나
#매수구간 최고가는 매수구간 첫봉 종가대비 50틱 이상이고 최고가 대비 30틱 아래의 저가가 발생하면
#재집입 변수 false
if Index >= i+50 or (hh >= cc+PriceScale*50 and l <= hh-PriceScale*30) Then
Condition1 = False;
#재진입허용 변수 true이고
if Condition1 == true and
#현재 무포지션이고 직전 거래가 매수포지션이고 손절로 끝났으면
MarketPosition == 0 and MarketPosition(1) == 1 and
IsexitName("StopLoss",1) == true Then
{
#매수구간 첫봉 종가 +10틱 이상 상승하면 재매수
Buy("b2",AtStop,BB+PriceScale*10);
}
}
#파라볼릭 매도구간
if T == -1 Then
{
#매도구간 최저가
if l < ll Then
ll = l;
#매도구간돌입 후 50개봉 이상 경과하거나
#매도구간 최저가는 매도구간 첫봉 종가대비 50틱 이하이고 최저가 대비 30틱 위의 고가가 발생하면
#재집입 변수 false
if Index >= i+50 or (ll <= cc-PriceScale*50 and h >= ll+PriceScale*30) Then
Condition2 = False;
#재진입허용 변수 true이고 #
if Condition2 == true and
#현재 무포지션이고 직전 거래가 매도포지션이고 손절로 끝났으면
MarketPosition == 0 and MarketPosition(1) == -1 and
IsexitName("StopLoss",1) == true Then
{
#매도구간 첫봉 종가 -10틱 이하 하락하면 재매도
Sell("s2",AtStop,SS-PriceScale*10);
}
}
SetStopLoss(PriceScale*10,PointStop);
즐거운 하루되세요
> 카르마다 님이 쓴 글입니다.
> 제목 : 87076번 실제 돌려보니 문의내용과 다른 결과입니다.
> 제가 잘 못 봤을 수도 있습니다만 다시 한번 확인 부탁드립니다.
그리고 주석도 조금 부탁드립니다~
매수신호후 진입가에서 10틱 밀리면 즉시 청산한 후 반등이 나와 매수신호가 나온 진입가를 돌파하여 10틱 이상 올라가면 즉시 재매수 신호가 나오게 하고 싶습니다.
이때 매도신호로 바뀌기 전까지 처음 매수신호가 나온 봉의 종가인 진입가를 기준으로 조건만족시 매수신호가 반복해서 나오길 원합니다.
(파라볼릭 매수신호가 유지되는 중간에 1) 50틱 상승후 고점대비 30틱 하락시, 2) 첫 매수신호 나온 후 50개봉이 경과하는 2가지 상황이 되면 위의 진입가 기준 재진입이 중단되게도 부탁드립니다)
==> 첫 진입가를 다시 10틱 돌파해도 청산식으로 청산되고나면 재신호가 정확하게 나오지 않는거 같습니다.