커뮤니티
부탁드립니다
2024-01-21 12:26:41
590
글번호 175926
1. 20분마다 전전전시간대 최고가와 최저가, 전전시간대 최고가와 최저가 및 전시간대 최고가, 최저가, 종가, 그리고 현시간대 시가를 우측 연장 추세선으로 구현해 주세요
2. 20분마다 현시간대 종가가 중간값 위로 오르면 빨강색 봉으로, 아래로 내리면 파란색 봉으로 구현해 주세요
3. 20분마다 현시간대 중간값 추세선이 전시간대 중간값 추세선보다 높으면 빨강 추세선으로, 낮으면 파란 추세선으로 구현해 주세요
고맙습니다.
답변 1
예스스탁 예스스탁 답변
2024-01-23 09:41:46
안녕하세요
예스스탁입니다.
1
input : 분1(20);
var : S1(0),D1(0),TM(0),TF1(0),cnt(0),DD(0),TT(0);
var : TL1(0),TL2(0),TL3(0),TL4(0),TL5(0),TL6(0),TL7(0),TL8(0);
Array : OO1[10](0),HH1[10](0),LL1[10](0),CC1[10](0);
if Bdate != Bdate[1] Then
{
S1 = TimeToMinutes(stime);
D1 = sdate;
}
if D1 > 0 then
{
if sdate == D1 Then
TM = TimeToMinutes(stime)-S1;
Else
TM = TimeToMinutes(stime)+1440-S1;
TF1 = TM%분1;
if Bdate != Bdate[1] or
(Bdate == Bdate[1] and 분1 > 1 and TF1 < TF1[1]) or
(Bdate == Bdate[1] and 분1 > 1 and TM >= TM[1]+분1) or
(Bdate == Bdate[1] and 분1 == 1 and TM > TM[1]) Then
{
for cnt = 9 downto 1
{
OO1[cnt] = OO1[cnt-1];
HH1[cnt] = HH1[cnt-1];
LL1[cnt] = LL1[cnt-1];
CC1[cnt] = CC1[cnt-1];
}
DD = sDate;
TT = sTime;
OO1[0] = O;
HH1[0] = H;
LL1[0] = L;
TL_Delete(TL1);
TL_Delete(TL2);
TL_Delete(TL3);
TL_Delete(TL4);
TL_Delete(TL5);
TL_Delete(TL6);
TL_Delete(TL7);
TL_Delete(TL8);
TL1 = TL_New(DD,TT,HH1[3],NextBarSdate,NextBarStime,HH1[3]);
TL2 = TL_New(DD,TT,LL1[3],NextBarSdate,NextBarStime,LL1[3]);
TL3 = TL_New(DD,TT,HH1[2],NextBarSdate,NextBarStime,HH1[2]);
TL4 = TL_New(DD,TT,LL1[2],NextBarSdate,NextBarStime,LL1[2]);
TL5 = TL_New(DD,TT,HH1[1],NextBarSdate,NextBarStime,HH1[1]);
TL6 = TL_New(DD,TT,LL1[1],NextBarSdate,NextBarStime,LL1[1]);
TL7 = TL_New(DD,TT,CC1[1],NextBarSdate,NextBarStime,CC1[1]);
TL8 = TL_New(DD,TT,OO1[0],NextBarSdate,NextBarStime,OO1[0]);
TL_SetColor(TL1,Red);
TL_SetColor(TL2,Blue);
TL_SetColor(TL3,Red);
TL_SetColor(TL4,Blue);
TL_SetColor(TL5,Red);
TL_SetColor(TL6,Blue);
TL_SetColor(TL7,Black);
TL_SetColor(TL8,Green);
TL_SetExtRight(TL1,true);
TL_SetExtRight(TL2,true);
TL_SetExtRight(TL3,true);
TL_SetExtRight(TL4,true);
TL_SetExtRight(TL5,true);
TL_SetExtRight(TL6,true);
TL_SetExtRight(TL7,true);
TL_SetExtRight(TL8,true);
}
if H > HH1[0] Then
{
HH1[0] = H;
}
if L < LL1[0] Then
{
LL1[0] = L;
}
CC1[0] = C;
}
2
input : 분1(20);
var : S1(0),D1(0),TM(0),TF1(0),HH(0),LL(0);
if Bdate != Bdate[1] Then
{
S1 = TimeToMinutes(stime);
D1 = sdate;
}
if D1 > 0 then
{
if sdate == D1 Then
TM = TimeToMinutes(stime)-S1;
Else
TM = TimeToMinutes(stime)+1440-S1;
TF1 = TM%분1;
if Bdate != Bdate[1] or
(Bdate == Bdate[1] and 분1 > 1 and TF1 < TF1[1]) or
(Bdate == Bdate[1] and 분1 > 1 and TM >= TM[1]+분1) or
(Bdate == Bdate[1] and 분1 == 1 and TM > TM[1]) Then
{
HH = H;
LL = L;
}
if H > HH Then
HH = H;
if L < LL Then
LL = L;
var1 = (HH+LL)/2;
PlotPaintBar(H,L,"강조",IFf(C>var1,Red,Blue));
}
3
input : 분1(20);
var : S1(0),D1(0),TM(0),TF1(0),HH(0),LL(0),DD(0),TT(0),TL(0);
if Bdate != Bdate[1] Then
{
S1 = TimeToMinutes(stime);
D1 = sdate;
}
if D1 > 0 then
{
if sdate == D1 Then
TM = TimeToMinutes(stime)-S1;
Else
TM = TimeToMinutes(stime)+1440-S1;
TF1 = TM%분1;
if Bdate != Bdate[1] or
(Bdate == Bdate[1] and 분1 > 1 and TF1 < TF1[1]) or
(Bdate == Bdate[1] and 분1 > 1 and TM >= TM[1]+분1) or
(Bdate == Bdate[1] and 분1 == 1 and TM > TM[1]) Then
{
DD = sDate;
TT = sTime;
HH = H;
LL = L;
var2 = var1[1];
var1 = (HH+LL)/2;
TL = TL_New(sDate,sTime,var1,NextBarSdate,NextBarStime,var1);
}
if H > HH Then
HH = H;
if L < LL Then
LL = L;
var1 = (HH+LL)/2;
TL_SetBegin(TL,DD,TT,var1);
TL_SetEnd(TL,NextBarSdate,NextBarStime,var1);
TL_SetColor(TL,IFf(var1>Var2,Red,Blue));
}
즐거운 하루되세요
> 서태공 님이 쓴 글입니다.
> 제목 : 부탁드립니다
> 1. 20분마다 전전전시간대 최고가와 최저가, 전전시간대 최고가와 최저가 및 전시간대 최고가, 최저가, 종가, 그리고 현시간대 시가를 우측 연장 추세선으로 구현해 주세요
2. 20분마다 현시간대 종가가 중간값 위로 오르면 빨강색 봉으로, 아래로 내리면 파란색 봉으로 구현해 주세요
3. 20분마다 현시간대 중간값 추세선이 전시간대 중간값 추세선보다 높으면 빨강 추세선으로, 낮으면 파란 추세선으로 구현해 주세요
고맙습니다.