커뮤니티
유진예스트레이더 사용자인데요
2020-03-28 19:11:49
537
글번호 137286
분봉 차트에서 일봉 기준 RSI(8) 의 값을 차트에 나올게 할수 있는 수식을 알려주시면 감사하겠습니다.
그리고 그래프와 별도로 RSI 현재값(일봉기준) 이 표기될수 있는 방법이 있을까요?
답변 1
예스스탁 예스스탁 답변
2020-03-30 14:44:13
안녕하세요
예스스탁입니다.
1
RSI가 과거봉에 따라 현재봉의 값에 변경이 있는 계산법을 사용합니다.
분봉차트에서는 기간문제로 일봉차트에서 많은 봉수 띄우고 보시는 값과 다를수 있습니다.
2
지표속성의 차트표시탭에서 마지막지표값표시에 체크하시면
Y축에 현재 지표값이 표시가 됩니다.
3
Input : Length(8);
var : cnt(0),SigSum(0),count2(0),RSIsig(0);
Var : Counter(0), DownAmt(0), UpAmt(0), UpSum(0), DownSum(0), UpAvg(0), DownAvg(0);
var : idx(0), PreUpAvg(0), preDownAvg(0),RSIV(0);
Array : C1[100](0);
if Bdate != Bdate[1] Then
{
for cnt = 1 to 99
{
C1[cnt] = C1[cnt-1][1];
}
PreUpAvg = UpAvg[1];
preDownAvg = DownAvg[1];
idx = idx + 1;
}
C1[0] = C;
If idx == Length+2 Then
{
UpSum = 0;
DownSum = 0;
For Counter = 0 To Length - 1
{
UpAmt = C1[Counter] - C1[Counter+1];
If UpAmt >= 0 Then
DownAmt = 0;
Else
{
DownAmt = -UpAmt;
UpAmt = 0;
}
UpSum = UpSum + UpAmt;
DownSum = DownSum + DownAmt;
}
UpAvg = UpSum / Length;
DownAvg = DownSum / Length;
}
If idx > Length+2 Then
{
UpAmt = C1[0] - C1[1];
If UpAmt >= 0 Then
DownAmt = 0;
Else
{
DownAmt = -UpAmt;
UpAmt = 0;
}
UpAvg = (PreUpAvg * (Length - 1) + UpAmt) / Length;
DownAvg = (preDownAvg * (Length - 1) + DownAmt) / Length;
}
If UpAvg + DownAvg <> 0 Then
RSIv = 100 * UpAvg / (UpAvg + DownAvg);
Else
RSIv = 0;
plot1(RSIv,"RSI");
PlotBaseLine1(30, "기준선 30");
PlotBaseLine2(70, "기준선 70");
즐거운 하루되세요
> 이형지 님이 쓴 글입니다.
> 제목 : 유진예스트레이더 사용자인데요
> 분봉 차트에서 일봉 기준 RSI(8) 의 값을 차트에 나올게 할수 있는 수식을 알려주시면 감사하겠습니다.
그리고 그래프와 별도로 RSI 현재값(일봉기준) 이 표기될수 있는 방법이 있을까요?
다음글
이전글