커뮤니티
macd 와 윌리엄즈R에 대한 문의(월봉을 일봉에 표기)
2024-03-15 18:24:17
744
글번호 177531
어렵네요. 도무지 해결이 되지 않아 찾던 중 해당 게시판을 알게 되어 문의드립니다.
가능하신 고수님들의 간절한 도움을 요청드립니다.
1. 주봉과 월봉의 MACD 0선 돌파를 일봉차트에 신호검색으로 나타내고자 합니다.
2. 일봉의 윌리엄즈R -20돌파 시점을 5분봉에 신호검색으로 나타내고자 합니다.
감사합니다.
답변 1
예스스탁 예스스탁 답변
2024-03-18 10:18:12
안녕하세요
예스스탁입니다.
예스랭귀지에서는 수식 종류 중 검색식(종목검색식이 아닙니다)이
조건에 만족한 봉에 점으로 표시하는 식입니다.
검색식으로 작성해 차트에 적용하시면 됩니다.
1
Input : short(12),long(26),sig(9);
var : EP1(0),EP2(0),EP3(0);
Var : widx(0),Wema1(0),Wema2(0),PreWema1(0),PreWema2(0);
Var : PreWMACDV(0),PreWMACDS(0),WMACDv(0),WMACDs(0);
Var : midx(0),Mema1(0),Mema2(0),PreMema1(0),PreMema2(0);
Var : PreMMACDV(0),PreMMACDS(0),MMACDv(0),MMACDs(0);
Ep1 = 2/(short+1);
Ep2 = 2/(long+1);
Ep3 = 2/(sig+1);
if DayOfWeek(Bdate) < DayOfWeek(Bdate[1]) Then
{
widx = widx + 1;
PreWema1 = Wema1[1];
PreWema2 = Wema2[1];
PreWMACDV = WMACDv[1];
PreWMACDS = WMACDs[1];
}
if widx <= 1 then
{
Wema1 = C;
Wema2 = C;
WMACDv = Wema1-Wema2;
WMACDs = WMACDv;
}
else{
Wema1 = C * EP1 + PreWema1 * (1-EP1);
Wema2 = C * EP2 + PreWema2 * (1-EP2);
WMACDV = Wema1-Wema2;
WMACDS = WMACDV * EP3 + PreWMACDS * (1-EP3);
}
if Bdate > Bdate[1]+30 Then
{
midx = midx + 1;
PreMema1 = Mema1[1];
PreMema2 = Mema2[1];
PreMMACDV = MMACDv[1];
PreMMACDS = MMACDs[1];
}
if midx <= 1 then
{
Mema1 = C;
Mema2 = C;
MMACDv = Mema1-Mema2;
MMACDs = MMACDv;
}
else{
Mema1 = C * EP1 + PreMema1 * (1-EP1);
Mema2 = C * EP2 + PreMema2 * (1-EP2);
MMACDV = Mema1-Mema2;
MMACDS = MMACDV * EP3 + PreMMACDS * (1-EP3);
}
if WMACDV > 0 and preWMACDV < 0 Then
Plot1(L,"검색",Red);
if MMACDV > 0 and preMMACDV < 0 Then
Plot2(L,"검색",Blue);
2
Input : Period(14);
Var : cnt(0);
var : H1(0),L1(0),WR1(0);
var : H2(0),L2(0),WR2(0);
H1 = DayHigh(0);
L1 = dayhigh(0);
H2 = DayHigh(1);
L2 = dayhigh(1);
for cnt = 0 to Period-1
{
if dayhigh(cnt) > H1 Then
H1 = dayhigh(cnt);
if daylow(cnt) < L1 Then
L1 = daylow(cnt);
if dayhigh(cnt+1) > H2 Then
H2 = dayhigh(cnt+1);
if daylow(cnt+1) < L2 Then
L2 = daylow(cnt+1);
}
WR1 = (H1 - Close) / (H1 - L1) * (-100);
WR2 = (H2 - Close) / (H2 - L2) * (-100);
if WR1 > -20 and WR2 < -20 Then
Plot1(L,"검색",Red);
즐거운 하루되세요
> 찰쓰 님이 쓴 글입니다.
> 제목 : macd 와 윌리엄즈R에 대한 문의(월봉을 일봉에 표기)
> 어렵네요. 도무지 해결이 되지 않아 찾던 중 해당 게시판을 알게 되어 문의드립니다.
가능하신 고수님들의 간절한 도움을 요청드립니다.
1. 주봉과 월봉의 MACD 0선 돌파를 일봉차트에 신호검색으로 나타내고자 합니다.
2. 일봉의 윌리엄즈R -20돌파 시점을 5분봉에 신호검색으로 나타내고자 합니다.
감사합니다.