커뮤니티
시스템 문의드립니다
2023-11-30 20:28:39
992
글번호 174488
첨부 이미지
그림1
이평선 골크 데크 기준으로 매수매도 진입시 현재가격에 대한 선긋기와 사진처럼 진입가 당시 ATR 값을 기준으로 선긋기 및 손익절을 해보고싶습니다.
검정선은 진입가격이고
흰색선은 익절가격이고
빨간선은 손절가격입니다.
사진상에 보이는 ATR 기간은 11 곱은 3입니다.
- 1. 175299_예시.png (0.11 MB)
답변 1
예스스탁 예스스탁 답변
2023-12-01 11:40:50
안녕하세요
예스스탁입니다.
input : P1(5),P2(20),ATRP(11),n(3);
var : mav1(0),mav2(0),ATRV(0),EP(0),Profit(0),Loss(0);
var : TL1(0),TL2(0),TL3(0);
mav1 = ma(C,P1);
mav2 = ma(C,P2);
atrv = ATR(ATRP);
if MarketPosition <= 0 and CrossUp(mav1,mav2) Then
{
Buy("b");
EP = C;
Profit = EP+atrv*n;
Loss = EP-atrv*n;
TL1 = TL_New(sDate,sTime,EP,NextBarSdate,NextBarStime,EP);
TL2 = TL_New(sDate,sTime,Profit,NextBarSdate,NextBarStime,Profit);
TL3 = TL_New(sDate,sTime,Loss,NextBarSdate,NextBarStime,Loss);
TL_SetColor(TL1,Black);
TL_SetColor(TL2,White);
TL_SetColor(TL3,Red);
}
if MarketPosition >= 0 and CrossDown(mav1,mav2) Then
{
Sell("s");
EP = C;
Profit = EP-atrv*n;
Loss = EP+atrv*n;
TL1 = TL_New(sDate,sTime,EP,NextBarSdate,NextBarStime,EP);
TL2 = TL_New(sDate,sTime,Profit,NextBarSdate,NextBarStime,Profit);
TL3 = TL_New(sDate,sTime,Loss,NextBarSdate,NextBarStime,Loss);
TL_SetColor(TL1,Black);
TL_SetColor(TL2,White);
TL_SetColor(TL3,Red);
}
if MarketPosition == 1 Then
{
TL_SetEnd(TL1,NextBarSdate,NextBarStime,EP);
TL_SetEnd(TL2,NextBarSdate,NextBarStime,Profit);
TL_SetEnd(TL3,NextBarSdate,NextBarStime,Loss);
ExitLong("bp",AtLimit,Profit);
ExitLong("blp",AtStop,Loss);
}
if MarketPosition == -1 Then
{
TL_SetEnd(TL1,NextBarSdate,NextBarStime,EP);
TL_SetEnd(TL2,NextBarSdate,NextBarStime,Profit);
TL_SetEnd(TL3,NextBarSdate,NextBarStime,Loss);
ExitShort("sp",AtLimit,Profit);
ExitShort("slp",AtStop,Loss);
}
즐거운 하루되세요
> 잘하고프다 님이 쓴 글입니다.
> 제목 : 시스템 문의드립니다
> 이평선 골크 데크 기준으로 매수매도 진입시 현재가격에 대한 선긋기와 사진처럼 진입가 당시 ATR 값을 기준으로 선긋기 및 손익절을 해보고싶습니다.
검정선은 진입가격이고
흰색선은 익절가격이고
빨간선은 손절가격입니다.
사진상에 보이는 ATR 기간은 11 곱은 3입니다.
다음글
이전글