커뮤니티
시스템 부탁 드립니다.
2024-04-19 14:29:23
802
글번호 178733
90틱에 신호발생
매수 신호:
5분봉의 5와 20선 위에 있고 AND 90틱에 5와 20선 위에 있을때
매도신호 :
5분봉의 5와 20선 아래 있고 AND 90틱에 5와 20선 아래 있을때
청산신호 :
선물매수호가 총건수- 선물매도호가 총건수
선물계약 외인- 선물 개인 차이
거래소 외인-개인 차이가
위 3가지 조건이 모두 0 이상이거나 0 이하일때 90틱의 60선 이탈시 청산
위 3가지 만족 조건 외에는 90틱에 20선 이탈시 청산
답변 1
예스스탁 예스스탁 답변
2024-04-19 15:38:23
안녕하세요
예스스탁입니다.
1
틱봉에서 분봉 지표는 정확한 계산이 불가합니다.
수식은 봉의 시고저종만 사용이 가능합니다.
분봉 시간경계가 봉 중간에 있을 경우가 많은데 해당 시점 값을 알수는 없습니다.
근사치로 계산된다고 보셔야 합니다.
2
참조데이터는 아래순서로 적용하시면 됩니다.
data2 선물매수호가 총건수
data3 선물매도호가 총건수
data4 선물계약 외인
data5 선물개인 차이
data6 거래소 외인
data7 개인 차이가
3
input : ntime1(5),P1(5),P2(20),p3(60);
var : S1(0,Data1),D1(0,Data1),TM(0,Data1),TF(0,Data1),cnt(0,Data1);
var : sum1(0,Data1),mav1(0,Data1);
var : sum2(0,Data1),mav2(0,Data1);
var : m1(0,Data1),m2(0,Data1),m3(0,Data1);
var : diff1(0,Data1),diff2(0,Data1),diff3(0,Data1);
Array : CC[100](0,Data1);
m1 = Data1(ma(c,P1));
m2 = Data1(ma(c,P2));
m3 = Data1(ma(c,P3));
diff1 = Data2(c)-data3(c);
diff2 = Data4(c)-data5(c);
diff3 = Data6(c)-data7(c);
if data1(Bdate != Bdate[1]) Then
{
S1 = data1(TimeToMinutes(stime));
D1 = data1(sdate);
}
if D1 > 0 then
{
if data1(sdate == D1) Then
TM = data1(TimeToMinutes(stime)-S1);
Else
TM = data1(TimeToMinutes(stime)+1440-S1);
TF = TM%ntime1;
if Bdate != Bdate[1] or
(Bdate == Bdate[1] and ntime1 > 1 and TF < TF[1]) or
(Bdate == Bdate[1] and ntime1 > 1 and TM >= TM[1]+ntime1) or
(Bdate == Bdate[1] and ntime1 == 1 and TM > TM[1]) Then
{
for cnt = 99 downto 1
{
CC[cnt] = CC[cnt-1];
}
}
CC[0] = data1(C);
if CC[P1-1] > 0 then
{
sum1 = 0;
for cnt = 0 to P1-1
{
sum1 = sum1+CC[cnt];
}
mav1 = sum1/P1;
}
if CC[P2-1] > 0 then
{
sum2 = 0;
for cnt = 0 to P2-1
{
sum2 = sum2+CC[cnt];
}
mav2 = sum2/P2;
}
if mav1 > 0 and mav2 > 0 Then
{
if CC[0] > max(mav1,mav2) and
Data1(c) > max(m1,m2) Then
Buy("b");
if CC[0] < max(mav1,mav2) and
Data1(c) < max(m1,m2) Then
Sell("s");
if MarketPosition == 1 Then
{
if diff1 > 0 and diff2 > 0 and diff3 > 0 Then
{
if CrossDown(c,m3) Then
ExitLong("bx1");
}
Else
{
if CrossDown(c,m2) Then
ExitLong("bx2");
}
}
if MarketPosition == -1 Then
{
if diff1 < 0 and diff2 < 0 and diff3 < 0 Then
{
if CrossUp(c,m3) Then
ExitShort("sx1");
}
Else
{
if CrossUp(c,m2) Then
ExitShort("sx2");
}
}
}
}
즐거운 하루되세요
> 오늘도수익 님이 쓴 글입니다.
> 제목 : 시스템 부탁 드립니다.
> 90틱에 신호발생
매수 신호:
5분봉의 5와 20선 위에 있고 AND 90틱에 5와 20선 위에 있을때
매도신호 :
5분봉의 5와 20선 아래 있고 AND 90틱에 5와 20선 아래 있을때
청산신호 :
선물매수호가 총건수- 선물매도호가 총건수
선물계약 외인- 선물 개인 차이
거래소 외인-개인 차이가
위 3가지 조건이 모두 0 이상이거나 0 이하일때 90틱의 60선 이탈시 청산
위 3가지 만족 조건 외에는 90틱에 20선 이탈시 청산
이전글