커뮤니티
함수식부탁입니다
2019-10-18 10:02:58
189
글번호 132896
#,안녕하세요
ㅡ,전주의 시가,고가,저가,중심가
ㅡ,전월의 시가,고가,저자,중심가
ㅡ,전년의 시가,고가,저가,중심가
##,해선 함수식 도움 부탁드립니다.
$,고맙습니다.
답변 1
예스스탁 예스스탁 답변
2019-10-18 14:18:12
안녕하세요
예스스탁입니다.
해선과 국내 모두 1번식으로 동일합니다.
항셍과 같이 별도의 시간이 하루의 기준으로 삼는 종목이면 2번식 이요하셔야 합니다.
1.
var : cnt(0);
Array : WH[10](0),WL[10](0),WO[10](0);
Array : MH[10](0),ML[10](0),MO[10](0);
Array : YH[10](0),YL[10](0),YO[10](0);
if DayOfWeek(bdate) < DayOfWeek(Bdate[1]) Then
{
WO[0] = O;
WH[0] = H;
WL[0] = L;
for cnt = 1 to 9
{
WO[cnt] = WO[cnt-1][1];
WH[cnt] = WH[cnt-1][1];
WL[cnt] = WL[cnt-1][1];
}
}
if WH[0] > 0 and H > WH[0] Then
WH[0] = H;
if WL[0] > 0 and L < WL[0] Then
WL[0] = L;
if bdate > Bdate[1]+30 Then
{
MO[0] = O;
MH[0] = H;
ML[0] = L;
for cnt = 1 to 9
{
MO[cnt] = MO[cnt-1][1];
MH[cnt] = MH[cnt-1][1];
ML[cnt] = ML[cnt-1][1];
}
}
if MH[0] > 0 and H > MH[0] Then
MH[0] = H;
if ML[0] > 0 and L < ML[0] Then
ML[0] = L;
if bdate > Bdate[1]+1000 Then
{
YO[0] = O;
YH[0] = H;
YL[0] = L;
for cnt = 1 to 9
{
YO[cnt] = YO[cnt-1][1];
YH[cnt] = YH[cnt-1][1];
YL[cnt] = YL[cnt-1][1];
}
}
if YH[0] > 0 and H > YH[0] Then
YH[0] = H;
if YL[0] > 0 and L < YL[0] Then
YL[0] = L;
plot1(WO[1],"전주시가");
plot2(WH[1],"전주고가");
plot3(WL[1],"전주저가");
plot4((WH[1]+WL[1])/2,"전주중심");
plot5(MO[1],"전월시가");
plot6(MH[1],"전월고가");
plot7(ML[1],"전월저가");
plot8(( MH[1]+ML[1])/2,"전월중심");
plot9(YO[1],"전년시가");
plot10(YH[1],"전년고가");
plot11(YL[1],"전년저가");
plot12((YH[1]+YL[1])/2,"전년중심");
2
var : cnt(0),D1(0),D2(0);
Array : WH[10](0),WL[10](0),WO[10](0);
Array : MH[10](0),ML[10](0),MO[10](0);
Array : YH[10](0),YL[10](0),YO[10](0);
if (sdate != sdate[1] and stime >= 101500) or
(sdate == sdate[1] and stime >= 101500 and stime[1] < 101500) Then
{
D1 = sdate;
D2 = D1[1];
if DayOfWeek(D1) < DayOfWeek(D2) Then
{
WO[0] = O;
WH[0] = H;
WL[0] = L;
for cnt = 1 to 9
{
WO[cnt] = WO[cnt-1][1];
WH[cnt] = WH[cnt-1][1];
WL[cnt] = WL[cnt-1][1];
}
}
if D1 > D2+30 Then
{
MO[0] = O;
MH[0] = H;
ML[0] = L;
for cnt = 1 to 9
{
MO[cnt] = MO[cnt-1][1];
MH[cnt] = MH[cnt-1][1];
ML[cnt] = ML[cnt-1][1];
}
}
if D1 > D2+1000 Then
{
YO[0] = O;
YH[0] = H;
YL[0] = L;
for cnt = 1 to 9
{
YO[cnt] = YO[cnt-1][1];
YH[cnt] = YH[cnt-1][1];
YL[cnt] = YL[cnt-1][1];
}
}
}
if WH[0] > 0 and H > WH[0] Then
WH[0] = H;
if WL[0] > 0 and L < WL[0] Then
WL[0] = L;
if MH[0] > 0 and H > MH[0] Then
MH[0] = H;
if ML[0] > 0 and L < ML[0] Then
ML[0] = L;
if YH[0] > 0 and H > YH[0] Then
YH[0] = H;
if YL[0] > 0 and L < YL[0] Then
YL[0] = L;
plot1(WO[1],"전주시가");
plot2(WH[1],"전주고가");
plot3(WL[1],"전주저가");
plot4((WH[1]+WL[1])/2,"전주중심");
plot5(MO[1],"전월시가");
plot6(MH[1],"전월고가");
plot7(ML[1],"전월저가");
plot8((MH[1]+ML[1])/2,"전월중심");
plot9(YO[1],"전년시가");
plot10(YH[1],"전년고가");
plot11(YL[1],"전년저가");
plot12((YH[1]+YL[1])/2,"전년중심");
즐거운 하루되세요
> 골든키 님이 쓴 글입니다.
> 제목 : 함수식부탁입니다
> #,안녕하세요
ㅡ,전주의 시가,고가,저가,중심가
ㅡ,전월의 시가,고가,저자,중심가
ㅡ,전년의 시가,고가,저가,중심가
##,해선 함수식 도움 부탁드립니다.
$,고맙습니다.