커뮤니티
질문 입니다
2019-10-04 13:15:59
219
글번호 132497
시스템 인데요
분봉에 20일 5일 일목 균형의 후행 선행1,2 표시 하고 싶읍니다
파워종목검색 안 쓰고 분봉에 20일 5일 를 정의 하고 crossup(5,20)도 표시 하고 싶습니다
답변 1
예스스탁 예스스탁 답변
2019-10-07 14:29:56
안녕하세요
예스스탁입니다.
1
아래는 분봉에서 일봉의 이동평균과 일목균형표를 그리는 지표입니다.
후행스팬은 현재가를 과거 N봉전으로 이동한 선인데
속성에서 직접 봉수로 지정해야 하고 분봉에서 일봉갯수가 가늠되지 않아
후행스팬은 표현이 불가능합니다.
input : P1(5),P2(20);
Input : 전환선기간(9), 기준선기간(26), 선행스팬2기간(52);
Var : 기준선(0), 전환선(0), 후행스팬(0), 선행스팬1(0), 선행스팬2(0);
var : cnt(0),H1(0),L1(0),H11(0),L11(0),H2(0),L2(0),H22(0),L22(0),H3(0),L3(0);
var : sum1(0),sum2(0),mav1(0),mav2(0);
sum1 = 0;
for cnt = 0 to P1-1
{
sum1 = sum1 + DayClose(cnt);
}
mav1 = sum1/P1;
sum2 = 0;
for cnt = 0 to P2-1
{
sum2 = sum2 + DayClose(cnt);
}
mav2 = sum2/P2;
plot1(mav1,"일봉P1이평");
plot2(mav2,"일봉P2이평");
H1 = dayhigh(0);
L1 = daylow(0);
H11 = dayhigh(25);
L11 = daylow(25);
H2 = dayhigh(0);
L2 = daylow(0);
H22 = dayhigh(25);
L22 = daylow(25);
H3 = dayhigh(25);
L3 = daylow(25);
for cnt = 0 to 선행스팬2기간-1
{
if cnt < 전환선기간 Then
{
if dayhigh(cnt) > H1 Then
H1 = dayhigh(cnt);
if daylow(cnt) < L1 Then
L1 = DayLow(cnt);
if dayhigh(cnt+25) > H11 Then
H11 = dayhigh(cnt+25);
if daylow(cnt+25) < L11 Then
L11 = DayLow(cnt+25);
}
if cnt < 기준선기간 Then
{
if dayhigh(cnt) > H2 Then
H2 = dayhigh(cnt);
if daylow(cnt) < L2 Then
L2 = DayLow(cnt);
if dayhigh(cnt+25) > H22 Then
H22 = dayhigh(cnt+25);
if daylow(cnt+25) < L22 Then
L22 = DayLow(cnt+25);
}
if dayhigh(cnt+25) > H3 Then
H3 = dayhigh(cnt+25);
if DayLow(cnt+25) < L3 Then
L3 = DayLow(cnt+25);
}
전환선 = (H1 + L1)/2;
기준선 = (H2 + L2) / 2;
선행스팬1 = ( (H11+L11)/2 + (H22+L22)/2) / 2 ;
선행스팬2 = (H3+L3) / 2;
plot3(전환선,"전환선");
plot4(기준선,"기준선");
plot5(선행스팬1,"선행1");
plot6(선행스팬2,"선행2");
2
input : P1(5),P2(20);
var : cnt(0),sum1(0),sum2(0),mav1(0),mav2(0);
var : sum11(0),mav11(0),sum22(0),mav22(0);
sum1 = 0;
sum11 = 0;
for cnt = 0 to P1-1
{
sum1 = sum1 + DayClose(cnt);
sum11 = sum11 + DayClose(cnt+1);
}
mav1 = sum1/P1;
mav11 = sum11/P1;
sum2 = 0;
sum22 = 0;
for cnt = 0 to P2-1
{
sum2 = sum2 + DayClose(cnt);
sum22 = sum22 + DayClose(cnt+1);
}
mav2 = sum2/P2;
mav22 = sum22/P2;
if mav1 > mav2 and mav11 <= mav22 Then
find(1);
즐거운 하루되세요
> 킬러잡이킬러 님이 쓴 글입니다.
> 제목 : 질문 입니다
> 시스템 인데요
분봉에 20일 5일 일목 균형의 후행 선행1,2 표시 하고 싶읍니다
파워종목검색 안 쓰고 분봉에 20일 5일 를 정의 하고 crossup(5,20)도 표시 하고 싶습니다
다음글
이전글