커뮤니티
지표에 신호 교차시 화살표 신호 넣기
2024-02-29 14:37:50
814
글번호 177072
아래는 trix지표인데
TRIXv(0)와 TRIXsig(0)가 교차시 화살표 신호가 나오게 하려 합니다
--------------------------------------
Input : Period(12), sigPeriod(9);
var : TRIXv(0),TRIXsig(0);
TRIXv = TRIX(Period);
TRIXsig = ema(TRIX(Period),sigPeriod);
Plot1(TRIXv,"TRIX");
Plot2(TRIXsig,"TRIX시그널");
PlotBaseLine1(0,"기준선");
답변 1
예스스탁 예스스탁 답변
2024-02-29 15:32:55
안녕하세요
예스스탁입니다.
1.
매수/매도 신호를 발생하고자 하시면
아래 내용을 시스템식으로 작성해 적용하셔야 합니다.
Input : Period(12), sigPeriod(9);
var : TRIXv(0),TRIXsig(0),tx(0);
TRIXv = TRIX(Period);
TRIXsig = ema(TRIX(Period),sigPeriod);
if CrossUp(TRIXv,TRIXsig) Then
{
Buy("b");
}
if CrossDown(TRIXv,TRIXsig) Then
{
Sell("s");
}
2.
봉에 삼각형, 역삼각형으로 표시하고자 하시면
아래 내용을 지표식으로 작성해 적용하시면 됩니다.
Input : Period(12), sigPeriod(9);
var : TRIXv(0),TRIXsig(0),tx(0);
TRIXv = TRIX(Period);
TRIXsig = ema(TRIX(Period),sigPeriod);
Plot1(TRIXv,"TRIX");
Plot2(TRIXsig,"TRIX시그널");
PlotBaseLine1(0,"기준선");
if CrossUp(TRIXv,TRIXsig) Then
{
tx = Text_New(sDate,sTime,L,"▲");
Text_SetStyle(tx,2,0);
Text_SetColor(tx,Red);
}
if CrossDown(TRIXv,TRIXsig) Then
{
tx = Text_New(sDate,sTime,H,"▼");
Text_SetStyle(tx,2,1);
Text_SetColor(tx,Blue);
}
3.
TRIX지표에 표시하고자 하시면
아래 내용을 지표식으로 작성해 적용하시면 됩니다.
Input : Period(12), sigPeriod(9);
var : TRIXv(0),TRIXsig(0),tx(0);
TRIXv = TRIX(Period);
TRIXsig = ema(TRIX(Period),sigPeriod);
Plot1(TRIXv,"TRIX");
Plot2(TRIXsig,"TRIX시그널");
PlotBaseLine1(0,"기준선");
if CrossUp(TRIXv,TRIXsig) Then
{
tx = Text_New_Self(sDate,sTime,TRIXsig,"▲");
Text_SetStyle(tx,2,0);
Text_SetColor(tx,Red);
}
if CrossDown(TRIXv,TRIXsig) Then
{
tx = Text_New_Self(sDate,sTime,TRIXsig,"▼");
Text_SetStyle(tx,2,1);
Text_SetColor(tx,Blue);
}
즐거운 하루되세요
> 치어스카한 님이 쓴 글입니다.
> 제목 : 지표에 신호 교차시 화살표 신호 넣기
> 아래는 trix지표인데
TRIXv(0)와 TRIXsig(0)가 교차시 화살표 신호가 나오게 하려 합니다
--------------------------------------
Input : Period(12), sigPeriod(9);
var : TRIXv(0),TRIXsig(0);
TRIXv = TRIX(Period);
TRIXsig = ema(TRIX(Period),sigPeriod);
Plot1(TRIXv,"TRIX");
Plot2(TRIXsig,"TRIX시그널");
PlotBaseLine1(0,"기준선");
이전글