커뮤니티
array
2023-12-26 16:50:02
1108
글번호 175193
안녕하세요?
5분봉 차트에서 매일 발생하는 10시~12 중의 최고가 H와 최저가 L의 차이 H-L를 20일간 어레이에 저장(오늘거를 제외한 20개 값)하고 이 어레이를 이용해서 평균과 표준편차를 구하고 싶습니다.
고맙습니다!
답변 1
예스스탁 예스스탁 답변
2023-12-27 17:15:32
안녕하세요
예스스탁입니다.
input : StartTime(100000),EndTime(120000);
input : N(20);
var : Tcond(false),cnt(0),sum(0),mav(0),SumSqrt(0),Stdv(0);
Array : hh[100](0),LL[100](0);
if (sdate != sdate[1] and stime >= StartTime) or
(sdate == sdate[1] and stime >= StartTime and stime[1] < StartTime) Then
{
Tcond = true;
For cnt = 99 DownTo 1
{
HH[cnt] = HH[cnt-1];
LL[cnt] = LL[cnt-1];
}
HH[0] = H;
LL[0] = L;
}
if (sdate != sdate[1] and stime >= EndTime) or
(sdate == sdate[1] and stime >= EndTime and stime[1] < EndTime) Then
{
Tcond = False;
}
if Tcond == true Then
{
if H > HH[0] Then
HH[0] = H;
if L < LL[0] Then
LL[0] = L;
}
if HH[n] > 0 and LL[n] > 0 Then
{
#평균
sum = 0;
For cnt = 1 to N
{
sum = sum + (HH[cnt]-LL[cnt]);
}
mav = sum/N;
#표준편차
SumSqrt = 0;
For cnt = 1 To N
{
SumSqrt = SumSqrt + ((HH[cnt]-LL[cnt]) - mav)^2;
}
Stdv = SquareRoot(SumSqrt / N);
}
새해 복 많이 받으세요
> 코퍼 님이 쓴 글입니다.
> 제목 : array
>
안녕하세요?
5분봉 차트에서 매일 발생하는 10시~12 중의 최고가 H와 최저가 L의 차이 H-L를 20일간 어레이에 저장(오늘거를 제외한 20개 값)하고 이 어레이를 이용해서 평균과 표준편차를 구하고 싶습니다.
고맙습니다!