커뮤니티
안녕하세요
2024-03-14 06:07:46
937
글번호 177464
rsi, macd등 분봉에서 보면 전일부터 당일까지 갭포함한 데이터를 반영하여
연결되어 나타나는데
이걸 당일이 되면 초기화해서 당일 수치만으로 각 지표들이 표시되게 하고 싶습니다
두개 중에 하나만 예를 들어 써주시면 참고하겠습니다 ^^
답변 1
예스스탁 예스스탁 답변
2024-03-14 11:27:32
안녕하세요
예스스탁입니다.
1
Input : Period1(12),Period2(26),Period3(9);
Var : Ep1(0), JISU1(0),Ep2(0), JISU2(0),Ep3(0),Jisu3(0);
var : MACDV(0),MACDS(0),idx(0);
Ep1 = 2/(Period1+1);
Ep2 = 2/(Period2+1);
Ep3 = 2/(Period3+1);
if bdate != Bdate[1] Then
idx = 0;
idx = idx+1;
if idx == 1 then
{
JISU1 = C;
JISU2 = C;
MACDv = JiSu1-Jisu2;
MACDs = MACDv;
}
else{
JISU1 = C * EP1 + JISU1[1] * (1-EP1);
JISU2 = C * EP2 + JISU2[1] * (1-EP2);
MACDv = JiSu1-Jisu2;
MACDs = MACDv * EP3 + MACDs[1] * (1-EP3);
}
plot1(MACDv);
plot2(MACDs);
PlotBaseLine1(0);
2
Inputs: Length(14);
Var : idx(0),Counter(0), DownAmt(0), UpAmt(0), UpSum(0), DownSum(0);
var : UpAvg(0), DownAvg(0),RSIV(0);
if Bdate != Bdate[1] Then
{
idx = 0;
}
idx = idx+1;
if idx <= Length Then
{
UpSum = 0;
DownSum = 0;
For Counter = 0 To idx - 1
{
UpAmt = C[Counter] - C[Counter+1];
If UpAmt >= 0 Then
DownAmt = 0;
Else
{
DownAmt = -UpAmt;
UpAmt = 0;
}
UpSum = UpSum + UpAmt;
DownSum = DownSum + DownAmt;
}
UpAvg = UpSum / Length;
DownAvg = DownSum / Length;
}
Else If idx > Length AND Length > 0 Then
{
UpAmt = C[0] - C[1];
If UpAmt >= 0 Then
DownAmt = 0;
Else
{
DownAmt = -UpAmt;
UpAmt = 0;
}
UpAvg = (UpAvg * (Length - 1) + UpAmt) / Length;
DownAvg = (DownAvg * (Length - 1) + DownAmt) / Length;
}
If UpAvg + DownAvg <> 0 Then
RSIv = 100 * UpAvg / (UpAvg + DownAvg);
Else
RSIv = 0;
plot1(RSIV);
PlotBaseLine1(30);
PlotBaseLine2(70);
즐거운 하루되세요
> 돈을잃자 님이 쓴 글입니다.
> 제목 : 안녕하세요
> rsi, macd등 분봉에서 보면 전일부터 당일까지 갭포함한 데이터를 반영하여
연결되어 나타나는데
이걸 당일이 되면 초기화해서 당일 수치만으로 각 지표들이 표시되게 하고 싶습니다
두개 중에 하나만 예를 들어 써주시면 참고하겠습니다 ^^
다음글