커뮤니티
분봉상 돌파수식 부탁드립니다
2024-03-22 12:46:09
867
글번호 177836
10분봉에서 일봉의 RSI지표를 참조하여 매매하는 수식을 만들고싶은데요.
수식
- 10분봉에 일봉 rsi(12) 표시
- 10분봉에 일봉 MA(rsi(12), 6) 표시
매수
- 10분봉에서 일봉rsi(12)가 일봉ma(rsi(12), 6)을 상향돌파할때
매도
- 10분봉에서 일봉rsi(12)가 일봉ma(rsi(12), 9)를 하향돌파일때
부탁드립니다!!
답변 1
예스스탁 예스스탁 답변
2024-03-25 11:14:02
안녕하세요
예스스탁입니다.
Input : Length(12),signal(6);
var : cnt(0),SigSum(0),count2(0),RSIsig(0);
Var : Counter(0), DownAmt(0), UpAmt(0), UpSum(0), DownSum(0), UpAvg(0), DownAvg(0);
var : idx(0), PreUpAvg(0), preDownAvg(0),sum(0);
Array : C1[100](0),RSIV[100](-1),RSIS[100](-1);
if Bdate != Bdate[1] Then
{
for cnt = 99 DownTo 1
{
C1[cnt] = C1[cnt-1];
RSIV[cnt] = RSIV[cnt-1];
}
PreUpAvg = UpAvg[1];
preDownAvg = DownAvg[1];
idx = idx + 1;
}
C1[0] = C;
If idx == Length+2 Then
{
UpSum = 0;
DownSum = 0;
For Counter = 0 To Length - 1
{
UpAmt = C1[Counter] - C1[Counter+1];
If UpAmt >= 0 Then
DownAmt = 0;
Else
{
DownAmt = -UpAmt;
UpAmt = 0;
}
UpSum = UpSum + UpAmt;
DownSum = DownSum + DownAmt;
}
UpAvg = UpSum / Length;
DownAvg = DownSum / Length;
}
If idx > Length+2 Then
{
UpAmt = C1[0] - C1[1];
If UpAmt >= 0 Then
DownAmt = 0;
Else
{
DownAmt = -UpAmt;
UpAmt = 0;
}
UpAvg = (PreUpAvg * (Length - 1) + UpAmt) / Length;
DownAvg = (preDownAvg * (Length - 1) + DownAmt) / Length;
}
If UpAvg + DownAvg <> 0 Then
RSIv[0] = 100 * UpAvg / (UpAvg + DownAvg);
Else
RSIv[0] = 0;
if RSIV[signal-1] >= 0 Then
{
sum = 0;
For cnt = 0 to signal-1
{
sum = sum + RSIV[cnt];
}
RSIS[0] = sum/signal;
}
if RSIV[1] >= 0 and RSIS[1] > 0 Then
{
if RSIV[0] > RSIS[0] and RSIV[1] <= RSIS[1] Then
Buy();
if RSIV[0] < RSIS[0] and RSIV[1] >= RSIS[1] Then
Sell();
}
즐거운 하루되세요
> kkskkskk 님이 쓴 글입니다.
> 제목 : 분봉상 돌파수식 부탁드립니다
> 10분봉에서 일봉의 RSI지표를 참조하여 매매하는 수식을 만들고싶은데요.
수식
- 10분봉에 일봉 rsi(12) 표시
- 10분봉에 일봉 MA(rsi(12), 6) 표시
매수
- 10분봉에서 일봉rsi(12)가 일봉ma(rsi(12), 6)을 상향돌파할때
매도
- 10분봉에서 일봉rsi(12)가 일봉ma(rsi(12), 9)를 하향돌파일때
부탁드립니다!!