커뮤니티
부탁드립니다
2024-02-28 08:58:42
653
글번호 177029
1. 전시간대 고가,저가,종가,시가 및 현시간대 시가, 중간값을 우측 추세선으로 구현해 주세요
2. 종가가 6시간전의 최저가 이하로 떨어지면 파란색으로, 그 다음 최저가 이상으로 올라오면 빨강색으로, 다시 앞서 파란색으로 갱신된 최저가 이하로 떨어지면 파란색으로, 종가가 6시간전의 최고가 이상으로 올라가면 빨강색으로, 그 다음 최고가 이하로 떨어지면 파란색으로, 다시 앞서빨강색으로 갱신된 최고가 이상으로 올라가면 빨강색으로 구현해 주세요
고맙습니다.
답변 1
예스스탁 예스스탁 답변
2024-02-28 11:51:52
안녕하세요
예스스탁입니다.
1
input : 분(60);
var : S1(0),D1(0),TM(0),TF(0),cnt(0),T(0);
var : dd(0),tt(0);
var : TL1(0),TL2(0),TL3(0),TL4(0),TL5(0),TL6(0);
Array : hh[20](0),LL[20](0),OO[20](0),CC[20](0);
if Bdate != Bdate[1] Then
{
S1 = TimeToMinutes(stime);
D1 = sdate;
}
if D1 > 0 then
{
if sdate == D1 Then
TM = TimeToMinutes(stime)-S1;
Else
TM = TimeToMinutes(stime)+1440-S1;
TF = TM%분;
if Bdate != Bdate[1] or
(Bdate == Bdate[1] and 분 > 1 and TF < TF[1]) or
(Bdate == Bdate[1] and 분 > 1 and TM >= TM[1]+분) or
(Bdate == Bdate[1] and 분 == 1 and TM > TM[1]) Then
{
dd = sDate;
tt = sTime;
For cnt = 19 DownTo 1
{
OO[cnt] = OO[cnt-1];
HH[cnt] = HH[cnt-1];
LL[cnt] = LL[cnt-1];
CC[cnt] = CC[cnt-1];
}
hh[0] = h;
LL[0] = l;
OO[0] = O;
if OO[1] > 0 Then
{
TL1 = TL_New(sDate,sTime,OO[1],NextBarSdate,NextBarStime,OO[1]);
TL2 = TL_New(sDate,sTime,HH[1],NextBarSdate,NextBarStime,HH[1]);
TL3 = TL_New(sDate,sTime,LL[1],NextBarSdate,NextBarStime,LL[1]);
TL4 = TL_New(sDate,sTime,CC[1],NextBarSdate,NextBarStime,CC[1]);
TL_SetColor(TL1,Green);
TL_SetColor(TL2,Red);
TL_SetColor(TL3,Blue);
TL_SetColor(TL4,Black);
TL_SetSize(TL1,1);
TL_SetSize(TL2,1);
TL_SetSize(TL3,1);
TL_SetSize(TL4,1);
}
TL5 = TL_New(sDate,sTime,OO[0],NextBarSdate,NextBarStime,OO[1]);
TL6 = TL_New(sDate,sTime,(HH[0]+LL[0])/2,NextBarSdate,NextBarStime,(HH[0]+LL[0])/2);
TL_SetColor(TL5,Cyan);
TL_SetColor(TL6,Magenta);
TL_SetSize(TL5,1);
TL_SetSize(TL6,1);
}
if HH[0] > 0 and H > HH[0] Then
HH[0] = H;
if LL[0] > 0 and L < LL[0] Then
LL[0] = L;
CC[0] = C;
if OO[1] > 0 Then
{
TL_SetEnd(TL1,NextBarSdate,NextBarStime,OO[1]);
TL_SetEnd(TL2,NextBarSdate,NextBarStime,HH[1]);
TL_SetEnd(TL3,NextBarSdate,NextBarStime,LL[1]);
TL_SetEnd(TL4,NextBarSdate,NextBarStime,CC[1]);
}
TL_SetEnd(TL5,NextBarSdate,NextBarStime,OO[0]);
TL_SetBegin(TL6,dd,tt,(HH[0]+LL[0])/2);
TL_SetEnd(TL6,NextBarSdate,NextBarStime,(HH[0]+LL[0])/2);
}
2
input : 분(60);
var : S1(0),D1(0),TM(0),TF(0),cnt(0),T(0);
Array : hh[20](0),LL[20](0),OO[20](0),CC[20](0);
if Bdate != Bdate[1] Then
{
S1 = TimeToMinutes(stime);
D1 = sdate;
}
if D1 > 0 then
{
if sdate == D1 Then
TM = TimeToMinutes(stime)-S1;
Else
TM = TimeToMinutes(stime)+1440-S1;
TF = TM%분;
if Bdate != Bdate[1] or
(Bdate == Bdate[1] and 분 > 1 and TF < TF[1]) or
(Bdate == Bdate[1] and 분 > 1 and TM >= TM[1]+분) or
(Bdate == Bdate[1] and 분 == 1 and TM > TM[1]) Then
{
For cnt = 19 DownTo 1
{
OO[cnt] = OO[cnt-1];
HH[cnt] = HH[cnt-1];
LL[cnt] = LL[cnt-1];
CC[cnt] = CC[cnt-1];
}
hh[0] = h;
LL[0] = l;
OO[0] = O;
T = 0;
}
if OO[6] > 0 Then
{
if CrossDown(C,LL[6]) Then
T = 1;
if CrossUp(C,LL[6]) Then
T = 2;
if CrossUp(C,HH[6]) Then
T = 3;
if CrossDown(C,HH[6]) Then
T = 4;
if T == 1 Then
PlotPaintBar(H,L,"강조",Blue);
if T == 2 Then
PlotPaintBar(H,L,"강조",Red);
if T == 3 Then
PlotPaintBar(H,L,"강조",Red);
if T == 4 Then
PlotPaintBar(H,L,"강조",Blue);
}
}
즐거운 하루되세요
> 서태공 님이 쓴 글입니다.
> 제목 : 부탁드립니다
> 1. 전시간대 고가,저가,종가,시가 및 현시간대 시가, 중간값을 우측 추세선으로 구현해 주세요
2. 종가가 6시간전의 최저가 이하로 떨어지면 파란색으로, 그 다음 최저가 이상으로 올라오면 빨강색으로, 다시 앞서 파란색으로 갱신된 최저가 이하로 떨어지면 파란색으로, 종가가 6시간전의 최고가 이상으로 올라가면 빨강색으로, 그 다음 최고가 이하로 떨어지면 파란색으로, 다시 앞서빨강색으로 갱신된 최고가 이상으로 올라가면 빨강색으로 구현해 주세요
고맙습니다.